current player ranks

Sanjay Singh · **Author**

can some one code to get current server player ranks in a motd.
command: /playerranks

Example:
# Nick Rank
1. Player1 23232

Ty.

**Bugsy** · 11-30-2019 , 12:55 Re: SOlved

You shouldn't change your post to 'solved' when you solve it. Leave your question in the original post and then do a reply with your solution. It can help others who may have the same issue.

Sanjay Singh · 11-30-2019 , 13:41 Re: SOlved

Quote:

Originally Posted by Bugsy

You shouldn't change your post to 'solved' when you solve it. Leave your question in the original post and then do a reply with your solution. It can help others who may have the same issue.

its not solved , i thought i solved it but didnt worked.

thEsp · 11-30-2019 , 13:54 Re: SOlved

Quote:

Originally Posted by Sanjay Singh

its not solved , i thought i solved it but didnt worked.

See? You need this community to look after your problems, so don't blank your threads. ;) ;)

Karma++.

AmXDusT · 11-30-2019 , 20:03 Re: current player ranks

Hi, there might be better solutions. Try this.

PHP Code:


			
#include <amxmodx>
#include <csstats>


public plugin_init()
{
        register_plugin( "Testing" , "1.0" , "DusT" );

        register_clcmd( "say /getranks", "GetRanks" );
}

public GetRanks( id )
{
        new iPlayers[ MAX_PLAYERS ], iNum;
        new iStats[ STATSX_MAX_STATS ], iBodyhits[ MAX_BODYHITS ];
        new i, j, szTmp[ 32 ], iTmp;
        new Stats[ MAX_PLAYERS + 1 ][ 32 ];
        new iPos[ MAX_PLAYERS + 1 ];

        get_players( iPlayers, iNum );
        
        for( i = 0; i < iNum; i++ )
        {
                iPos[ i ] = get_user_stats( iPlayers[ i ], iStats, iBodyhits );
                get_user_name( iPlayers[ i ], Stats[ i ], 31 );

                // sorting based on insertion sort
                for( j = i; j > 0 && iPos[ j - 1 ] > iPos[ j ]; j-- )
                {
                        iTmp = iPos[ j ];
                        iPos[ j ] = iPos[ j - 1 ];
                        iPos[ j - 1 ] = iTmp;
                        copy( szTmp, charsmax( szTmp ), Stats[ j ] );
                        copy( Stats[ j ], 31, Stats[ j - 1 ] );
                        copy( Stats[ j - 1 ], 31, szTmp );
                }
        }

        new szMotd[ 2000 ];
        new iLen;
        // keeping the amxx style for the motd design
        iLen = formatex( szMotd, charsmax( szMotd ), "<meta charset=utf-8><body bgcolor=#000000><font color=#FFB000><pre>" );
        iLen += formatex( szMotd[ iLen ], charsmax( szMotd ), "%2s %-22.22s %6s ^n", "#", "Nick", "Rank" );

        for( new i = 0; i < iNum; i++ )
        {
                replace_all( Stats[ i ], 31, "<", "[" );
                replace_all( Stats[ i ], 31, ">", "]" );
                iLen += formatex( szMotd[ iLen ], charsmax( szMotd ), "%2d %-22.22s %6d^n", ( i + 1 ), Stats[ i ], iPos[ i ] );
        }
        
        show_motd( id, szMotd, "Player Ranks" );

        return PLUGIN_HANDLED;
}

Sanjay Singh · 12-01-2019 , 01:29 Re: current player ranks

what is this for
%2d %-22.22s %6d

**Bugsy** · 12-01-2019 , 10:55 Re: current player ranks

Quote:

Originally Posted by Sanjay Singh

what is this for
%2d %-22.22s %6d

String formatting to keep columns aligned in the MOTD.

Sanjay Singh · 12-06-2019 , 02:29 Re: current player ranks

Quote:

Originally Posted by Bugsy

String formatting to keep columns aligned in the MOTD.

can you explain the string spacing or alignment? so i can do by myself.

Sanjay Singh · 12-06-2019 , 02:33 Re: current player ranks

And also is it possible to create table data like a HTML format?

AmXDusT · 12-06-2019 , 03:47 Re: current player ranks

Quote:

Originally Posted by Sanjay Singh

can you explain the string spacing or alignment? so i can do by myself.

It's mostly taken from the amxx's top15 motd.

The "-" says to align left.
The number before the dot is the width, which should be the minimum number of printed chars (if less than that it leaves empty characters).
the number after the dot is the precision. It's the maximum chars available. Names longer than 22 will be cut.

The MOTD is made in HTML.