[bullet28]

Basically what this does is making your chat a little cleaner.



Should be used in gamemodes where there is only 1 playable team (coop, scavenge, etc)

Updates history:
31 January 2024: Uploaded improved version by HarryPotter
09 April 2020: Switched to use 'OnClientSayCommand' (thanks to Marttt), added ignore list convar.

[zaviier]

Thanks... this is great for one team only.

[Marttt]

Nice, good idea.

Anyway I checked the code and you can do some improvements.

Spoiler

• Found an extra space while changing the say_team for say command, after the client name.
• Replace the "GetClientName" with "%N", unless there is some reason to do it.
• Using RegConsoleCmd on an existing command is not a good thing, try to use the
  public Action OnClientSayCommand(int client, const char[] command, const char[] sArgs)
  or add a listener (Dragokas snippet)
  AddCommandListener(ListenSayTeam, "say_team");
• You could hide the "team chat" command for the sender, now it is displaying twice.
• Maybe you should remove the "@" prefix for this code, because if u are an admin, you are able to talk only with admins using @ prefix in team chat

[bullet28]

Originally Posted by Marttt Found an extra space while changing the say_team for say command, after the client name

It is not extra, original message has same amount of spaces, if you remove it -- message will look different.

Originally Posted by Marttt Replace the "GetClientName" with "%N", unless there is some reason to do it.

It is used for TrimString.. but reality is that trim should be removed too, so I do it.

Originally Posted by Marttt OnClientSayCommand(int client, const char[] command, const char[] sArgs)

If it's really so important.. ok, I will use it.

Originally Posted by Marttt You could hide the "team chat" command for the sender, now it is displaying twice.

What do you mean by "team chat command"? I never seen messages twice while using this plugin.

Originally Posted by Marttt Maybe you should remove the "@" prefix for this code, because if u are an admin, you are able to talk only with admins using @ prefix in team chat

Ok, didn't knew about this prefix. I will add convar for those who has their own preferences.

[Marttt]

Originally Posted by bullet28 It is not extra, original message has same amount of spaces, if you remove it -- message will look different.

What I mean is that you are "double" spacing, instead just a single one.

.Mart. : a (all chat)
.Mart. : a (team chat)

EDIT: I cant show here because SM removes double spacing from the post, but you can check what I mean by clicking in "quote"

Originally Posted by bullet28 What do you mean by "team chat command"? I never seen messages twice while using this plugin.

I get this result because I have a plugin that makes !commands lowercase, probably is some conflict.
I made a test removing the RegConsoleCmd and changing it to the Action OnClientSayCommand and it stopped.
I also had to change the last line to Plugin_Stop; and check if the command var is "say_team"

Anyway nice plugin, I just wanted to warn you about some stuff you could improve

[bullet28]

Originally Posted by Marttt I made a test removing the RegConsoleCmd and changing it to the Action OnClientSayCommand and it stopped

Good. I have updated version to use OnClientSayCommand. Thank you!

Originally Posted by Marttt I mean is that you are "double" spacing, instead just a single one

I have recorded for you a small video to show that I has exactly same amount of spaces as in original game. https://youtu.be/mtUomL5-ZNk Are you using L4D2 too?

[HarryPotter]

I have this error in sourcemod 1.8 on local windows server

Spoiler

L 04/21/2020 - 18:498: [SM] Exception reported: No command callback available
L 04/21/2020 - 18:498: [SM] Blaming: lfd_noTeamSay.smx
L 04/21/2020 - 18:498: [SM] Call stack trace:
L 04/21/2020 - 18:498: [SM] [0] GetCmdArg
L 04/21/2020 - 18:498: [SM] [1] Line 38, D:\Program Files (x86)\Steam\steamapps\common\Left 4 Dead 2 Dedicated Server\left4dead2\addons\sourcemod\scripting\ lfd_noTeamSay.sp::OnClientSayCommand
L 04/21/2020 - 18:54:28: Error log file session closed.

so I modify some codes, works for me.

PHP Code:

public void OnPluginStart() {
    AddCommandListener(TeamSay_Callback, "say_team");
.
.
}

public Action TeamSay_Callback(int client, const char[] command, int argc){
    if (!StrEqual(command, "say_team", false))
        return Plugin_Continue;

    if (client <= 0)
        return Plugin_Continue;

    char msg[MAX_NAME_LENGTH];
    GetCmdArg(1, msg, sizeof(msg));

    for (int i = 0; i < sizeof ignoreList; i++) {
        if (ignoreList[i][0] != EOS && StrContains(msg, ignoreList[i]) == 0) {
            return Plugin_Continue;
        }
    }
    
    TrimString(msg);

    char buffer[256];
    Format(buffer, sizeof(buffer), "\x03%N\x01 :  %s", client, msg);

    for (int i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && !IsFakeClient(i)) {
            SayText2(i, client, buffer);
        }
    }

    return Plugin_Handled;
}

/*
public Action OnClientSayCommand(int client, const char[] command, const char[] sArgs) {
    if (!StrEqual(command, "say_team", false))
        return Plugin_Continue;

    if (client <= 0)
        return Plugin_Continue;

    char msg[192];
    GetCmdArg(1, msg, sizeof(msg));

    for (int i = 0; i < sizeof ignoreList; i++) {
        if (ignoreList[i][0] != EOS && StrContains(msg, ignoreList[i]) == 0) {
            return Plugin_Continue;
        }
    }
    
    TrimString(msg);

    char buffer[256];
    Format(buffer, sizeof(buffer), "\x03%N\x01 :  %s", client, msg);

    for (int i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && !IsFakeClient(i)) {
            SayText2(i, client, buffer);
        }
    }

    return Plugin_Stop;
}
*/ 


[Zheldorg]

I compiled using build "1.10.0.6492" but still got the error "[SM] Exception reported: No command callback available".
I'm not sure if it's appropriate to call GetCmdArg () here, because already getting sArgs as chat argument string
My fix option using this:

PHP Code:

public Action OnClientSayCommand(int client, const char[] command, const char[] sArgs) {
    if (!StrEqual(command, "say_team", false))
        return Plugin_Continue;

    if (client <= 0)
        return Plugin_Continue;

    char msg[192];
    strcopy(msg, sizeof(msg), sArgs);// replacement GetCmdArg(1, msg, sizeof(msg));
//    GetCmdArg(1, msg, sizeof(msg)); // do error:
/*
L 08/04/2020 - 21:43:30: [SM] Exception reported: No command callback available
L 08/04/2020 - 21:43:30: [SM] Blaming: lfd_noTeamSay.smx
L 08/04/2020 - 21:43:30: [SM] Call stack trace:
L 08/04/2020 - 21:43:30: [SM]   [0] GetCmdArg
L 08/04/2020 - 21:43:30: [SM]   [1] Line 38, D:\ScmdServers\apps\l4d2\left4dead2\addons\sourcemod\scripting\lfd_noTeamSay.sp::OnClientSayCommand 
*/
    for (int i = 0; i < sizeof ignoreList; i++) {
        if (ignoreList[i][0] != EOS && StrContains(msg, ignoreList[i]) == 0) {
            return Plugin_Continue;
        }
    }
    
    TrimString(msg);

    char buffer[256];
    Format(buffer, sizeof(buffer), "\x03%N\x01 :  %s", client, msg);

    for (int i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i) && !IsFakeClient(i)) {
            SayText2(i, client, buffer);
        }
    }

    return Plugin_Stop;
} 


[Marttt]

L4D2 Windows (Local Server), but no problem, thanks to check.

[HarryPotter]

Remake
https://github.com/fbef0102/L4D1_2-P.../lfd_noTeamSay