[JoaoRodrigoGamer]

Originally Posted by ShD3luxe It looks like now it's listing all the weapons except for the healthshot . In what slot do you have the healthshot ? It should be on the 5 (the c4 slot). Try checking if the debug command is showing weapon_c4 if you have it on you.

On the chat debug it does not show the c4 but it takes and then gives it back to the player.

The health shot is not in the c4 slot but below it (see attachment).

僕の kill‎ : !test
[DEBUG] User weapon weapon_glock , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_knife , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_taser , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_tagrenade , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_hegrenade , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_flashbang , weapon to check for : weapon_healthshot

Originally Posted by ShD3luxe If you want to limit the user to just one healthshot(per round) use the cvar : ammo_item_limit_healthshot 1

I could do that but then, the script would be giving extra health shots and those would be dropped on the floor.

Originally Posted by ShD3luxe Also try just giving the item back to the player without equiping it: PHP Code: stock bool WeaponsClientHasWeapon(int client, const char weapon[32]) {     // Get all of client's current weapons.     int weapons[WeaponsSlot][WEAPONS_ON_SLOTS_MAX];     WeaponsGetClientWeapons(client, weapons);       char classname[64];          // x = slot index     for (int x = 0; x < WEAPONS_SLOTS_MAX; x++)     {         for(int w = 0;w < WEAPONS_ON_SLOTS_MAX;w++)          {             // If slot is empty or is 0(WORLD index) then stop.             if (weapons[x][w] <= 0)              {                 continue;             }                         // Use the weapon index to get her name (weapon_...)             GetEdictClassname(weapons[x][w], classname, sizeof(classname));             // Now give the user item back              GivePlayerItem(client, classname);             // Debug for test             PrintToChat(client,"[DEBUG] User weapon %s , weapon to check for : %s",classname,weapon);             // If the weapon's classname matches, then return true.             if (StrEqual(weapon, classname, false))             {                 return true;             }         }     }        return false; }

Not sure what you've changed, but now the grenades are being detected

[ShD3luxe]

Try changing it to this :

PHP Code:

#define WEAPONS_SLOTS_MAX 6 // from 5 to 6

enum WeaponsSlot
{
    Slot_Invalid        = -1,   /** Invalid weapon (slot). */
    Slot_Primary        = 0,    /** Primary weapon slot. */
    Slot_Secondary      = 1,    /** Secondary weapon slot. */
    Slot_Melee          = 2,    /** Melee (knife) weapon slot. */
    Slot_Projectile     = 3,    /** Projectile (grenades, flashbangs, etc) weapon slot. */
    Slot_Explosive      = 4,    /** Explosive (c4) weapon slot. */
    Slot_NVGs          = 5,    /** NVGs (fake) equipment slot. */ // and this new slot
}; 


Question : What key do you press to change to the healthshot ? 6? I'm not sure why but in the wiki it says that the healthshot is in the c4 slot (lol) .

[Ilusion9]

Use this to check if a client has certain weapons

PHP Code:


    int size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");
    
    for (int i= 0; i < m_hMyWeapons_size; i++) 
    { 
        int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i); 

        if (item != -1) 
        { 
            char classname[64];
            GetEntityClassname(item, classname, sizeof(classname));
        } 
    } 


[JoaoRodrigoGamer]

Originally Posted by ShD3luxe Try changing it to this : PHP Code: #define WEAPONS_SLOTS_MAX 6 // from 5 to 6 enum WeaponsSlot {     Slot_Invalid        = -1,   /** Invalid weapon (slot). */     Slot_Primary        = 0,    /** Primary weapon slot. */     Slot_Secondary      = 1,    /** Secondary weapon slot. */     Slot_Melee          = 2,    /** Melee (knife) weapon slot. */     Slot_Projectile     = 3,    /** Projectile (grenades, flashbangs, etc) weapon slot. */     Slot_Explosive      = 4,    /** Explosive (c4) weapon slot. */     Slot_NVGs          = 5,    /** NVGs (fake) equipment slot. */ // and this new slot };

Unfortunately, the code did not change anything.

僕の kill‎ : !test
[DEBUG] User weapon weapon_glock , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_knife , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_taser , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_tagrenade , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_hegrenade , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_flashbang , weapon to check for : weapon_healthshot
[DEBUG] User weapon weapon_c4 , weapon to check for : weapon_healthshot

Originally Posted by ShD3luxe Question : What key do you press to change to the healthshot ? 6? I'm not sure why but in the wiki it says that the healthshot is in the c4 slot (lol) .

When I'm playing, I use the mouse scroll, but the in-game shortcut is "X".
6 to 0 is to select an individual type of grenade, like: he, flashbang, smoke, etc...

[ShD3luxe]

Originally Posted by Ilusion9 Use this to check if a client has certain weapons PHP Code:     int size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");          for (int i= 0; i < m_hMyWeapons_size; i++)      {          int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);          if (item != -1)          {              char classname[64];             GetEntityClassname(item, classname, sizeof(classname));         }      }

Will this return all the weapons even if the player has more than one in one slot ?

Also this as a function :

PHP Code:

stock bool ClientHasWeapon(int client, const char weapon[32])
{
    int size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");
    for (int i= 0; i < size; i++) 
    { 
        int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i); 
        if (item != -1) 
        { 
            char classname[64];
            GetEntityClassname(item, classname, sizeof(classname));
            if(StrEqual(weapon, classname, false))
            {
                return true;
            }
        } 
    }  
    return false;
} 


[JoaoRodrigoGamer]

Originally Posted by Ilusion9 Use this to check if a client has certain weapons PHP Code:     int size = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");          for (int i= 0; i < m_hMyWeapons_size; i++)      {          int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);          if (item != -1)          {              char classname[64];             GetEntityClassname(item, classname, sizeof(classname));         }      }

Can you please explain how that code works and how can it be applied to, for example, find if the player has a health shot?

[Ilusion9]

PHP Code:


stock bool HasWeapon(int client, const char[] weapon)
{
    int length = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons"); 
     
    for (int i= 0; i < length; i++)  
    {  
        int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);  

        if (item != -1)  
        {  
            char classname[64]; 
            
            if (GetEntityClassname(item, classname, sizeof(classname)))
            {
                if (StrEqual(weapon, classname, false))
                {
                    return true;
                }
            }
        }  
    } 

    return false;
}

if (HasWeapon(client, "weapon_healthshot"))
{
    // do something
} 


[JoaoRodrigoGamer]

Originally Posted by Ilusion9 PHP Code: stock bool HasWeapon(int client, const char[] weapon) {     int length = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");            for (int i= 0; i < length; i++)       {           int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);           if (item != -1)           {               char classname[64];                           if (GetEntityClassname(item, classname, sizeof(classname)))             {                 if (StrEqual(weapon, classname, false))                 {                     return true;                 }             }         }       }      return false; } if (HasWeapon(client, "weapon_healthshot")) {     // do something }

I just tested your code with this plugin and it seems to be working just fine

Also, I used this simple plugin to test your code:

PHP Code:

#pragma semicolon 1

#define DEBUG

#define PLUGIN_AUTHOR ""
#define PLUGIN_VERSION "0.00"

#include <sourcemod>
#include <sdktools>

#pragma newdecls required

public Plugin myinfo = 
{
    name = "",
    author = PLUGIN_AUTHOR,
    description = "",
    version = PLUGIN_VERSION,
    url = ""
};

public void OnPluginStart()
{
    RegConsoleCmd("sm_check", check);
}

public Action check(int client, int agrs)
{
    if (HasWeapon(client, "weapon_healthshot")) 
    { 
        PrintCenterText(client, "Has healthshot");
    }
    else
    {
        PrintCenterText(client, "Does not have a healthshot");
    }
}

stock bool HasWeapon(int client, const char[] weapon) 
{ 
    int length = GetEntPropArraySize(client, Prop_Send, "m_hMyWeapons");  
      
    for (int i= 0; i < length; i++)   
    {   
        int item = GetEntPropEnt(client, Prop_Send, "m_hMyWeapons", i);   

        if (item != -1)   
        {   
            char classname[64];  
             
            if (GetEntityClassname(item, classname, sizeof(classname))) 
            { 
                if (StrEqual(weapon, classname, false)) 
                { 
                    return true; 
                } 
            } 
        }   
    }  

    return false; 
} 


[JoaoRodrigoGamer]

Originally Posted by Ilusion9 Use this to check if a client has certain weapons

Yeah, your code works just fine

Thank you all for your help!