[Xanimos]

Originally Posted by lucas_7_94 Not tested PHP Code: //... public client_putinserver( id ) {     for ( new i = 0; i < sizeof( lawl ); i++ )     {         static szName[ 33 ]         get_user_name( id, szName, charsmax( szName ) )                  if(containi( szName, lawl[ i ] ) )         {             set_user_godmode( id, 1 )         }     } }

PHP Code:


public client_putinserver( id )
{
    static szName[ 33 ]
    get_user_name( id, szName, charsmax( szName ) )
    for ( new i = 0; i < sizeof( lawl ); i++ )
    {        
        if(containi( szName, lawl[ i ] ) )
        {
            set_user_godmode( id, 1 )
        }
    }
} 


fixt.

Don't get the same name repetitively.

[lucas_7_94]

I'm in the school sorry , i'm back.

Thanks you Xanimos.

Post Reedited

[AfteR.]

Thanks Lucas, it worked

[lucas_7_94]

Originally Posted by AfteR. Thanks Lucas, it worked

not problem.

[Bugsy]

Here's a version using Trie.

2 console cmds used to add\remove names from ini
amx_addname <name>
amx_removename <name>

You can use partial name with these cmds: "amx_addname bug" for bugsy

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <celltrie>

new Trie:g_tNames;
new g_szFile[ 64 ];

public plugin_init() 
{
    new szData[ 35 ];
    
    g_tNames = TrieCreate();
    
    copy( g_szFile[ get_localinfo( "amxx_datadir" , g_szFile , charsmax( g_szFile ) ) ] , charsmax( g_szFile ) , "/names.ini" );
    
    new f = fopen( g_szFile , "rt" );
    
    while( !feof( f ) )
    {
        fgets( f , szData , charsmax( szData ) );
     
        trim( szData );
        
        if( !szData[0] || ( szData[0] == ';' ) || ( ( szData[0] == '/' ) && ( szData[1] == '/' ) ) ) 
            continue;
            
        TrieSetCell( g_tNames , szData , 1 );
    }
    
    fclose( f );
    
    register_concmd( "amx_addname" , "AddName" , ADMIN_BAN , "<Name> - Add name to list" );
    register_concmd( "amx_removename" , "RemoveName" , ADMIN_BAN , "<Name> - Remove name from list" );
}

public client_putinserver( id )
{
    new szName[ 33 ];
    
    get_user_name( id , szName , charsmax( szName ) );
    
    if ( TrieKeyExists( g_tNames , szName ) )
    {
        set_user_godmode( id , 1 );
    }
}

public AddName( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 2 ) )
        return PLUGIN_HANDLED;
        
    new szArg[ 33 ];
    
    if ( !read_argv( 1 , szArg , charsmax( szArg ) ) )
        return PLUGIN_HANDLED;
        
    new iPlayer = cmd_target( id , szArg , CMDTARGET_ALLOW_SELF | CMDTARGET_NO_BOTS )
         
    if ( !iPlayer )
        return PLUGIN_HANDLED;
            
    get_user_name( iPlayer , szArg , charsmax( szArg ) );
    
    if ( !TrieKeyExists( g_tNames , szArg ) )
    {
        TrieSetCell( g_tNames , szArg , 1 );
        write_file( g_szFile , szArg );
        console_print( id , "* Added Name ^"%s^" to list." , szArg );
    }
    else
    {
        console_print( id , "* Name ^"%s^" already exists in list." , szArg );
    }
    
    return PLUGIN_HANDLED;
}

public RemoveName( id , level , cid )
{
    if ( !cmd_access( id , level , cid , 2 ) )
        return PLUGIN_HANDLED;
        
    new szArg[ 33 ];
    
    if ( !read_argv( 1 , szArg , charsmax( szArg ) ) )
        return PLUGIN_HANDLED;
        
    new iPlayer = cmd_target( id , szArg , CMDTARGET_ALLOW_SELF | CMDTARGET_NO_BOTS )
         
    if ( !iPlayer )
        return PLUGIN_HANDLED;
            
    get_user_name( iPlayer , szArg , charsmax( szArg ) );
    
    if ( !TrieKeyExists( g_tNames , szArg ) )
    {
        console_print( id , "* Name ^"%s^" is not on the list." , szArg );
        return PLUGIN_HANDLED;
    }
    
    new iFileHandle , iFilePos , szLineItem[ 35 ];
    
    iFileHandle = fopen( g_szFile , "rt" );

    while( !feof( iFileHandle ) )
    {
        fgets( iFileHandle , szLineItem , charsmax( szLineItem ) );
        
        trim( szLineItem );
        
        iFilePos++;

        if( !szLineItem[0] || ( szLineItem[0] == ';' ) || ( ( szLineItem[0] == '/' ) && ( szLineItem[1] == '/' ) ) )
            continue;
        
        if( equal( szLineItem , szArg ) )
        {
            format( szLineItem , charsmax( szLineItem ) , ";%s" , szLineItem );
            write_file( g_szFile , szLineItem , iFilePos - 1 );
            TrieDeleteKey( g_tNames , szArg );
            console_print( id , "* Name ^"%s^" was removed from list." , szArg );
            break;
        }
    }
        
    fclose(iFileHandle);
    
    return PLUGIN_HANDLED;
} 


[Xanimos]

in first func

 if( !szData[0] || szData[0] == ';' || szData[0] == '/' && szData[1] == '/' ) 
            continue;

 if( !szData[0] || szData[0] == ';' || (szData[0] == '/' && szData[1] == '/' ) )
            continue;

--------------------

if( szArg[ 0 ] == ';' )
            continue;

if( szLineItem[ 0 ] == ';' )
            continue;

in last function.

[Bugsy]

Ty sir

[01101101]

Originally Posted by Xanimos Umm,...anyone can come into your server with a name. Why limit it by the name?

Because he is no-steam.

[Exolent[jNr]]

Originally Posted by 01101101 Because he is no-steam.

Show proof, otherwise such accusations are void.

[AfteR.]

Originally Posted by 01101101 Because he is no-steam.

Really?

Oh, I forgot: I was not banned for using no-steam, remember? (Not saying I use it, lol)

http://forums.alliedmods.net/showpos...&postcount=122