Block weapon pickup

livingstone · **Author**

can any1 make plugin that will block pickup of weapons when player say /block

master4life · 03-25-2010 , 14:15 Re: Block weapon pickup

go try this

PHP Code:


			
#include < amxmodx >

#include < hamsandwich >



new bool: g_bEnable[ 32 ]; 



public plugin_init( ) {

    register_plugin( "Block Pickup", "0.1", "master4life" );

    

    register_clcmd( "say /block", "CmdBlockPickup" );

    

    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPlayerPickup" );

    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPlayerPickup" );

}



public client_putinserver( id )

    g_bEnable[ id ] = false;



public FwdHamPlayerPickup( iEntity, id )

    return g_bEnable[ id ] ? HAM_SUPERCEDE : HAM_IGNORED



public CmdBlockPickup( id )

    g_bEnable[ id ] = !g_bEnable[ id ];

DIREKTOR · 03-25-2010 , 14:21 Re: Block weapon pickup

my server wont run with this. as my friends server wont run with this

wrecked_ · 03-25-2010 , 15:27 Re: Block weapon pickup

Quote:

Originally Posted by DIREKTOR

my server wont run with this. as my friends server wont run with this

Code:

#include < amxmodx > 
#include < hamsandwich > 

new bool:g_bEnable[ 33 ];  

public plugin_init( )
{ 
    register_plugin( "Block Pickup", "0.1", "master4life" ); 
     
    register_clcmd( "say /block", "CmdBlockPickup" ); 
     
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPlayerPickup" ); 
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPlayerPickup" ); 
} 

public client_putinserver( id ) 
    g_bEnable[ id ] = false; 

public FwdHamPlayerPickup( iEntity, id ) 
    return g_bEnable[ id ] ? HAM_SUPERCEDE : HAM_IGNORED;

public CmdBlockPickup( id )
    /* g_bEnable[ id ] = !g_bEnable[ id ]; */
    /* Didn't know if it'd work, just to be safe */
    g_bEnable[ id ] = g_bEnable[ id ] ? false : true;

Exolent[jNr] · 03-25-2010 , 15:31 Re: Block weapon pickup

Quote:

Originally Posted by wrecked_

...

It works fine the way it was.

What I would do is make sure a player is touching the entities:

Code:

#include < amxmodx >
#include < hamsandwich >

// should be 33 with id as index,
// or use 32 with id-1 as index
new bool: g_bEnable[ 33 ];

new g_iMaxPlayers;

public plugin_init( ) {
    register_plugin( "Block Pickup", "0.1", "master4life" );
    
    register_clcmd( "say /block", "CmdBlockPickup" );
    
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPlayerPickup" );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPlayerPickup" );
    
    g_iMaxPlayers = get_maxplayers( );
}

public client_putinserver( id )
    g_bEnable[ id ] = false;

public FwdHamPlayerPickup( iEntity, id )
    return ( 1 <= id <= g_iMaxPlayers && g_bEnable[ id ] ) ? HAM_SUPERCEDE : HAM_IGNORED

public CmdBlockPickup( id )
    g_bEnable[ id ] = !g_bEnable[ id ];

DIREKTOR · 03-25-2010 , 15:53 Re: Block weapon pickup

Quote:

Originally Posted by Exolent[jNr]

It works fine the way it was.

What I would do is make sure a player is touching the entities:

Code:

#include < amxmodx >
#include < hamsandwich >

// should be 33 with id as index,
// or use 32 with id-1 as index
new bool: g_bEnable[ 33 ];

new g_iMaxPlayers;

public plugin_init( ) {
    register_plugin( "Block Pickup", "0.1", "master4life" );
    
    register_clcmd( "say /block", "CmdBlockPickup" );
    
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPlayerPickup" );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPlayerPickup" );
    
    g_iMaxPlayers = get_maxplayers( );
}

public client_putinserver( id )
    g_bEnable[ id ] = false;

public FwdHamPlayerPickup( iEntity, id )
    return ( 1 <= id <= g_iMaxPlayers && g_bEnable[ id ] ) ? HAM_SUPERCEDE : HAM_IGNORED

public CmdBlockPickup( id )
    g_bEnable[ id ] = !g_bEnable[ id ];

exolent please can you make this only when Terror say /block

Exolent[jNr] · 03-25-2010 , 16:51 Re: Block weapon pickup

Code:

#include < amxmodx >
#include < cstrike >
#include < hamsandwich >

#define MAX_PLAYERS 32

new bool: g_bEnable[ MAX_PLAYERS + 1 ];

new g_iMaxPlayers;

public plugin_init( ) {
    register_plugin( "Block Pickup", "0.1", "master4life" );
    
    register_clcmd( "say /block", "CmdBlockPickup" );
    
    RegisterHam( Ham_Touch, "armoury_entity", "FwdHamPlayerPickup" );
    RegisterHam( Ham_Touch, "weaponbox", "FwdHamPlayerPickup" );
    
    g_iMaxPlayers = get_maxplayers( );
}

public client_putinserver( id )
    g_bEnable[ id ] = false;

public FwdHamPlayerPickup( iEntity, id )
{
    if( ( 1 <= id <= g_iMaxPlayers )
    &&  g_bEnable[ id ] )
    {
        if( cs_get_user_team( id ) == CS_TEAM_T )
            return HAM_SUPERCEDE;
        else
            g_bEnable[ id ] = false;
    }
    
    return HAM_IGNORED;
}

public CmdBlockPickup( id )
    g_bEnable[ id ] = ( !g_bEnable[ id ] && cs_get_user_team( id ) == CS_TEAM_T );

DIREKTOR · 03-26-2010 , 07:03 Re: Block weapon pickup

unable co compile
error:/groups/amxmodx/tmp3/textoWewuK.sma(25) : error 017: undefined symbol "cs_get_user_team"

wrecked_ · 03-26-2010 , 07:06 Re: Block weapon pickup

#include <cstrike>

at the top.

hleV · 03-26-2010 , 09:57 Re: Block weapon pickup

PHP Code:


			
#include <amxmodx>
#include <engine>
#include <cstrike>
 
new bool:g_BlockPickup[33];
 
public plugin_init()
{
        register_plugin("Block Pickup", "1.0", "AMXX Community");
 
        register_clcmd("say /block", "SayBlock");
 
        register_touch("weaponbox", "player", "BlockPickup");
        register_touch("armoury_entity", "player", "BlockPickup");
        register_touch("weapon_shield", "player", "BlockPickup");
}
 
public client_putinserver(Client)
        g_BlockPickup[Client] = false;
 
public SayBlock(Client)
        if (cs_get_user_team(Client) == CS_TEAM_T)
                g_BlockPickup[Client] = !g_BlockPickup[Client];
 
public BlockPickup(Entity, Client)
        return (g_BlockPickup[Client] && cs_get_user_team(Client) == CS_TEAM_T) ? PLUGIN_HANDLED : PLUGIN_CONTINUE;