[abdul-rehman]

I tried many ways of retrieving strings using dynamic natives but i failed this is the main plugin that i was using:

#include <amxmodx>
#include <amxmisc>

public plugin_natives()
{
    register_native("get_persons_name", "_get_persons_name", 1)
}

public _get_persons_name(plugin, paramsnum)
{
    // No parameters passed
    if(!paramsnum)
        return -1
    
    new name[32]
    get_user_name(get_param(1), name, 30)

    set_string(2, name, get_param(3))

    return 1
}

sub plugin looks like this
i use the native to retrieve a persons name [Its just for testing purposes]

#include <amxmodx>
#include <amxmisc>
#include < name >

public plugin_init()
{
    // Plugin registeration
    register_plugin("-New","1.0","@bdul!")
    
    register_clcmd("say test", "hook")
}

public hook(id)
{
    new name[32]
    get_persons_name(id, name, charsmax(name))
    
    client_print( id, print_chat, "******* Your Name : %s", name)
}

Include file looks like this:

PHP Code:

#if defined _name_included
  #endinput
#endif
#define _name_included

native get_persons_name( id, const string[], len ) 


The Problem:
When i type test for checking i get this stupid run-time error:

PHP Code:

L 07/11/2010 - 23:27:57: Wrong style of dynamic native
L 07/11/2010 - 23:27:57: [AMXX] Run time error 10 (plugin "example.amxx") (native "get_param") - debug not enabled!
L 07/11/2010 - 23:27:57: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 07/11/2010 - 23:27:57: Unhandled dynamic native error
L 07/11/2010 - 23:27:57: [AMXX] Run time error 10 (plugin "working.amxx") (native "get_persons_name") - debug not enabled!
L 07/11/2010 - 23:27:57: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes). 


I dont know why these errors are occuring and due to this the native is not performing what it is supposed to do
So if please some one can help me then it would be great

Thnx in advance....

[fysiks]

First of all you need to read this: "[AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes)."

You are registering the native with style 1 but are actually using style 0.

There is also an error in the third param of get_user_nam(), it can't be hardcoded to work correclty.

[abdul-rehman]

Originally Posted by fysiks First of all you need to read this: "[AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes)." You are registering the native with style 1 but are actually using style 0. There is also an error in the third param of get_user_nam(), it can't be hardcoded to work correclty.

OK then i dont wont to enable debug mode and what should i do to make my native compatible with style 1 [If possible]

[grimvh2]

at top of plugin_natives()

PHP Code:

register_library("includename") 


and in include i use this

PHP Code:

#if defined _includename_included
    #endinput
#endif

#define _includename_included

#pragma reqlib includename 


[fysiks]

Originally Posted by abdul-rehman OK then i dont wont to enable debug mode and what should i do to make my native compatible with style 1 [If possible]

If you don't want to enable debug mode then you obviously don't know what debug means.

Use style 0. If you want to use style 1 then you can find information about it the tutorials section (or elsewhere).

[ConnorMcLeod]

Try this :

#include <amxmodx>

#define FIRST_PLAYER_ID 1

new g_iMaxPlayers
#define IsPlayer(%1)	( FIRST_PLAYER_ID <= %1 <= g_iMaxPlayers )

#define CHECK_PLAYER(%1) \
	if( !IsPlayer(%1) ) \
	{ \
		log_error(AMX_ERR_NATIVE, "Player out of range (%d)", %1); \
		return 0; \
	} \
	else if( !is_user_connected(%1) ) \
	{ \
		log_error(AMX_ERR_NATIVE, "Invalid player (%d)", %1); \
		return 0; \
	}

public plugin_init()
{
	register_plugin("My Awesome Fake Native", "0.1", "ConnorMcLeod")

	g_iMaxPlayers = get_maxplayers()
}

public plugin_natives()
{
    register_native("get_persons_name", "get_persons_name", 0)
}

public get_persons_name(plugin, paramsnum) // get_persons_name(index, name[], len)
{
	if( paramsnum != 3 )
	{
		log_error(AMX_ERR_NATIVE, "Bad arguments num, expected 3, passed %d", paramsnum)
		return 0
	}

	new id = get_param(1)

	CHECK_PLAYER( id )    

	new name[32]
	get_user_name(id, name, charsmax(name))

	new len = get_param(3)
	name[len] = 0

	set_string(2, name, len)

	return 1
}

[abdul-rehman]

Originally Posted by ConnorMcLeod Try this : #include <amxmodx> #define FIRST_PLAYER_ID 1 new g_iMaxPlayers #define IsPlayer(%1) ( FIRST_PLAYER_ID <= %1 <= g_iMaxPlayers ) #define CHECK_PLAYER(%1) \ if( !IsPlayer(%1) ) \ { \ log_error(AMX_ERR_NATIVE, "Player out of range (%d)", %1); \ return 0; \ } \ else if( !is_user_connected(%1) ) \ { \ log_error(AMX_ERR_NATIVE, "Invalid player (%d)", %1); \ return 0; \ } public plugin_init() { register_plugin("My Awesome Fake Native", "0.1", "ConnorMcLeod") g_iMaxPlayers = get_maxplayers() } public plugin_natives() { register_native("get_persons_name", "get_persons_name", 0) } public get_persons_name(plugin, paramsnum) // get_persons_name(index, name[], len) { if( paramsnum != 3 ) { log_error(AMX_ERR_NATIVE, "Bad arguments num, expected 3, passed %d", paramsnum) return 0 } new id = get_param(1) CHECK_PLAYER( id ) new name[32] get_user_name(id, name, charsmax(name)) new len = get_param(3) name[len] = 0 set_string(2, name, len) return 1 }

Conner one question...How can i make it compatible with style 1 if i want
if its possible then please tell me
btw thnks for your code i will use it as a backup...

[ConnorMcLeod]

from kz-arg

PHP Code:

public native_kz_get_configsdir(name[], len)
{
    param_convert(1)
    
    new lalin[64]
    get_localinfo("amxx_configsdir", lalin,63)
    
    return formatex(name, len, "%s/%s", lalin, KZ_DIR)
} 


[abdul-rehman]

Problem solved thnx to conner, fysiks and every one who responded to my thread.....i will give you credits in my next version of Zombie Plague Advance