[Shadowysn]

SOLVED: The solution was to do this:

Spoiler

PHP Code:

void SpawnPack(int client)
{
    int pack = CreateEntityByName("item_healthkit_small");
    DispatchKeyValue(pack, "AutoMaterialize", "0");
    DispatchKeyValue(pack, "velocity", "0.0 0.0 1.0");
    DispatchKeyValue(pack, "basevelocity", "0.0 0.0 1.0");
    //DispatchKeyValue(pack, "nextthink", "-1");
    //SetEntPropEnt(pack, Prop_Data, "m_hOwner", client);
    
    float cl_pos[3];
    GetClientEyePosition(client, cl_pos);
    
    //float pack_vel[3]; pack_vel = (view_as<float>({0.0, 0.0, -1.0})); // A little bit of velocity is required to wake it up
    
    TeleportEntity(pack, cl_pos, NULL_VECTOR, NULL_VECTOR);
    
    SetEntProp(pack, Prop_Data, "m_bActivateWhenAtRest", 1);
    //SetEntProp(pack, Prop_Data, "m_nNextThinkTick", -1);
    SetEntProp(pack, Prop_Send, "m_ubInterpolationFrame", 0);
    SetEntPropEnt(pack, Prop_Send, "m_hOwnerEntity", client);
    SetEntityGravity(pack, 1.0);
    
    //SetEntProp(pack, Prop_Send, "m_nNextThinkTick", client);
    
    DispatchSpawn(pack);
    ActivateEntity(pack);
    
    DispatchKeyValue(pack, "nextthink", "0.1"); // The fix to the laggy physics. This is what you're looking for on the forum.
    //SetEntProp(pack, Prop_Send, "movetype", MOVETYPE_FLYGRAVITY);
    //SetEntProp(pack, Prop_Data, "m_MoveType", MOVETYPE_FLYGRAVITY);
    
    SetVariantString("OnPlayerTouch !self:Kill::0:-1");
    AcceptEntityInput(pack, "AddOutput");
    
    SetVariantString("OnUser1 !self:Kill::30.0:-1");
    AcceptEntityInput(pack, "AddOutput");
    AcceptEntityInput(pack, "FireUser1");
    
    RequestFrame(SpawnPack_FrameCallback, pack); // Have to change movetype in a frame callback
}

void SpawnPack_FrameCallback(int pack)
{
    if (!IsValidEntity(pack) || pack < 1) return;
    
    SetEntityMoveType(pack, MOVETYPE_FLYGRAVITY);
    SetEntProp(pack, Prop_Send, "movecollide", 1); // These two...
    SetEntProp(pack, Prop_Data, "m_MoveCollide", 1); // ...allow the pack to bounce.
} 


I'm trying to find a way to spawn a physics-affected health pack, like the ones dropped by players when killed in Medieval Mode or by a candy cane Scout.
Preferably within the boundaries of normal Sourcemod entity-spawning of CreateEntityByName and such.


So far, I got it to work except for one crucial thing:
The physics are updating in just half-seconds, resulting in it being slow and laggy.

Spoiler

PHP Code:

#pragma newdecls required
#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
//#include <sdkhooks>
//#include <tf2_stocks>

#define PLUGIN_NAME "[TF2] Spawn Physics-Affected Health Kit"
#define PLUGIN_AUTHOR "Shadowysn"
#define PLUGIN_DESC "Spawn a physics-affected health pack drop."
#define PLUGIN_VERSION "1.0.0"
#define PLUGIN_URL ""
#define PLUGIN_NAME_SHORT "Spawn Physics-Affected Health Kit"
#define PLUGIN_NAME_TECH "phys_healthkit"

#define CMD_INVALID_CL "[SM] Invalid client!"
#define CMD_DEAD_CL "[SM] Client is not a living player!"

#define cmd_1 "sm_spawnphyspack"
#define cmd_1_desc "%s <client> - Spawn pack on player. If not defined, will spawn on you instead."

public Plugin myinfo = 
{
    name = PLUGIN_NAME,
    author = PLUGIN_AUTHOR,
    description = PLUGIN_DESC,
    version = PLUGIN_VERSION,
    url = PLUGIN_URL
}

public void OnPluginStart()
{
    char temp_str[512];
    Format(temp_str, sizeof(temp_str), cmd_1_desc, cmd_1);
    RegAdminCmd(cmd_1, Cmd_Act_SpawnPack, ADMFLAG_CHEATS, temp_str);
    
    LoadTranslations("common.phrases");
}

Action Cmd_Act_SpawnPack(int client, int args)
{
    if (!IsValidClient(client))
    { return Plugin_Handled; }
    
    if (args < 1)
    {
        //ReplyToCommand(client, "[SM] Pack spawned on yourself.");
        
        Cmd_SpawnPack(client, client);
        return Plugin_Handled;
    }
    else if (args > 1)
    {
        ReplyToCommand(client, cmd_1_desc);
        return Plugin_Handled;
    }
    
    char arg[256];
    GetCmdArg(1, arg, sizeof(arg));
    
    int target_list[MAXPLAYERS];
    int target_count = Cmd_GetTargets(client, arg, target_list);
    
    for (int i=0; i < target_count; i++)
    {
        int target = target_list[i];
        
        Cmd_SpawnPack(target, client);
    }
    
    return Plugin_Handled;
}

void Cmd_SpawnPack(int target, int client)
{
    if (!Cmd_CheckClient(target, client, false)) return;
    
    SpawnPack(target);
}

void SpawnPack(int client)
{
    int pack = CreateEntityByName("item_healthkit_small");
    DispatchKeyValue(pack, "AutoMaterialize", "0");
    //DispatchKeyValue(pack, "nextthink", "-1");
    //SetEntPropEnt(pack, Prop_Data, "m_hOwner", client);
    
    float cl_pos[3];
    GetClientEyePosition(client, cl_pos);
    
    float pack_vel[3]; pack_vel = (view_as<float>({0.0, 0.0, -1.0})); // A little bit of velocity is required to wake it up
    
    TeleportEntity(pack, cl_pos, NULL_VECTOR, pack_vel);
    
    SetEntProp(pack, Prop_Data, "m_bActivateWhenAtRest", 1);
    //SetEntProp(pack, Prop_Data, "m_nNextThinkTick", -1);
    SetEntProp(pack, Prop_Send, "m_ubInterpolationFrame", 0);
    SetEntPropEnt(pack, Prop_Send, "m_hOwnerEntity", client);
    SetEntityGravity(pack, 1.0);
    
    DispatchSpawn(pack);
    ActivateEntity(pack);
    
    //SetEntProp(pack, Prop_Send, "movetype", MOVETYPE_FLYGRAVITY);
    //SetEntProp(pack, Prop_Data, "m_MoveType", MOVETYPE_FLYGRAVITY);
    
    SetVariantString("OnPlayerTouch !self:Kill::0:-1");
    AcceptEntityInput(pack, "AddOutput");
    
    SetVariantString("OnUser1 !self:Kill::30.0:-1");
    AcceptEntityInput(pack, "AddOutput");
    AcceptEntityInput(pack, "FireUser1");
    
    RequestFrame(SpawnPack_FrameCallback, pack); // Have to change movetype in a frame callback
}

void SpawnPack_FrameCallback(int pack)
{
    if (!IsValidEntity(pack) || pack < 1) return;
    
    SetEntityMoveType(pack, MOVETYPE_FLYGRAVITY);
    SetEntProp(pack, Prop_Send, "movecollide", 1); // These two...
    SetEntProp(pack, Prop_Data, "m_MoveCollide", 1); // ...allow the pack to bounce.
}

bool Cmd_CheckClient(int client, int sender = -1, bool must_be_alive = false, int must_be_survivor = -1, bool print = true)
{
    if (!IsValidClient(client))
    { if (print && IsValidClient(sender)) PrintToChat(sender, CMD_INVALID_CL); return false; }
    
    if (must_be_alive && (!IsPlayerAlive(client) || IsClientObserver(client)))
    { if (print && IsValidClient(sender)) PrintToChat(sender, CMD_DEAD_CL); return false; }
    
    /*if (must_be_survivor > 0)
    {
        if (!IsSurvivor(client))
        { if (print && IsValidClient(sender)) PrintToChat(sender, CMD_NOT_SURVIVOR_CL); return false; }
    }
    else if (must_be_survivor == 0)
    {
        if (!IsInfected(client))
        { if (print && IsValidClient(sender)) PrintToChat(sender, CMD_NOT_INFECTED_CL); return false; }
    }*/
    
    return true;
}

int Cmd_GetTargets(int client, const char[] arg, int[] target_list, int filter = COMMAND_FILTER_ALIVE)
{
    char target_name[MAX_TARGET_LENGTH];
    int target_count;
    bool tn_is_ml;
    if ((target_count = ProcessTargetString(
            arg,
            client,
            target_list,
            MAXPLAYERS,
            filter,
            target_name,
            sizeof(target_name),
            tn_is_ml)) <= 0)
    { ReplyToTargetError(client, target_count); return -1; }
    return target_count;
}

bool IsValidClient(int client, bool replaycheck = true)
{
    if (client <= 0 || client > MaxClients) return false;
    if (!IsClientInGame(client)) return false;
    if (GetEntProp(client, Prop_Send, "m_bIsCoaching")) return false;
    if (replaycheck)
    {
        if (IsClientSourceTV(client) || IsClientReplay(client)) return false;
    }
    return true;
} 


[nosoop]

The robust way would be an SDKCall on either CTFPowerup::DropSingleInstance() (applied to your health / ammo pack), or CTFPlayer::DropHealthPack() (which calls the former internally).

Internally, it sets MOVETYPE_FLYGRAVITY and MOVECOLLIDE_FLY_BOUNCE and a few other properties, including removing itself after some time and setting the owner.

[Shadowysn]

Originally Posted by nosoop The robust way would be an SDKCall on either CTFPowerup::DropSingleInstance() (applied to your health / ammo pack), or CTFPlayer::DropHealthPack() (which calls the former internally). Internally, it sets MOVETYPE_FLYGRAVITY and MOVECOLLIDE_FLY_BOUNCE and a few other properties, including removing itself after some time and setting the owner.

Yeah, but that does require a signature.
I know I said 'screw it, go full sig', but my mind is kind of inconsistent. :I

If 1 week goes by and there still hasn't been a solution to this without using one, I'll mark this as Solved and use a signature instead.