[Drimacus]

Hello!
Please tell me how to load strings from ini-file into a dynamic array and go through the array by FOR loop.

Contents of the ini file:

models/player/zh/zh_charple001.mdl
models/player/zh/zh_charple002.mdl
models/player/zh/zh_charple003.mdl

Current implementation via While and with limited number of lines (20 lines)

PHP Code:

#define MAX_BUFFER_SIZE 200
#define MAX_MODELS 20
#define MAX_PATH_LENGTH 128
#define MAX_STRING_MODELS_LENGTH 640

new String:g_Models[MAX_MODELS][MAX_STRING_MODELS_LENGTH];
new String:g_Models_Count;

public OnMapStart()
{
    g_Models_Count = 0;
    g_Models_Count = LoadModels(g_Models, "configs/models.ini");

    if (g_Models_Count == 0) SetFailState("No models found by plugin");

    PrintToServer("%d models precached.", g_Models_Count);
}

stock LoadModels(String:models[][], String:ini_file[])
{
    decl String:buffer[MAX_BUFFER_SIZE];
    decl String:file[MAX_PATH_LENGTH];
    new models_count;

    BuildPath(Path_SM, file, MAX_PATH_LENGTH, ini_file);
    
    new Handle:fileh = OpenFile(file, "r");
    while (ReadFileLine(fileh, buffer, MAX_PATH_LENGTH))
    {
        TrimString(buffer);
        if (FileExists(buffer))
        {
            AddFileToDownloadsTable(buffer);
            if (StrEqual(buffer[strlen(buffer) - 4], ".mdl", false) && (models_count < MAX_MODELS))
            {
                strcopy(models[models_count++], strlen(buffer) + 1, buffer);
            }
        }
    }
    return models_count;
} 


[little_froy]

use ArrayList

[Marttt]

You can check this plugin https://forums.alliedmods.net/showthread.php?p=1471736
Does a similar thing about what you are trying to do.

[Grey83]

PHP Code:

#pragma semicolon 1
#pragma newdecls required

ArrayList hModels;

public void OnPluginStart()
{
    hModels = new ArrayList(ByteCountToCells(PLATFORM_MAX_PATH));
}

public void OnMapStart()
{
    if(hModels.Length) hModels.Clear();

    char buffer[PLATFORM_MAX_PATH];
    BuildPath(Path_SM, buffer, sizeof(buffer), "configs/models.ini");

    File fileh = OpenFile(buffer, "r");
    if(!fileh) ThrowError("Config file \"%s\" not found.", buffer);

    int i, len;
    while(ReadFileLine(fileh, buffer, sizeof(buffer)))
    {
        if(buffer[len-1] == '\n') buffer[--len] = 0;

        // ignore lines that are too short
        if((len = TrimString(buffer)) < 5)
            continue;

        // ignoring comments
        i = -1;
        while(buffer[++i]) if(buffer[i] == '/' && buffer[i+1] == '/')
        {
            buffer[i] = 0;
            break;
        }

        // ignoring too short lines and files missing on the server
        if(i < 5 || (len != i && (len = TrimString(buffer)) < 5) || !FileExists(buffer))
            continue;

        AddFileToDownloadsTable(buffer);
        if(!strcmp(buffer[len - 4], ".mdl", false))
        {
            if(PrecacheModel(buffer, true)) hModels.PushString(buffer);
            else LogError("Can't precache model \"%s\"", buffer);
        }
    }

    if(!hModels.Length) LogError("No models found by plugin");
    else PrintToServer("%d models precached.", hModels.Length);
}

...

void PrintModels()
{
    if(!hModels.Length)
        return;

    int num = hModels.Length;
    PrintToServer("Total %i models:", num);
    if(num)
    {
        char buffer[PLATFORM_MAX_PATH];
        for(int i; i < num; i++)
        {
            hModels.GetString(i, buffer, sizeof(buffer));
            PrintToServer(" %3i) %s", i+1, buffer);
        }
    }

    PrintToServer(" ");
}