[farawayf]

Hello. How to get current hostname and add specific string to at start of hostname.

I don't know how to use Format or StrCat

PHP Code:


public void OnPluginStart()
{
    HookEntityOutput("logic_relay", "OnTrigger", Trigger_Relay);
}

public Trigger_Relay(const String:output[], caller, attacker, Float:delay)
{
    char lvlt3[64];

    GetEntPropString(caller, Prop_Data, "m_iName", lvlt3, sizeof(lvlt3));
    
    
    
    if (StrEqual(lvlt3, "Mode_Stage1")) 
    {
        //here need to add string [Stage 1] to at start of hostname. Example "[Stage 1] Server Hostname"     
    }
    
    if (StrEqual(lvlt3, "Mode_Stage2")) 
    {
        //here need to add string [Stage 2] to at start of hostname. Example "[Stage 2] Server Hostname" 
    }
    
} 


[Kolapsicle]

You may be able to get the 'hostname' console variable and read it into a char buffer. You'll need FindConVar and GetConVarString. To easily format a string, I suggest you use Format as you can merge multiple strings into a new char variable.

FindConVar example:

Spoiler

Handle hostCV = FindConVar("hostname");

GetConVarString example:

Spoiler

char hostname[64];
GetConVarString(hostCV, hostname, sizeof(hostname));

Format example:

Spoiler

char buffer[128];
Format(buffer, sizeof(buffer), "[Stage n] %s", hostname);

None of the above code has been tested.

[impossible_cc]

I'm not sure that it is possible to get access to hostname this way, but if that's true, it should work.

PHP Code:

ConVar cv_Name;
public void OnPluginStart() 
{ 
    HookEntityOutput("logic_relay", "OnTrigger", Trigger_Relay);
    cv_Name = FindConVar("hostname");
} 

public Trigger_Relay(const String:output[], caller, attacker, Float:delay) 
{ 
    char lvlt3[64]; 

    GetEntPropString(caller, Prop_Data, "m_iName", lvlt3, sizeof(lvlt3));
    
    if (StrEqual(lvlt3, "Mode_Stage1"))  
    {
        char buffer[32];
        cv_Name.GetString(buffer, 32);
        Format(buffer, 32, "[Stage 1] %s", buffer);
        
        cv_Name.SetString(buffer, true, false);//here we add string [Stage 1] to at start of hostname. Example "[Stage 1] Server Hostname"  
        
        
    }
     
    if (StrEqual(lvlt3, "Mode_Stage2"))  
    {
        char buffer[32];
        cv_Name.GetString(buffer, 32);
        Format(buffer, 32, "[Stage 2] %s", buffer);
        
        cv_Name.SetString(buffer, true, false);//here we add string [Stage 2] to at start of hostname. Example "[Stage 2] Server Hostname"  
        
        
    } 
     
} 


[farawayf]

Thank you Kolapsicle for information.

impossible_cc yes it works, thank you.

[Neuro Toxin]

Originally Posted by impossible_cc I'm not sure that it is possible to get access to hostname this way, but if that's true, it should work. PHP Code: ConVar cv_Name; public void OnPluginStart()  {      HookEntityOutput("logic_relay", "OnTrigger", Trigger_Relay);     cv_Name = FindConVar("hostname"); }  public Trigger_Relay(const String:output[], caller, attacker, Float:delay)  {      char lvlt3[64];      GetEntPropString(caller, Prop_Data, "m_iName", lvlt3, sizeof(lvlt3));          if (StrEqual(lvlt3, "Mode_Stage1"))       {         char buffer[32];         cv_Name.GetString(buffer, 32);         Format(buffer, 32, "[Stage 1] %s", buffer);                  cv_Name.SetString(buffer, true, false);//here we add string [Stage 1] to at start of hostname. Example "[Stage 1] Server Hostname"                         }           if (StrEqual(lvlt3, "Mode_Stage2"))       {         char buffer[32];         cv_Name.GetString(buffer, 32);         Format(buffer, 32, "[Stage 2] %s", buffer);                  cv_Name.SetString(buffer, true, false);//here we add string [Stage 2] to at start of hostname. Example "[Stage 2] Server Hostname"                         }        }

This implentation would end up with "[Stage 2] [Stage 1] ..."

You should store the hostname string during OnConfigsExecuted and always use it when formatting to avoid the above.

The buffer you use to write the level and hostname is to small and should be declared once at the start of the callback instead of multiple times.

When calling format use sizeof(buffer) instead of manually putting in the char array size.

[impossible_cc]

Originally Posted by Neuro Toxin You should store the hostname string during OnConfigsExecuted and always use it when formatting to avoid the above.

Nice catch. You are right here.

Originally Posted by Neuro Toxin When calling format use sizeof(buffer) instead of manually putting in the char array size.

Such metod will work slower.

Originally Posted by Neuro Toxin The buffer you use to write the level and hostname is to small and should be declared once at the start of the callback instead of multiple times.

I wrote it like this because I don't know is there any Trigger_Relay action, that will be just ignored (We don't need it). If so, we will declare char [], and don't use it sometimes.


I know that we will NEVER see the difference, because it works very fast anyways, so probably I'm too mad on optimizing, I rather do a bit more optimized than understandable, sorry for that.

I post it here, probably it is better

PHP Code:

ConVar cv_Name;

#define HOSTNAME_MAX_LENGTH 60

char s_Hostname[HOSTNAME_MAX_LENGTH];

public void OnPluginStart()  
{  
    HookEntityOutput("logic_relay", "OnTrigger", Trigger_Relay); 
    cv_Name = FindConVar("hostname"); 
}  

public void OnConfigsExecuted()
{
    cv_Name.GetString(s_Hostname, HOSTNAME_MAX_LENGTH);
}

public Trigger_Relay(const String:output[], caller, attacker, Float:delay)  
{  
    char lvlt3[64];
    GetEntPropString(caller, Prop_Data, "m_iName", lvlt3, sizeof(lvlt3));
    
    if(StrContains(lvlt3, "Mode_Stage", false) > -1)
    {
//Any Mode_Stage will change the hostname, so you can do a restriction here
        char buffer[72];
        Format(buffer, sizeof(buffer), "[Stage %s] %s", lvlt3[10], s_Hostname);
        cv_Name.SetString(buffer, true, false);
    }
} 


[farawayf]

anyway bcs of 2 plugins which conflicting with this plugin i put timer 0.5 .
buffer[32] changed to buffer[64]. working good.

[Neuro Toxin]

Your comment in map end is right. Server.cfg will override as it re-executes before the next configs execute callback is fired.

[asherkin]

Originally Posted by impossible_cc Such metod will work slower.

No it wont, sizeof is compile time, there is no runtime penalty as there is no runtime code, it just gets replaced with the correct number.

[impossible_cc]

Originally Posted by asherkin No it wont, sizeof is compile time, there is no runtime penalty as there is no runtime code, it just gets replaced with the correct number.

Oh, that's nice.

For some reason, when I think about sizeof, I imagine strlen, my fault.