[Solved] Need Help with a Vote Menu

Psyk0tik · **Author**

Hey guys, I need help with inserting these:

PHP Code:


			
        IntToString(0, TVMEntry, sizeof(TVMEntry));

        IntToString(1, TVMEntry, sizeof(TVMEntry));

Into this vote menu:

PHP Code:


			
        Menu TeleportVoteMenu = CreateMenu(TeleportMenuHandler);

        SetVoteResultCallback(TeleportVoteMenu, TeleportVoteResults);

        Format(VoteOptions, sizeof(VoteOptions), "%T", "TeleportSpeedrunners", client);

        TeleportVoteMenu.SetTitle(VoteOptions); 

        Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", client);

        TeleportVoteMenu.AddItem("Yes", VoteOptions);

        Format(VoteOptions, sizeof(VoteOptions), "%T", "No", client);

        TeleportVoteMenu.AddItem("No", VoteOptions); 

        SetMenuPagination(TeleportVoteMenu, MENU_NO_PAGINATION);

        TeleportVoteMenu.ExitButton = false;

        VoteMenu(TeleportVoteMenu, HumanPlayers, TotalHumans, 30);

I tried this but it didn't work:

PHP Code:


			
        Menu TeleportVoteMenu = CreateMenu(TeleportMenuHandler);

        SetVoteResultCallback(TeleportVoteMenu, TeleportVoteResults);

        Format(VoteOptions, sizeof(VoteOptions), "%T", "TeleportSpeedrunners", client);

        TeleportVoteMenu.SetTitle(VoteOptions); 

        Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", client);

        IntToString(0, TVMEntry, sizeof(TVMEntry));

        TeleportVoteMenu.AddItem(TVMEntry, "Yes", VoteOptions);

        Format(VoteOptions, sizeof(VoteOptions), "%T", "No", client);

        IntToString(1, TVMEntry, sizeof(TVMEntry));

        TeleportVoteMenu.AddItem(TVMEntry, "No", VoteOptions); 

        SetMenuPagination(TeleportVoteMenu, MENU_NO_PAGINATION);

        TeleportVoteMenu.ExitButton = false;

        VoteMenu(TeleportVoteMenu, HumanPlayers, TotalHumans, 30);

Psyk0tik · 12-20-2017 , 03:47 Re: Need Help with a Vote Menu

Never mind. Turns out I didn't need to do anything like this.

8guawong · 12-20-2017 , 03:54 Re: Need Help with a Vote Menu

what exactly are you trying to do?

https://sm.alliedmods.net/new-api/menus/Menu/AddItem

bool AddItem(const char[] info, const char[] display, int style)

PHP Code:


			
Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", client); 

        IntToString(0, TVMEntry, sizeof(TVMEntry)); 

        TeleportVoteMenu.AddItem(TVMEntry, "Yes", VoteOptions);

your using a translation for style?

cravenge · 12-20-2017 , 03:55 Re: Need Help with a Vote Menu

Here you go, Crasher:

PHP Code:


			
Menu TeleportVoteMenu = new Menu(TeleportMenuHandler); TeleportVoteMenu.VoteResultCallback = TeleportVoteResults;



Format(VoteOptions, sizeof(VoteOptions), "%T", "TeleportSpeedrunners", client); 

TeleportVoteMenu.SetTitle(VoteOptions);



Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", client); 

TeleportVoteMenu.AddItem("", VoteOptions); 

Format(VoteOptions, sizeof(VoteOptions), "%T", "No", client);  

TeleportVoteMenu.AddItem("", VoteOptions);



TeleportVoteMenu.MenuPagination = MENU_NO_PAGINATION; 

TeleportVoteMenu.ExitButton = false; 

TeleportVoteMenu.Vote(HumanPlayers, TotalHumans, 30);

You don't need those to see if they chose yes or no. In the menu handler, just check the param2 because that is the index of the choice.

Example:

Psyk0tik · 12-20-2017 , 04:02 Re: Need Help with a Vote Menu

Quote:

Originally Posted by 8guawong

what exactly are you trying to do?

https://sm.alliedmods.net/new-api/menus/Menu/AddItem

bool AddItem(const char[] info, const char[] display, int style)

PHP Code:


			
Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", client); 

        IntToString(0, TVMEntry, sizeof(TVMEntry)); 

        TeleportVoteMenu.AddItem(TVMEntry, "Yes", VoteOptions);

your using a translation for style?

The vote options were messed up, as in, both options were returning the callback function for when the majority vote is "yes". I thought that IntToString was what can solve the problem. However, cravenge pointed it out to me in PM that it was something else, which is pasted in their post above. (The "switch(param2)".)

P.S. Thanks again cravenge!

Powerlord · *Last edited by Powerlord; 12-20-2017 at 05:19.*

Don't use MenuAction_Select in a vote. You should use one of these instead:

Use MenuAction_VoteEnd. param1 will be the winning item and param2 can be passed to GetMenuVoteInfo to get the number of votes the winning item got and how many votes were cast. Edit: I used this in the example down below.
Use a VoteResultCallback (aka VoteHandler), which will tell you how many votes each item got at the end of the vote, how many votes were cast, what each client voted for, etc...

Note: If you use a VoteResultCallback, you'll still need a regular MenuHandler to handle things like cleaning up the Menu at the end of the vote or to do proper translations for each client.

Edit: On the subject of translations, the way you have translations set up now, they'll only appear in the language of the person who called the vote. If you want an actual translation for each player, you need to do this:

Code:

// When you create the vote menu
Menu TeleportVoteMenu = new Menu(TeleportMenuHandler,
MENU_ACTIONS_DEFAULT|MenuAction_Display|MenuAction_DisplayItem|MenuAction_VoteEnd);

// and the actual handler
public int TeleportMenuHandler(Menu menu, MenuAction action, int param1, int param2)
{
    switch (action)
    {
        case MenuAction_End:
        {
            delete menu;
        }
        case MenuAction_VoteEnd:
        {
            int winningVotes;
            int totalVotes;
            GetMenuVoteInfo(param2, winningVotes, totalVotes);

            switch (param1)
            {
                case 0:
                {
                    // Yes won, do stuff here
                }
                case 1:
                {
                    // No won, do stuff here
                }
            }
        }
        // translate the menu title
        case MenuAction_Display:
        {
            Panel panel = view_as<Panel>(param2);
            char VoteOptions[64];
            Format(VoteOptions, sizeof(VoteOptions), "%T", "TeleportSpeedrunners", param1);
            panel.SetTitle(VoteOptions);
        }
        // translate the menu options
        case MenuAction_DisplayItem:
        {
            char VoteOptions[64];

            switch (param2)
            {
                case 0:
                {
                    Format(VoteOptions, sizeof(VoteOptions), "%T", "Yes", param1);
                    return RedrawMenuItem(VoteOptions);
                }

                case 1:
                {
                    Format(VoteOptions, sizeof(VoteOptions), "%T", "No", param1);
                    return RedrawMenuItem(VoteOptions);
                }
            }
        }
    }
    return 0;

}

Psyk0tik · *Last edited by Psyk0tik; 12-23-2017 at 17:51.*

Quote:

Originally Posted by Powerlord

First off, thank you for showing me a more efficient way of creating and handling a vote menu.

Second of all, here's what I have now:

Spoiler

PHP Code:


			
public Action aCommand_Votewarp(int client, int args)
{
    if(!cvEnablePlugin.BoolValue)
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "PluginOff");
        return Plugin_Handled;
    }

    if(!cvTeleportVoteSystem.BoolValue || cvTeleportAutoMode.BoolValue)
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "CommandOff");
        return Plugin_Handled;
    }

    if(!cvTeleportTankAlive.BoolValue)
    {
        vCountTanks();
        if(iNumTanks4)
        {
            ReplyToCommand(client, "\x04[ASS]\x01 %t", "TankAlive");
            return Plugin_Handled;
        }
    }

    if(!cvTeleportEnable.BoolValue)
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "WelcomeOff");
        return Plugin_Handled;
    }

    if(!bIsSystemValid())
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "MapModeNotSupported");
        return Plugin_Handled;
    }

    if(args > 0)
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "Usage3a");
        return Plugin_Handled;
    }

    if(IsVoteInProgress())
    {
        ReplyToCommand(client, "\x04[ASS]\x01 %t", "Vote in Progress");
        return Plugin_Handled;
    }

    Menu mTeleportVoteMenu = new Menu(iTeleportVoteMenuHandler, MENU_ACTIONS_DEFAULT|MenuAction_Display|MenuAction_DisplayItem|MenuAction_VoteEnd);
    mTeleportVoteMenu.SetTitle("Teleport speedrunners?");
    mTeleportVoteMenu.AddItem("yes", "Yes");
    mTeleportVoteMenu.AddItem("no", "No");
    mTeleportVoteMenu.ExitButton = false;
    mTeleportVoteMenu.DisplayVoteToAll(15);
    return Plugin_Handled;
}

int iGetHumanCount()
{
    int iHumanCount;
    for(int iHuman = 1; iHuman <= MaxClients; iHuman++)
        if(bIsValidClient(iHuman))
            iHumanCount += 1;
    return iHumanCount;
}

public int iTeleportVoteMenuHandler(Menu menu, MenuAction action, int param1, int param2)
{
    switch(action)
    {
        char sVoteOptions[255];
        case MenuAction_End:
            delete menu;
        case MenuAction_VoteEnd:
        {
            int iTotalVotes;
            int iVotedYes;
            GetMenuVoteInfo(param2, iVotedYes, iTotalVotes);
            if(iTotalVotes != iGetHumanCount())
                PrintToChatAll("\x04[ASS]\x01 %T", "NoVotes", param1, iTotalVotes, iGetHumanCount());
            switch(param1)
            {
                case 0:
                {
                    if(cvTeleportDetectionDelay.IntValue != 0 && cvTeleportDetectionTimer.IntValue != 0)
                        CreateTimer(cvTeleportDetectionDelay.FloatValue, tManualTimerTeleportSpeedrunners, GetEngineTime() + cvTeleportDetectionTimer.IntValue, TIMER_REPEAT);
                    PrintToChatAll("\x04[ASS]\x01 %T", "VotedYes", param1, iVotedYes, iTotalVotes);
                }

                case 1: PrintToChatAll("\x04[ASS]\x01 %T", "VotedNo", param1, iVotedYes, iTotalVotes);
            }
        }

        case MenuAction_Display:
        {
            Panel panel = view_as<Panel>(param2);
            Format(sVoteOptions, sizeof(sVoteOptions), "%T", "TeleportSpeedrunners", param1);
            panel.SetTitle(sVoteOptions);
        }

        case MenuAction_DisplayItem:
        {
            switch(param2)
            {
                case 0:
                {
                    char sYesOption[64];
                    menu.GetItem(param2, "", 0, _, sYesOption, sizeof(sYesOption));
                    Format(sVoteOptions, sizeof(sVoteOptions), "%T", sYesOption, param1);
                    return RedrawMenuItem(sVoteOptions);
                }

                case 1:
                {
                    char sNoOption[64];
                    menu.GetItem(param2, "", 1, _, sNoOption, sizeof(sNoOption));
                    Format(sVoteOptions, sizeof(sVoteOptions), "%T", sNoOption, param1);
                    return RedrawMenuItem(sVoteOptions);
                }
            }
        }
    }

    return 0;
}

I'm not sure if there's anything that I'm missing or that I did wrong. I used the wiki to help set this up.

EDIT: Tested this out even more and confirmed it to work as intended.

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode