[OnePL]

Error logs:

L 01/30/2014 - 20:32:35: [AMXX] Displaying debug trace (plugin "ruletka.amxx", version "1.2.6")
L 01/30/2014 - 20:32:35: [AMXX] Run time error 10: native error (native "pev")
L 01/30/2014 - 20:32:35: [AMXX]    [0] Untitled.sma::pfn_touch (line 934)
L 01/30/2014 - 20:32:35: [FAKEMETA] Invalid entity

Code:

PHP Code:

public pfn_touch(ptr, ptd) {
    if(!ptd) return 0;

    new szClassName[32]; pev(ptd, pev_classname, szClassName, 31);

    if(ptr) {
        new szClassNameOther[32]; pev(ptr, pev_classname, szClassNameOther, 31);

        if(equal(szClassName, "grenade") && equal(szClassNameOther, "player")) {
            new greModel[64]; pev(ptd, pev_model, greModel, 63);

            if(equali(greModel, "models/w_smokegrenade.mdl")) {
                new id = pev(ptd, pev_owner);

                if(is_user_alive(id) && is_user_alive(ptr) && SmiertelneSmoke[id] && get_user_team(id) != get_user_team(ptr) && pev(ptr, pev_takedamage) != 0.0) {
                    //ExecuteHamB(Ham_Killed, ptr, id, 0);
                    set_pev(id, pev_frags, float(pev(id, pev_frags)) + 1);

                    user_silentkill(ptr);
                    message_begin(2, 83, {0, 0, 0}, 0);
                    write_byte(id);
                    write_byte(ptr);
                    write_byte(0);
                    write_string("world");
                    message_end();

                    message_begin(2, 85);
                    write_byte(id);
                    write_short(pev(id, pev_frags));
                    write_short(get_user_deaths(id));
                    write_short(0);
                    write_short(get_user_team(id));
                    message_end();

                    message_begin(2, 85);
                    write_byte(ptr);
                    write_short(pev(ptr, pev_frags));
                    write_short(get_user_deaths(ptr));
                    write_short(0);
                    write_short(get_user_team(ptr));
                    message_end();
                }
            }
        }
    }
    return 0;
} 


line 934:

PHP Code:

new szClassNameOther[32]; pev(ptr, pev_classname, szClassNameOther, 31); 


[ConnorMcLeod]

line 934 is not the one you gave.
Would be better to use register_touch rather that pfn_touch, so entities would be filtered directly in engine module.

Try this (you need amxx1.8.3 to compile and to run) :

Spoiler

PHP Code:

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < hamsandwich >

#pragma semicolon 1

#define PLUGIN ""
#define VERSION "0.0.1"

#define cm(%0)    ( sizeof(%0) - 1 )

const m_bIsC4 = 385;
const m_usEvent_Grenade = 228;

new gmsgDeathMsg;

new SmiertelneSmoke[33];

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );

    gmsgDeathMsg = get_user_msgid("DeathMsg");
    register_touch("grenade", "player", "OnGrenadeTouchPlayer");
}

public OnGrenadeTouchPlayer(nade, player)
{
    if( is_user_alive(player) && GetGrenadeType(nade) == CSW_SMOKEGRENADE )
    {
        new id = entity_get_edict(nade, EV_ENT_owner);
        if( SmiertelneSmoke[id] && is_user_alive(id) && get_user_team(id) != get_user_team(player) && entity_get_float(player, EV_FL_takedamage) != DAMAGE_NO)
        {
            new iMsgBlock = get_msg_block(gmsgDeathMsg);
            if( iMsgBlock == BLOCK_NOT )
            {
                set_msg_block(gmsgDeathMsg, BLOCK_ONCE);
            }
            user_kill(player);
            if( iMsgBlock == BLOCK_ONCE )
            {
                set_msg_block(gmsgDeathMsg, iMsgBlock);
            }

            message_begin(MSG_ALL, gmsgDeathMsg);
            write_byte(id);
            write_byte(player);
            write_byte(0);
            write_string("world");
            message_end();

            ExecuteHam(Ham_AddPoints, id, 1, 1); // add 1 frag and update scoreboard
            ExecuteHam(Ham_AddPoints, player, 0, 1); // update scoreboard
        }
    }
}

GetGrenadeType( ent, bool:bCheckClass = true )
{
    if( bCheckClass )
    {
        new class[9];
        pev(ent, pev_classname, class, charsmax(class));
        if( !equal(class, "grenade") )
        {
            return 0;
        }
    }

    if( get_pdata_bool(ent, m_bIsC4) )
    {
        return CSW_C4;
    }

    new usEvent = get_pdata_short(ent, m_usEvent_Grenade);
    if( !usEvent )
    {
        return CSW_FLASHBANG;
    }

    static m_usHgrenExplo; // , m_usSmokeExplo
    if( !m_usHgrenExplo )
    {
        m_usHgrenExplo = engfunc(EngFunc_PrecacheEvent, 1, "events/createexplo.sc");
        // m_usSmokeExplo = engfunc(EngFunc_PrecacheEvent, 1, "events/createsmoke.sc");
    }

    return usEvent == m_usHgrenExplo ? CSW_HEGRENADE : CSW_SMOKEGRENADE;
} 


[OnePL]

Thanks, solved