[Help] Distance between player and object

kiryxa · **Author**

[en]
Hi!. I want to exist between player and object "Sandbags"(max radius, when the player puts sundbags).

PHP Code:


			
get_entity_distance(id,ent)

not suitable, because the object did not exist yet.
How can this be done?

[ru]
Привет,я хочу,чтобы был максимальный радиус,куда можно поставить мешки с песком,

PHP Code:


			
get_entity_distance(id,ent)

не подходит,так как обьект еще не существует-он работает-только тогда,когда он создался(то есть как я уже поставил сам мешок).Как можно реализовать проверку на этот радиус?

Code/Код:

PHP Code:


			
public Place_sandbags(id)
{
    if(palletscout == get_pcvar_num(Max_Num_Pallets))
        return PLUGIN_HANDLED;
        
    
        /* Не подходит
        new units = get_entity_distance(id,ent)
    
    if(units >= 100.0)
    {
        client_print(id,print_chat,"Нельзя больше")
        return PLUGIN_HANDLED;
    }
        */
    
    ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "func_wall"));
    
    set_pev(ent,pev_classname,"amxx_pallets");
            
    engfunc(EngFunc_SetModel,ent, PALLET_MODEL);
    
    static Float:xorigin[3];
    get_user_hitpoint(id,xorigin);
    
    if(engfunc(EngFunc_PointContents,xorigin) == CONTENTS_SKY)
        return PLUGIN_HANDLED
    
    static Float:p_mins[3], Float:p_maxs[3];
    p_mins = PALLET_MINS;
    p_maxs = PALLET_MAXS;
    engfunc(EngFunc_SetSize, ent, p_mins, p_maxs);
    set_pev(ent, pev_mins, p_mins);
    set_pev(ent, pev_maxs, p_maxs );
    set_pev(ent, pev_absmin, p_mins);
    set_pev(ent, pev_absmax, p_maxs );

    engfunc(EngFunc_SetOrigin, ent, xorigin);

    set_pev(ent,pev_solid,SOLID_BBOX)
    set_pev(ent,pev_movetype,MOVETYPE_FLY)
    
    new Float:p_cvar_health = get_pcvar_float(Health_Pallets);
    
    switch(p_cvar_health)
    {
        case 0.0 :
        {
            set_pev(ent,pev_takedamage,DAMAGE_NO);
        }
        
        default :
        {
            set_pev(ent,pev_health,p_cvar_health);
            set_pev(ent,pev_takedamage,DAMAGE_YES);
        }
    }
    
    static Float:rvec[3];
    pev(id,pev_v_angle,rvec);
    
    rvec[0] = 0.0;
    
    set_pev(ent,pev_angles,rvec);
    
    fm_drop_to_floor(ent);
    
    palletscout++;
    
    return PLUGIN_HANDLED;
}

Thanks!

ConnorMcLeod · 02-03-2014 , 13:17 Re: [Help] Distance between player and object

Show get_user_hitpoints function or make it return the distance, and call it before create_entity, so you can, if distance is too short, abort the creation.

kiryxa · 02-03-2014 , 13:25 Re: [Help] Distance between player and object

The stock "get_user_hitpoint":

PHP Code:


			
stock get_user_hitpoint(id, Float:hOrigin[3]) 

{

    if ( ! is_user_alive( id ))

        return 0;

    

    new Float:fOrigin[3], Float:fvAngle[3], Float:fvOffset[3], Float:fvOrigin[3], Float:feOrigin[3];

    new Float:fTemp[3];

    

    pev(id, pev_origin, fOrigin);

    pev(id, pev_v_angle, fvAngle);

    pev(id, pev_view_ofs, fvOffset);

    

    xs_vec_add(fOrigin, fvOffset, fvOrigin);

    

    engfunc(EngFunc_AngleVectors, fvAngle, feOrigin, fTemp, fTemp);

    

    xs_vec_mul_scalar(feOrigin, 9999.9, feOrigin);

    xs_vec_add(fvOrigin, feOrigin, feOrigin);

    

    engfunc(EngFunc_TraceLine, fvOrigin, feOrigin, 0, id);

    global_get(glb_trace_endpos, hOrigin);

    

    return 1;

}

ConnorMcLeod · 02-03-2014 , 16:42 Re: [Help] Distance between player and object

Try :

PHP Code:


			
get_user_hitpoint(id, Float:hOrigin[3], Float:fDistance)  

{ 

    if ( ! is_user_alive( id )) 

        return 0; 

     

    new Float:fOrigin[3], Float:feOrigin[3]; 



    pev(id, pev_origin, fOrigin);

    velocity_by_aim(id, 9999, feOrigin);



    xs_vec_add(fOrigin, feOrigin, feOrigin); 



    trace_line(id, fOrigin, feOrigin, hOrigin);



    fDistance = get_distance_f(fOrigin, hOrigin);



    return 1; 

}

kiryxa · 02-04-2014 , 01:29 Re: [Help] Distance between player and object

ConnorMcLeod
Ok, i try your code,but where i have to do the check of distance?

PHP Code:


			
    static Float:xorigin[3];

    new Float:fDistance;

    get_user_hitpoint(id,xorigin, fDistance);

    

    if(engfunc(EngFunc_PointContents,xorigin) == CONTENTS_SKY)

        return PLUGIN_HANDLED

        

    if (fDistance > 50.0)

        return PLUGIN_HANDLED

It does not work.How to do it correctly?

ConnorMcLeod · 02-04-2014 , 01:58 Re: [Help] Distance between player and object

Try to print the distance in chat so you can figure out if result is relevant or not.
50 is really short, a player is 64.

May be you want :

PHP Code:


			
    get_user_hitpoint(id,xorigin, fDistance); 

    client_print(id, print_chat, "Distance is %.1 units", fDistance);

    if (fDistance < 50.0) // < (you did >)

        return PLUGIN_HANDLED;



    if(engfunc(EngFunc_PointContents,xorigin) == CONTENTS_SKY) 

        return PLUGIN_HANDLED;

kiryxa · *Last edited by kiryxa; 02-04-2014 at 02:43.*

Okey,So what I want on screen:

The check does not work,bags puts all the same where x-->bag:

PHP Code:


			
public Place_sandbags(id)
{
    if(palletscout == get_pcvar_num(Max_Num_Pallets))
        return PLUGIN_HANDLED;
    
    ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "func_wall"));
    
    set_pev(ent,pev_classname,"amxx_pallets");
            
    engfunc(EngFunc_SetModel,ent, PALLET_MODEL);
    
    static Float:xorigin[3];
    new Float:fDistance;
    get_user_hitpoint(id,xorigin, fDistance);
    
    if (fDistance > 300.0)
    {
        client_print(id, print_chat, "Distance is %.1f units", fDistance); 
        return PLUGIN_HANDLED;
    }
    
    if(engfunc(EngFunc_PointContents,xorigin) == CONTENTS_SKY)
        return PLUGIN_HANDLED
    
        // other code
}

Also, the compiler says:
D:\Server\ZP4.3\cstrike\addons\amxmodx\script ing\zp_test.sma(236) : warning 2 04: symbol is assigned a value that is never used: "fDistance"
in this code:

PHP Code:


			
get_user_hitpoint(id, Float:hOrigin[3], Float:fDistance)   
{  
    if ( ! is_user_alive( id ))  
        return 0;  
      
    new Float:fOrigin[3], Float:feOrigin[3];  

    pev(id, pev_origin, fOrigin); 
    velocity_by_aim(id, 9999, feOrigin); 

    xs_vec_add(fOrigin, feOrigin, feOrigin);  

    trace_line(id, fOrigin, feOrigin, hOrigin); 

    fDistance = get_distance_f(fOrigin, hOrigin); 

    return 1;  
}

ConnorMcLeod · *Last edited by ConnorMcLeod; 02-04-2014 at 15:35.*

Oh, add '&' in front of 'Float:fDistance'

-> get_user_hitpoint(id, Float:hOrigin[3], &Float:fDistance)

avril-lavigne · *Last edited by avril-lavigne; 02-04-2014 at 16:28.*

distance between =

static iTarget, iBody
get_user_aiming(id, iTarget, iBody)

or

get_user_aiming(id, iTarget, iBody, 900) // 900 units of max distance

// 900 юнитов максимальное расстояние на котором будет действовать условие.

iTarget - enemy or something .

kiryxa · *Last edited by kiryxa; 02-05-2014 at 00:38.*

Thanks a lot,but:

PHP Code:


			
stock get_user_hitpoint(id, Float:hOrigin[3]) 
{
    if ( ! is_user_alive( id ))
        return 0;
    
    new Float:fOrigin[3], Float:fvAngle[3], Float:fvOffset[3], Float:fvOrigin[3], Float:feOrigin[3];
    new Float:fTemp[3];
    
    pev(id, pev_origin, fOrigin);
    pev(id, pev_v_angle, fvAngle);
    pev(id, pev_view_ofs, fvOffset);
    
    xs_vec_add(fOrigin, fvOffset, fvOrigin);
    
    engfunc(EngFunc_AngleVectors, fvAngle, feOrigin, fTemp, fTemp);
    
    xs_vec_mul_scalar(feOrigin, 9999.9, feOrigin);
    xs_vec_add(fvOrigin, feOrigin, feOrigin);
    
    engfunc(EngFunc_TraceLine, fvOrigin, feOrigin, 0, id);
    global_get(glb_trace_endpos, hOrigin);
    
    return 1;
}

PHP Code:


			
xs_vec_mul_scalar(feOrigin, 9999.9, feOrigin);

where 9999.9-this is max radius,i did not know about this.