[headshot910]

PHP Code:

public fw_SetModel(entity, model[])
{
    if(!is_valid_ent(entity))
        return FMRES_IGNORED;
    static szClassName[33]
    entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
    if(!equal(szClassName, "weaponbox"))
        return FMRES_IGNORED;
    static iOwner
    iOwner = entity_get_edict(entity, EV_ENT_owner)
    if(equal(model, "models/w_aug.mdl"))
    {
        static iStoredSVDID
        iStoredSVDID = find_ent_by_owner(-1, went, entity)
        if(!is_valid_ent(iStoredSVDID))
            return FMRES_IGNORED;
        if(g_has_balrog5[iOwner])
        {
            entity_set_int(iStoredSVDID, EV_INT_impulse, WEAPONKEY)
            g_has_balrog5[iOwner] = false        
            
            //It should save here
            set_pev(entity, pev_iuser1, skin[iOwner])
            
            entity_set_model(entity, skin[iOwner]?balrog5_W_MODELB:balrog5_W_MODEL)    
            
            client_print(iOwner,print_chat,"You dropped %s Balrog-V",pev(entity, pev_iuser1)?"BLUE":"RED")
            return FMRES_SUPERCEDE;
        }
    }
    return FMRES_IGNORED;
}
public fw_balrog5_AddToPlayer(balrog5, id)
{
    if(!is_valid_ent(balrog5) || !is_user_connected(id))
        return HAM_IGNORED;
    if(entity_get_int(balrog5, EV_INT_impulse) == WEAPONKEY)
    {
        g_has_balrog5[id] = true
        entity_set_int(balrog5, EV_INT_impulse, 0)
        
        //But NO, it's not loading :(
        skin[id] = pev(balrog5, pev_iuser1)
        client_print(id,print_chat,"You picked up %s Balrog-V",pev(balrog5, pev_iuser1)?"BLUE":"RED")
        return HAM_HANDLED;
    }
    return HAM_IGNORED;
} 


Hi i'm trying to save variable "skin" of player to dropped entity but when i picked up, it's seem like nothing different and the skin variable back to player'id default value.
I already search on forum and try on Touch but it's seem like nothing work for me.
Please help!

[HamletEagle]

I didn't read your code, but your problem may be because you don't know how weaponbox entities work. A "weaponbox" entity is exactly what the name says: a box that contains a weapon entity.
In fw_SetModel you set iuser1 on the box itself.
In fw_balrog5_AddToPlayer you try to retrieve iuser1 from the weapon that was in the box.
The box and the weapon are 2 different entities.

You should instead set your flag on the weapon from the box. Touch should also work, as long as you hook touch with the weaponbox and not the weapon.

[headshot910]

Originally Posted by HamletEagle I didn't read your code, but your problem may be because you don't know how weaponbox entities work. A "weaponbox" entity is exactly what the name says: a box that contains a weapon entity. In fw_SetModel you set iuser1 on the box itself. In fw_balrog5_AddToPlayer you try to retrieve iuser1 from the weapon that was in the box. The box and the weapon are 2 different entities. You should instead set your flag on the weapon from the box. Touch should also work, as long as you hook touch with the weaponbox and not the weapon.

Can you demonstrate some code base on mine? Thank you

[Bugsy]

You would need to add more checking in AddPlayerItem but this is the basic idea that HamletEagle was suggesting.

PHP Code:


#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

const XO_CWEAPONBOX = 4;

new const m_rgpPlayerItems_CWeaponBox[ 6 ] = { 34 , 35, ... };
 
public plugin_init()
{
    register_forward( FM_SetModel , "SetModel" );
    RegisterHam( Ham_AddPlayerItem , "player" , "AddPlayerItem" );
}
    
public SetModel( iEntity , const szModel[] )
{
    static szClass[ 32 ] , iWeaponEntity , iRandom , iPlayer;
    pev( iEntity , pev_classname , szClass , charsmax( szClass ) );
    
    if ( equal( szClass , "weaponbox" ) )
    {
        for ( new i = 1 ; i < sizeof( m_rgpPlayerItems_CWeaponBox ) ; i++ )
        {
            if ( ( iWeaponEntity = get_pdata_cbase( iEntity , m_rgpPlayerItems_CWeaponBox[ i ] , XO_CWEAPONBOX ) ) > 0 )
            {
                iRandom = random( 1000 );
                set_pev( iWeaponEntity , pev_iuser1 , iRandom );
                
                iPlayer = pev( iEntity , pev_owner );
                client_print( iPlayer , print_chat , "Dropped weapon with pev_iuser1 = %d" , iRandom );
                break;
            }
        }
    }
}

public AddPlayerItem( iPlayer , iEntity )
{
    new pev_iuser1_value = pev( iEntity , pev_iuser1 );
    
    if ( pev_iuser1_value )
    {
        client_print( iPlayer , print_chat , "Picked up weapon with pev_iuser1 = %d" , pev_iuser1_value );
    }
}