[mamistikfistik]

Hello friends, let me show an example of what I want to do, the library I use is sqlx. I will run a query like this, I will give steamid, if that steamid is found, return; If not, it will insert. I leave the version I made with javascript below, I would appreciate it if you inform me.

const SteamID = '12345';
const Query = `SELECT * FROM players WHERE steam_id = '${SteamID}'`;

connection.query(Query, (error, results) => {
if (error) {
console.log(error.stack);
return;
}

if (results.length > 0) {
console.log('Steam ID found.');
} else {
const query2 = `INSERT INTO players (steam_id) VALUES ('${SteamID}')`;
connection.query(query2, (insertError, insertResults) => {
if (insertError) {
console.log(insertError.stack);
return;
}
}

[Bugsy]

Not tested

PHP Code:


#include <amxmodx>
#include <sqlx>

new Handle:g_SQLTuple;

new g_szBuffer[ 256 ];

public plugin_init() 
{
    SQL_SetAffinity( "sqlite" );
    g_SQLTuple = SQL_MakeDbTuple( "host" , "user" , "pass" , "DBName" );
}

public client_authorized( id )
{
    new szSteamID[ 35 ];
    get_user_authid( id , szSteamID , charsmax( szSteamID ) );

    formatex( g_szBuffer , charsmax( g_szBuffer ) , "SELECT * FROM players WHERE steam_id = '%s';" , szSteamID );
    SQL_ThreadQuery( g_SQLTuple , "SQLCallBack" , g_szBuffer , szSteamID , sizeof( szSteamID )  );
}

public SQLCallBack(FailState, Handle:Query, Error[], Errcode, const Data[], DataSize)
{
    new szSteamID[ 35 ];
    
    if ( !Errcode )
    {
        if ( SQL_NumResults( Query ) )
        {
            SQL_ReadResult( Query , 0 , szSteamID , charsmax( szSteamID ) );
            
            console_print( 0 , "SteamID Found" );
        }
        else
        {
            formatex( g_szBuffer , charsmax( g_szBuffer ) , "INSERT INTO players (steam_id) VALUES ('%s');" , Data );
            SQL_ThreadQuery( g_SQLTuple , "SQLCallBack" , g_szBuffer );
            
            console_print( 0 , "SteamID Inserted" );
        }
    }
} 


[mamistikfistik]

Originally Posted by Bugsy Not tested PHP Code: #include <amxmodx> #include <sqlx> new Handle:g_SQLTuple; new g_szBuffer[ 256 ]; public plugin_init()  {     new const szSteamID[] = "STEAM12345";     formatex( g_szBuffer , charsmax( g_szBuffer ) , "SELECT * FROM players WHERE steam_id = '%s';" , szSteamID );          SQL_SetAffinity( "sqlite" );          g_SQLTuple = SQL_MakeDbTuple( "host" , "user" , "pass" , "DBName" );          SQL_ThreadQuery( g_SQLTuple , "SQLCallBack" , g_szBuffer , szSteamID , sizeof( szSteamID )  ); } public SQLCallBack(FailState, Handle:Query, Error[], Errcode, const Data[], DataSize) {     new szSteamID[ 35 ];          if ( !Errcode )     {         if ( SQL_NumResults( Query ) )         {             SQL_ReadResult( Query , 0 , szSteamID , charsmax( szSteamID ) );                          console_print( 0 , "SteamID Found" );         }         else         {             formatex( g_szBuffer , charsmax( g_szBuffer ) , "INSERT INTO players (steam_id) VALUES ('%s');" , Data );             SQL_ThreadQuery( g_SQLTuple , "SQLCallBack" , g_szBuffer );                          console_print( 0 , "SteamID Inserted" );         }     } }

Can you show me how to use this in client_putinserver, I tried to try it myself but I guess it didn't work.

[Bugsy]

Above code is updated.. authorized should be used opposed to putinserver

[mamistikfistik]

Originally Posted by Bugsy Above code is updated.. authorized should be used opposed to putinserver

When I try the code, it performs a lot of sql queries, including after entering the server. The current number is 4000 for 20 seconds. It also tries to add even if there is a Steam ID.

[mamistikfistik]

Okay, I solved the error I mentioned, now I have a question. For example, I found the sql data with Steam ID, but I need to get or update other things, for example LastName, can you explain how to do that?

[Bugsy]

So you need to query for the SteamID and LastName and if no record exists, insert both fields as a new record?

[mamistikfistik]

Originally Posted by Bugsy So you need to query for the SteamID and LastName and if no record exists, insert both fields as a new record?

Let me give an example here. How can I subtract Steam_ID and LastName? Let's say I gave Steam_ID 123, how can I get the equal LastName?

CREATE TABLE IF NOT EXISTS `players` (
`ID` int NOT NULL AUTO_INCREMENT,
`Steam_ID` varchar(32) NOT NULL,
`LastName` varchar(32) DEFAULT 'None',
PRIMARY KEY (`ID`)
) ENGINE=MyISAM AUTO_INCREMENT=421 DEFAULT CHARSET=utf8mb4 COLLATE=utf8mb4_0900_ai_ci;

[bigdaddy424]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <sqlx>

new Handle:MYSQL_CONNECTION
new DatabaseID[MAX_PLAYERS + 1]
new const MYSQL_TABLE[] = "table"

public plugin_cfg()
    MYSQL_Init()

public plugin_end()
    SQL_FreeHandle(MYSQL_CONNECTION)

public MYSQL_Init()
{
    MYSQL_CONNECTION = SQL_MakeStdTuple()

    new query[256]
    formatex(query, charsmax(query), "CREATE TABLE IF NOT EXISTS `%s` (\
        `id` INT(4) NOT NULL AUTO_INCREMENT,\
        `steamid` VARCHAR(32) NOT NULL,\
        `name` VARCHAR(64) NOT NULL,\
        PRIMARY KEY (`id`),\
        UNIQUE (`steamid`));", MYSQL_TABLE)
    SQL_ThreadQuery(MYSQL_CONNECTION, "IgnoredOutput", query)
}

public client_authorized(id)
{
    if (!is_user_bot(id) && !is_user_hltv(id))
    {
        new steamid[32], data[2]
        data[0] = id
        data[1] = 0
        DatabaseID[id] = 0
        get_user_authid(id, steamid, charsmax(steamid))
        SQL_ThreadQuery(MYSQL_CONNECTION, "DataOutput", fmt("SELECT * FROM `%s` WHERE BINARY `steamid` = '%s';", MYSQL_TABLE, steamid), data, sizeof(data))
    }
}

public client_disconnected(id)
{
    if (!is_user_bot(id) && !is_user_hltv(id))
    {
        new buffer[MAX_NAME_LENGTH*2]
        SQL_QuoteStringFmt(Empty_Handle, buffer, charsmax(buffer), "%n", id)
        server_print(buffer)
        SQL_ThreadQuery(MYSQL_CONNECTION, "IgnoredOutput", fmt("UPDATE `%s` SET `name` = '%s' WHERE id = %d;", MYSQL_TABLE, buffer, DatabaseID[id]))
        DatabaseID[id] = 0
    }
}


public DataOutput(failState, Handle:query, error[], errNum, data[])
{
    if(errNum)
        server_print("MYSQL Error # (%d)%s", errNum, error)

    else
    {
        new id = data[0]
        if(is_user_connected(id))
        {
            if(!SQL_NumResults(query))
            {
                new steamid[MAX_NAME_LENGTH], buffer[MAX_NAME_LENGTH*2]
                get_user_authid(id, steamid, charsmax(steamid))
                SQL_QuoteStringFmt(Empty_Handle, buffer, charsmax(buffer), "%n", id)
                SQL_ThreadQuery(MYSQL_CONNECTION, "IgnoredOutput", fmt("INSERT INTO `%s` VALUES(NULL, '%s', '%s');", MYSQL_TABLE, steamid, buffer))
                client_authorized(id, NULL_STRING)
            }

            else
                DatabaseID[id] = SQL_ReadResult(query, 0)
        }
    }
}

public IgnoredOutput(failState, Handle:query, const error[], errNum)
{
    if(errNum)
        server_print("MYSQL Error # (%d)%s", errNum, error)
} 


[Bugsy]

Originally Posted by mamistikfistik Let me give an example here. How can I subtract Steam_ID and LastName? Let's say I gave Steam_ID 123, how can I get the equal LastName? CREATE TABLE IF NOT EXISTS `players` ( `ID` int NOT NULL AUTO_INCREMENT, `Steam_ID` varchar(32) NOT NULL, `LastName` varchar(32) DEFAULT 'None', PRIMARY KEY (`ID`) ) ENGINE=MyISAM AUTO_INCREMENT=421 DEFAULT CHARSET=utf8mb4 COLLATE=utf8mb4_0900_ai_ci;

It would be easiest to replace

PHP Code:

SELECT * FROM players WHERE steam_id = '%s'; 


with

PHP Code:

SELECT LastName FROM players WHERE steam_id = '%s'; 


I imagine that you do not have a ridiculous number of fields/columns where it's too much work to just specify the column names you want opposed to passing *...("*" means get every column, if you didn't know).

Then in the call back function, this will retrieve the LastName value.

PHP Code:

SQL_ReadResult( Query , 0 , szLastName , charsmax( szLastName ) ); 


If you wanted multiple things, you'd do this:

PHP Code:

SELECT LastName, Age, XP FROM players WHERE steam_id = '%s'; 


Then in the callback you'd do:

PHP Code:

SQL_ReadResult( Query , 0 , szLastName , charsmax( szLastName ) );
new iAge = SQL_ReadResult( Query , 1 );
new iXP = SQL_ReadResult( Query , 2 );