[midnight9]

Hello! Im using SetClientName to change players name and im wondering if there is a way to do it without in chat name change announcement.

[sdz]

PHP Code:

#include <sourcemod>

public void OnPluginStart()
{
    //This hooks the event, we'll implement a listener for it.
    bool exists = HookEventEx("player_changename", Event_NameChanged, EventHookMode_Pre);
    if(!exists) SetFailState("[SM] SetFailState: player_changename event does not exist. Unloading...");
}

public Action Event_NameChanged(Event event, const char[] name, bool dontBroadcast)
{
    //This gets the client's user ID then translates it to a client index
    int client = GetClientOfUserId(event.GetInt("userid"));

    //Validity of client
    if(client > MaxClients || client < 1) return Plugin_Continue;
    if(!IsClientConnected(client) || !IsClientInGame(client)) return Plugin_Continue;

    //Get the new name of client
    char newName[MAX_NAME_LENGTH];
    event.GetString("newname", newName, sizeof(newName));
    
    if(StrContains(newName, "[AFK]", false) != -1 || StrContains(newName, "[CRASHED]", false) != -1) 
    {
        SetClientName(client, "hot");
        SetEventBroadcast(event, true);
        PrintToChatAll("asd");
        return Plugin_Handled;
    }

    else return Plugin_Continue;
}

public Plugin myinfo = 
{
    name = "Block Namechange Message",
    author = "Sidezz",
    description = "Stuff for people",
    version = SOURCEMOD_VERSION,
    url = "http://www.coldcommunity.com"
}; 


[PinHeaDi]

You can just edit the normal rename.sp and remove that part.

[midnight9]

Hi, thanks for reply, i have allready tried player_changename event but it doesnt block any name change announcements at all.

[PinHeaDi]

Originally Posted by midnight9 Hi, thanks for reply, i have allready tried player_changename event but it doesnt block any name change announcements at all.

Try with the plugin I attached, it should work. The .SP is if you want to compile playercommands.smx by yourself.

[midnight9]

Originally Posted by PinHeaDi You can just edit the normal rename.sp and remove that part.

Sorry i didnt make it clear enough. Im using SetClientName in a simple plugin that automatically renames player upon connection. I want only remove remove notification when this plugin changes players name, any other name changes should be announced as normal.

[sdz]

Originally Posted by midnight9 Sorry i didnt make it clear enough. Im using SetClientName in a simple plugin that automatically renames player upon connection. I want only remove remove notification when this plugin changes players name, any other name changes should be announced as normal.

Then you could just have a client variable like g_Rename[client] = true; when the player joins, call SetClientName and in the name changed event you just check for the value of that variable

[midnight9]

I have allready thought of that so i just tried this:

#include <sourcemod>

public void OnPluginStart()
{
    //This hooks the event, we'll implement a listener for it.
    bool exists = HookEventEx("player_changename", Event_NameChanged, EventHookMode_Pre);
    if(!exists) SetFailState("[SM] SetFailState: player_changename event does not exist. Unloading...");
}

public Action Event_NameChanged(Event event, const char[] name, bool dontBroadcast)
{

    SetEventBroadcast(event, true);
    PrintToChatAll("asd");
    return Plugin_Handled;
}

to see if it will block all name changes but it doesnt.

[shavit]

i got you, fam

NAME_CHANGE_STRING will be different for games that aren't cs:s or cs:go

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

#define NAME_CHANGE_STRING "#Cstrike_Name_Change"

bool gB_HideNameChange = false;

public void OnPluginStart()
{
	RegConsoleCmd("sm_name", Command_Name);

	HookUserMessage(GetUserMessageId("SayText2"), Hook_SayText2, true);
}

public Action Command_Name(int client, int args)
{
	if(client == 0)
	{
		return Plugin_Handled;
	}

	char[] sArgs = new char[MAX_NAME_LENGTH];
	GetCmdArgString(sArgs, MAX_NAME_LENGTH);

	gB_HideNameChange = true; // do this whenever you want name changes to be silent
	SetClientName(client, sArgs);

	return Plugin_Handled;
}

public Action Hook_SayText2(UserMsg msg_id, any msg, const int[] players, int playersNum, bool reliable, bool init)
{
	if(!gB_HideNameChange)
	{
		return Plugin_Continue;
	}

	char[] sMessage = new char[24];

	if(GetUserMessageType() == UM_Protobuf)
	{
		Protobuf pbmsg = msg;
		pbmsg.ReadString("msg_name", sMessage, 24);
	}

	else
	{
		BfRead bfmsg = msg;
		bfmsg.ReadByte();
		bfmsg.ReadByte();
		bfmsg.ReadString(sMessage, 24, false);
	}

	if(StrEqual(sMessage, NAME_CHANGE_STRING))
	{
		gB_HideNameChange = false;

		return Plugin_Handled;
	}

	return Plugin_Continue;
}

[midnight9]

Originally Posted by shavit i got you, fam NAME_CHANGE_STRING will be different for games that aren't cs:s or cs:go #include <sourcemod> #include <sdktools> #pragma semicolon 1 #pragma newdecls required #define NAME_CHANGE_STRING "#Cstrike_Name_Change" bool gB_HideNameChange = false; public void OnPluginStart() { RegConsoleCmd("sm_name", Command_Name); HookUserMessage(GetUserMessageId("SayText2"), Hook_SayText2, true); } public Action Command_Name(int client, int args) { if(client == 0) { return Plugin_Handled; } char[] sArgs = new char[MAX_NAME_LENGTH]; GetCmdArgString(sArgs, MAX_NAME_LENGTH); gB_HideNameChange = true; // do this whenever you want name changes to be silent SetClientName(client, sArgs); return Plugin_Handled; } public Action Hook_SayText2(UserMsg msg_id, any msg, const int[] players, int playersNum, bool reliable, bool init) { if(!gB_HideNameChange) { return Plugin_Continue; } char[] sMessage = new char[24]; if(GetUserMessageType() == UM_Protobuf) { Protobuf pbmsg = msg; pbmsg.ReadString("msg_name", sMessage, 24); } else { BfRead bfmsg = msg; bfmsg.ReadByte(); bfmsg.ReadByte(); bfmsg.ReadString(sMessage, 24, false); } if(StrEqual(sMessage, NAME_CHANGE_STRING)) { gB_HideNameChange = false; return Plugin_Handled; } return Plugin_Continue; }

Hi, HookUserMessage works indeed. I did it in a different way but you gave me an idea of how to do it, thanks