[PC Gamer]

How would this stock be updated with the new style declarations?

PHP Code:

stock TF2_SwitchtoSlot(client, slot)
{
    if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))
    {
        new String:wepclassname[64];
        new wep = GetPlayerWeaponSlot(client, slot);
        if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))
        {
            FakeClientCommandEx(client, "use %s", wepclassname);
            SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);
        }
    }
} 


I read the SourcePan Transitional Syntax wiki, but it isn't written at a level that I can fully understand. Here's where the wiki became too confusing for me:

Grammar The new and old declaration grammar is below. return-type ::= return-old | return-new return-new ::= type-expr new-dims? // Note, dims not yet supported. return-old ::= old-dims? label? argdecl ::= arg-old | arg-new arg-new ::= "const"? type-expr '&'? symbol old-dims? ('=' arg-init)? arg-old ::= "const"? tags? '&'? symbol old-dims? ('=' arg-init)?

[Maxximou5]

I only see three instances of updating. More input is always wanted.

Before:

Spoiler

PHP Code:

stock TF2_SwitchtoSlot(client, slot) // <-- Update
{
    if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))
    {
        new String:wepclassname[64]; // <-- Update
        new wep = GetPlayerWeaponSlot(client, slot); // <-- Update
        if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))
        {
            FakeClientCommandEx(client, "use %s", wepclassname);
            SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);
        }
    }
} 


After:

Spoiler

PHP Code:

stock TF2_SwitchtoSlot(int client, int slot) // <-- Changed
{
    if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))
    {
        char wepclassname[64]; // <-- Changed
        int wep = GetPlayerWeaponSlot(client, slot); // <-- Changed
        if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))
        {
            FakeClientCommandEx(client, "use %s", wepclassname);
            SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);
        }
    }
} 


[MAGNAT2645]

Originally Posted by Maxximou5 I only see three instances of updating. More input is always wanted. Before: Spoiler PHP Code: stock TF2_SwitchtoSlot(client, slot) // <-- Update {     if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))     {         new String:wepclassname[64]; // <-- Update         new wep = GetPlayerWeaponSlot(client, slot); // <-- Update         if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))         {             FakeClientCommandEx(client, "use %s", wepclassname);             SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);         }     } }  After: Spoiler PHP Code: stock TF2_SwitchtoSlot(int client, int slot) // <-- Changed {     if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))     {         char wepclassname[64]; // <-- Changed         int wep = GetPlayerWeaponSlot(client, slot); // <-- Changed         if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))         {             FakeClientCommandEx(client, "use %s", wepclassname);             SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);         }     } }

You forgot to add void return type.

stock void TF2_SwitchToSlot(int client, int slot)
// Will be treated by compiler as an error if your function doesn't have return type but you have #pragma newdecls required

[PC Gamer]

Thanks Guys! I updated the code with your suggestions and it works great!

Final solution:

PHP Code:

stock void TF2_SwitchtoSlot(int client, int slot)
{
    if (slot >= 0 && slot <= 5 && IsClientInGame(client) && IsPlayerAlive(client))
    {
        char wepclassname[64];
        int wep = GetPlayerWeaponSlot(client, slot);
        if (wep > MaxClients && IsValidEdict(wep) && GetEdictClassname(wep, wepclassname, sizeof(wepclassname)))
        {
            FakeClientCommandEx(client, "use %s", wepclassname);
            SetEntPropEnt(client, Prop_Send, "m_hActiveWeapon", wep);
        }
    }
}