[phayzee]

Hi.

I'm trying to find out if there's any way to check if a player sends some specific commands (+jump, -jump, +moveleft, +moveright, etc.).

This is what I tried so far, but it doesn't seem to work as it print nothing to the console.

PHP Code:

#include <amxmodx>

public plugin_init() {
    register_plugin("Log commands", "0.1", "tester");

    register_clcmd("+jump", "jumpExecuted");
    register_clcmd("-jump", "jumpTerminated");
}

public jumpExecuted(id) {
    console_print(id, "+jump executed");

    return PLUGIN_HANDLED;
}

public jumpTerminated(id) {
    console_print(id, "-jump executed");

    return PLUGIN_HANDLED;
} 


[jimaway]

/**
     * Description:     Typically called every frame when a player has jump held.
     * Forward params:  function(this)
     * Return type:     None.
     * Execute params:  ExecuteHam(Ham_Player_Jump, this);
     */
    Ham_Player_Jump,

    /**
     * Description:     Typically called every frame when a player has duck held.
     *                  This function is not supported in Earth's Special Forces mod.
     * Forward params:  function(this)
     * Return type:     None.
     * Execute params:  ExecuteHam(Ham_Player_Duck, this);
     */
    Ham_Player_Duck

[phayzee]

That seems good, for now.
1. But what about the corresponding -command for each of them? How can I see when is that called (-jump, -duck, for example)

2. Is there anything similar for +moveright, +moveleft, +forward, +back etc. ? Or for any other commands that might exist (+speed, +use, etc.)

[Mistrick]

PHP Code:

#include <amxmodx>
#include <fakemeta>

public plugin_init()
{
    register_forward(FM_PlayerPreThink, "FM_PlayerPreThink_Pre", false);
}
public FM_PlayerPreThink_Pre(id)
{
    new buttons, old_buttons;
    buttons = pev(id, pev_button);
    old_buttons = pev(id, pev_oldbuttons);

    if(buttons & IN_BACK && ~old_buttons & IN_BACK) {
        client_print(id, print_chat, "BACK Pressed");
    }
    
    if(buttons & IN_BACK) {
        client_print(id, print_chat, "BACK Active");
    }
    
    if(~buttons & IN_BACK && old_buttons & IN_BACK) {
        client_print(id, print_chat, "BACK Released");
    }
} 


Change IN_BACK to another constant to check another button. Don't work for +speed.

[MrPickles]

PHP Code:

if(entity_get_int( Client, EV_INT_button ) & 2 ) // Holding Jump
if(!entity_get_int( Client, EV_INT_button ) & 2 ) // Not Holding Jump

if(entity_get_int( Client, EV_INT_button ) & 4 ) // Holding Duck

/*
    0 - IDLE
    1 - MOUSE1
    2048 - MOUSE2
    512 - MOVE LEFT
    1024 - MOVE RIGHT
    8 - MOVE FORWARD
    16 - MOVE BACKWARDS
    2 - JUMP
    4 - CTRL
    32768 - TAB
    8192 - RELOAD
    32 - USE       */ 


[fysiks]

Originally Posted by MrPickles PHP Code: if(!entity_get_int( Client, EV_INT_button ) & 2 ) // Not Holding Jump

When negating a value being used to store bit-wise values, you should use a tilde (~) instead of an exclamation (!).

PHP Code:

if( ~entity_get_int( Client, EV_INT_button ) & 2 ) // Not Holding Jump 


Alternatively, you can force the bitwise comparison to occur first and then you can use the exclamation:

PHP Code:

if( !(entity_get_int( Client, EV_INT_button ) & 2) ) // Not Holding Jump 


[MrPickles]

Originally Posted by fysiks When negating a value being used to store bit-wise values, you should use a tilde (~) instead of an exclamation (!). PHP Code: if( ~entity_get_int( Client, EV_INT_button ) & 2 ) // Not Holding Jump

PHP Code:

if( ~entity_get_int( Client, EV_INT_button ) & 2 ) // Not Holding Jump 


=>

PHP Code:

if( entity_get_int( Client, EV_INT_button ) & ~2 ) // Not Holding Jump 


============================================

PHP Code:

if( !(entity_get_int( Client, EV_INT_button ) & 2) ) // Not Holding Jump 


and yes, i forget the () before the exclamation

[fysiks]

Originally Posted by MrPickles PHP Code: if( entity_get_int( Client, EV_INT_button ) & ~2 ) // Not Holding Jump

No. Doing the bitwise NOT on the 2 will not work, you must do it how I wrote. This is what will happen:

   0b11010101 (buttons value with second bit not set)
 & 0b11111101 (~2)
 = 0b11010101 (evalutates as true)


   0b11010111 (buttons value with second bit set)
 & 0b11111101 (~2)
 = 0b11010101 (same exact result as above)

As you can see, it will return true for both pressed and not pressed except when no other buttons are pressed which cannot be guaranteed (which is why the buttons are stored in bitwise fashion).