[iskenderkebab33]

Hey! i have a problem with my code which reason i don't know...

code must do: give every player +10 HP every 30 seconds

my try:

PHP Code:

#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
}

public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast)
{
    CreateTimer(30.0, Timer_Health, INVALID_HANDLE, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
    
    return Plugin_Continue;
}

public Action Timer_Health(Handle hTimer)
{
    int client = GetClientUserId(client);

    int health = GetEntProp(client, Prop_Send, "m_iHealth");
        health += 10;
    
    return Plugin_Continue;
} 


any help is welcome <3

[mug1wara]

First, something that annoys me. You include sdkhooks, but don't even use it.

Line 15, replace "INVALID_HANDLE" with "_".

Line 22, that basically tells me: get userid from nothing. You could get the userid and pass it as third param on line 15, but that means you have to GetClientOfUserid aswell in callback.

Line 23, there's nothing really wrong here, just want to point out that the int "health" is EXACTLY the same as "GetEntProp(client, Prop_Send, "m_iHealth");"

Line 24, here comes a problem: we first have to get the client's health with GetEntProp, then we have to set it with SetEntProp, or SetEntityHealth (both of which works as good as eachother).

If you're too lazy to read plain english, here's what it should look like.

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
}

public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast)
{
    CreateTimer(30.0, Timer_Health, _, TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE);
    
    return Plugin_Continue;
}

public Action Timer_Health(Handle hTimer)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        int iHealth = GetClientHealth(i) + 10;
        
        SetEntityHealth(i, iHealth);
    }
    
    return Plugin_Continue;
} 


[iskenderkebab33]

Originally Posted by mug1wara First, something that annoys me. You include sdkhooks, but don't even use it. Line 15, replace "INVALID_HANDLE" with "_". Line 22, that basically tells me: get userid from nothing. You could get the userid and pass it as third param on line 15, but that means you have to GetClientOfUserid aswell in callback. Line 23, there's nothing really wrong here, just want to point out that the int "health" is EXACTLY the same as "GetEntProp(client, Prop_Send, "m_iHealth");" Line 24, here comes a problem: we first have to get the client's health with GetEntProp, then we have to set it with SetEntProp, or SetEntityHealth (both of which works as good as eachother). If you're too lazy to read plain english, here's what it should look like. PHP Code: #include <sourcemod> #include <sdktools> #pragma semicolon 1 public void OnPluginStart() {     HookEvent("round_start", Event_RoundStart); } public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast) {     CreateTimer(30.0, Timer_Health, _, TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE);          return Plugin_Continue; } public Action Timer_Health(Handle hTimer) {     for (int i = 1; i <= MaxClients; i++)     {         int iHealth = GetClientHealth(i) + 10;                  SetEntityHealth(i, iHealth);     }          return Plugin_Continue; }

thank you, working.

[eyal282]

Originally Posted by mug1wara First, something that annoys me. You include sdkhooks, but don't even use it. Line 15, replace "INVALID_HANDLE" with "_". Line 22, that basically tells me: get userid from nothing. You could get the userid and pass it as third param on line 15, but that means you have to GetClientOfUserid aswell in callback. Line 23, there's nothing really wrong here, just want to point out that the int "health" is EXACTLY the same as "GetEntProp(client, Prop_Send, "m_iHealth");" Line 24, here comes a problem: we first have to get the client's health with GetEntProp, then we have to set it with SetEntProp, or SetEntityHealth (both of which works as good as eachother). If you're too lazy to read plain english, here's what it should look like. PHP Code: #include <sourcemod> #include <sdktools> #pragma semicolon 1 public void OnPluginStart() {     HookEvent("round_start", Event_RoundStart); } public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast) {     CreateTimer(30.0, Timer_Health, _, TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE);          return Plugin_Continue; } public Action Timer_Health(Handle hTimer) {     for (int i = 1; i <= MaxClients; i++)     {         int iHealth = GetClientHealth(i) + 10;                  SetEntityHealth(i, iHealth);     }          return Plugin_Continue; }

I feel bad for the server for having to store infinite size errors because you don't check IsClientInGame when looping all POSSIBLE players.

Also, the amount of health you will earn will increase by 10 every round. This means that when 30 rounds pass, each 30 seconds you will get 300 HP.

And I have no clue what happens when you heal a dead player nor want to.

The code I attached here solves the issues.

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1

new Handle:hTimerHealth = INVALID_HANDLE;

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
}

public Action Event_RoundStart(Event hEvent, const char[] sName, bool bDontBroadcast)
{
    if(hTimerHealth != INVALID_HANDLE)
    {
        CloseHandle(hTimerHealth);
        hTimerHealth = INVALID_HANDLE;
    }
    hTimerHealth = CreateTimer(30.0, Timer_Health, _, TIMER_REPEAT | TIMER_FLAG_NO_MAPCHANGE);
    
    return Plugin_Continue;
}

public Action Timer_Health(Handle hTimer)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if(!IsClientInGame(i))
            continue;
            
        else if(!IsPlayerAlive(i))
            continue;

        int iHealth = GetClientHealth(i) + 10;
        
        SetEntityHealth(i, iHealth);
    }
    
    return Plugin_Continue;
}

[micapat]

It would certainly be nice to check if the player is alive too

[eyal282]

Originally Posted by micapat It would certainly be nice to check if the player is alive too

Face palm thanks.

[mug1wara]

He never told me to check if the client was valid :p

[Psyk0tik]

SDKTools is not needed.

PHP Code:

#include <sourcemod>
#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    HookEvent("round_start", eEventRoundStart);
}

public void eEventRoundStart(Event event, const char[] name, bool dontBroadcast)
{
    CreateTimer(30.0, tTimerHeal, _, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
}

public Action tTimerHeal(Handle timer)
{
    for (int iPlayer = 1; iPlayer <= MaxClients; iPlayer++)
    {
        if (bIsValidClient(iPlayer))
        {
            int iHealth = GetClientHealth(iPlayer) + 10;
            SetEntityHealth(iPlayer, iHealth);
        }
    }
}

stock bool bIsValidClient(int client)
{
    return client > 0 && client <= MaxClients && IsClientInGame(client) && IsPlayerAlive(client) && !IsClientInKickQueue(client);
} 


[mug1wara]

Yep, noticed. Thought GetClientHealth / SetEntityHealth was a part of sdktools.

[LenHard]

Originally Posted by mug1wara He never told me to check if the client was valid :p

You should always check no matter what's the reason, it's really a bad practice to not check. It'll prevent you from making that mistake in the future and also prevent errors to those whom you're helping.

Originally Posted by Crasher_3637 SDKTools is not needed. PHP Code: #include <sourcemod> #pragma semicolon 1 #pragma newdecls required public void OnPluginStart() {     HookEvent("round_start", eEventRoundStart); } public void eEventRoundStart(Event event, const char[] name, bool dontBroadcast) {     CreateTimer(30.0, tTimerHeal, _, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT); } public Action tTimerHeal(Handle timer) {     for (int iPlayer = 1; iPlayer <= MaxClients; iPlayer++)     {         if (bIsValidClient(iPlayer))         {             int iHealth = GetClientHealth(iPlayer) + 10;             SetEntityHealth(iPlayer, iHealth);         }     } } stock bool bIsValidClient(int client) {     return client > 0 && client <= MaxClients && IsClientInGame(client) && IsPlayerAlive(client) && !IsClientInKickQueue(client); }

If I'm not wrong, that'd cause a timer to be set every round start causing duplicating timers. Add a integer of the round and stop the timer.

PHP Code:

int gI_Round;

public void eEventRoundStart(Event hEvent, const char[] sEventName, bool bDontBroadcast)
{
    ++gI_Round;
    CreateTimer(30.0, Timer_Heal, gI_Round, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
}

public Action Timer_Heal(Handle hTimer, any iRound)
{
    if (gI_Round == iRound)
    {
        for (int i = 1; i <= MaxClients; i++) 
            if (IsClientInGame(i) && IsPlayerAlive(i)) 
                SetEntityHealth(i, GetClientHealth(i) + 10); 
        return Plugin_Continue;
    }
    else return Plugin_Stop;
}