[Natsheh]

i have a function will transfer numbers and words of time format to timestamp, i was wondering if there is a better way i can achieve.

PHP Code:

new const szTimeLength[][] = {
    "Second",
    "Minute",
    "Hour",
    "Day",
    "Week",
    "Month",
    "Year",
    "Permanent"
}

new const iLengthMultiplier[] = {
    1,
    60,
    3600,
    86400,
    604800,
    2592000,
    86400*365,
    0
}

stock time_to_timestamps(const expiredate[])
{
    new iExpireLength;
    for(new szTimeLength_Size = sizeof szTimeLength, i, c, x, iLen = strlen(expiredate), szNum[20], g, szTime[11]; i < iLen; i++)
    {
        if(isdigit(expiredate[i]))
        {
            if(g > 0) c = g = 0;
            if(!( sizeof szNum > c >= 0)) continue;
            szNum[c] = expiredate[i];
            c++;
        }
        else if( sizeof szTime > g >= 0 && isalpha(expiredate[i]) )
        {
            szTime[g] = expiredate[i];
            g++;
            
            for(x = 0; x < szTimeLength_Size; x++)
            {
                if(equali(szTimeLength[x], szTime))
                {
                    c = str_to_num(szNum);
                    iExpireLength += iLengthMultiplier[x] * !c ? 1:c;
                    g = c = 0;
                    
                    arrayset(szTime, 0, sizeof szTime);
                    arrayset(szNum, 0, sizeof szNum);
                }
            }
        }
    }
    return iExpireLength 
} 


Example of stock:-

PHP Code:

time_to_timestamps("1 week 1 day") // will return  ( 86400 * 7 + 86400 ) = 691200 


[fysiks]

Depends on if you enforce a pattern. If you enforce spaces between everything you can use strtok() or strbreak() to get each section in a loop instead of parsing each character. You'd also need to require that there always be a number followed by a string.

Here's a quick test function I wrote. It doesn't check the whole unit string but surely that's not all that important.

PHP Code:

public cmdTest()
{
    new szArg[100]
    read_args(szArg, charsmax(szArg))
    remove_quotes(szArg)
    
    new szValue[5], iValue, szUnit[32], iMultiplier
    new iTotal = 0
    
    while( szArg[0] )
    {
        strbreak(szArg, szValue, charsmax(szValue), szArg, charsmax(szArg))
        strbreak(szArg, szUnit, charsmax(szUnit), szArg, charsmax(szArg))
        
        iValue = str_to_num(szValue)
        
        switch(szUnit[0])
        {
            case 's', 'S':
            {
                iMultiplier = 1
            }
            case 'm', 'M':
            {
                switch(szUnit[1])
                {
                    case 'i': iMultiplier = 60
                    case 'o': iMultiplier = 2592000
                }
            }
            case 'h', 'H':
            {
                iMultiplier = 3600
            }
            case 'd', 'D':
            {
                iMultiplier = 86400
            }
            case 'w', 'W':
            {
                iMultiplier = 604800
            }
            case 'y', 'Y':
            {
                iMultiplier = 31536000
            }
            default:
            {
                iMultiplier = 0
            }
        }
        
        iTotal += iValue * iMultiplier
    }
        
    server_print("Total = %d", iTotal)
} 


You could obviously check for the odd one out (i.e. "Permanent") before doing this loop.


Why are you defining all your variables in the for loop statement? It makes your code harder to read.

[Natsheh]

There is no specific pattern and numbers aren't always followed by a string.

Why I'm defining the variables at the loop init because I'm only using them in the body of the loop.

[fysiks]

Originally Posted by Natsheh There is no specific pattern and numbers aren't always followed by a string.

Um, how does that work? What is a scenario that a number isn't followed by a string? What patterns that you expect won't work my the function that I provided?

[Natsheh]

time_to_timestamps("year")

time_to_timestamps("1week")

[^SmileY]

Input param need to be a string if i understand correctly?

[Natsheh]

Originally Posted by ^SmileY Input param need to be a string if i understand correctly?

Then what is it currently?

I am asking if there is a better method to interpret string rather than reading the string char by char based on the multiple various inputs, to transfer time from words t0 timestamp.

[fysiks]

Originally Posted by Natsheh I am asking if there is a better method to format interpret the string than reading the string char by char based on the multiple various inputs, to transfer time from words t0 timestamp.

Fixed.

If there is no required pattern, you're going to need to traverse the string by individual character anyways (unless you use RegEx though that might be less efficient).

[Natsheh]

Thanks for your time regex seems the best solution for this solved.