Changing Clients Speed Without using "m_flLaggedMovementValue"

Master53 · **Author**

i want to change teh clients speed by using something else than "m_flLaggedMovementValue" because it gliches the player everytime they move over objects or jump and wont work for what im making

iloveportalz0r

I think there's a thing called m_vecVelocity in players. No idea if it's related to that though.

xbatista

Changing speed as a velocity bad idea

Paah

SetEntPropFloat(client, Prop_Send, "m_flMaxspeed", XX)

Works for TF2 atleast.

Master53

yes i actually did try and use m_flMaxspeed but i got no result from my test i did.

Master53

i actually found this in my database of scripts. would this do the trick?

PHP Code:


			
public OnPluginStart() {
    LoadTranslations("common.phrases");
    RegConsoleCmd("set_speed", CmdSetSpeed)
}

public Action:CmdSetSpeed(client, args) {
    //arg0 is set_speed
    decl String:arg1[32]
    decl String:arg2[32]
    GetCmdArg(1, arg1, sizeof(arg1))
    GetCmdArg(2, arg2, sizeof(arg2))
    new target
    target = FindTarget(client, arg1, true, false)
    new Float:flspeed = StringToFloat(arg2)
    
    CustomSetSpeed(target, flspeed, 0)
}
stock CustomSetSpeed(ent, Float:speed, mode, const Float:origin[3] = {0.0,0.0,0.0} )
{
    if(!ent)
        return 0;
    
    switch(mode)
    {
        case 0:
        {
            new Float:f_Velocity[3];
            GetEntityVelocity(ent,f_Velocity);
            
            new Float:y;
            y = f_Velocity[0] * f_Velocity[0] + f_Velocity[1] * f_Velocity[1];
            
            new Float:x;
            if(y) x = SquareRoot(speed * speed / y);
            
            f_Velocity[0] *= x;
            f_Velocity[1] *= x;
            
            if(speed < 0.0)
            {
                f_Velocity[0] *= -1;
                f_Velocity[1] *= -1;
            }
            
            SetEntityVelocity(ent,f_Velocity);
        }

        case 1:
        {
            new Float:f_Velocity[3];
            GetEntityVelocity(ent,f_Velocity);
            
            new Float:y;
            y = f_Velocity[0] * f_Velocity[0] + f_Velocity[1] * f_Velocity[1] + f_Velocity[2] * f_Velocity[2];
            
            new Float:x;
            if(y) x = SquareRoot(speed * speed / y);
            
            f_Velocity[0] *= x;
            f_Velocity[1] *= x;
            f_Velocity[2] *= x;

            if(speed < 0.0)
            {
                f_Velocity[0] *= -1;
                f_Velocity[1] *= -1;
                f_Velocity[2] *= -1;
            }
            
            SetEntityVelocity(ent,f_Velocity);
        }
        case 2:
        {
            new Float:fOrigin[3];
            GetEntityOrigin(ent,fOrigin);
            
            new Float:f_NewVelo[3];
            
            f_NewVelo[0] = origin[0] - fOrigin[0];
            f_NewVelo[1] = origin[1] - fOrigin[1];
            f_NewVelo[2] = origin[2] - fOrigin[2];
            
            new Float:y;
            y = f_NewVelo[0] * f_NewVelo[0] + f_NewVelo[1] * f_NewVelo[1] + f_NewVelo[2] * f_NewVelo[2];
            
            new Float:x;
            if(y) x = SquareRoot(speed * speed / y);
            
            f_NewVelo[0] *= x;
            f_NewVelo[1] *= x;
            f_NewVelo[2] *= x;
            
            if(speed < 0.0)
            {
                f_NewVelo[0] *= -1;
                f_NewVelo[1] *= -1;
                f_NewVelo[2] *= -1;
            }
            
            SetEntityVelocity(ent,f_NewVelo);
        }

        default: return 0;
    }
    return 1;
}

stock GetEntityVelocity(ent,Float:velocity[3]) 
{
    // m_vecVelocity
    return GetEntPropVector(ent,Prop_Data,"m_vecVelocity",velocity);
}

stock SetEntityVelocity(ent,Float:velocity[3]) 
{
    // m_vecVelocity
    return SetEntPropVector(ent,Prop_Data,"m_vecVelocity",velocity);
}

stock GetEntityOrigin(ent, Float:fOrigin[3])
{
    // m_vecOrigin
    return GetEntPropVector(ent,Prop_Data,"m_vecOrigin",fOrigin);
}

LumiStance

Whats wrong with

Code:

native TeleportEntity(entity, const Float:origin[3], const Float:angles[3], const Float:velocity[3]);

javalia

i made this code for my tactical gunmod`s maximum speed suit fucntion

lol this code is crap but it works lol

Code:

if(suitmode[client] == suitmode_speed){
            
            if(((buttons & IN_FORWARD) || (buttons & IN_BACK) || (buttons & IN_MOVELEFT) || (buttons & IN_MOVERIGHT)) && !(buttons & IN_DUCK) && !(buttons & IN_SPEED) && (GetEntityFlags(client) & FL_ONGROUND)){
                
                if(armorvalue >= SUIT_SPEED_ENERGY){
                
                    decl Float:playerspeed[3], Float:clienteyeangle[3], Float:anglevector[3];
                    GetEntPropVector(client, Prop_Data, "m_vecVelocity", playerspeed);
                    
                    GetClientEyeAngles(client, clienteyeangle);
                    clienteyeangle[0] = 0.0;
                    
                    //플레이어의 위와 아래로 가는 속도는 기존 속도에서 가져오고,
                    //플레이어가 갈 방향의 속도를 플레이어의 눈 각도로부터 만든 벡터에서 가져온다
                    //눌린 이동버튼의 조합을 통해서 이동할 방향을 구한다
                    
                    //앞이나 뒤중 하나만이 눌려있거나 아무것도 눌려선 안된다
                    if(((buttons & IN_FORWARD) && !(buttons & IN_BACK)) || (!(buttons & IN_FORWARD) && (buttons & IN_BACK))|| (!(buttons & IN_FORWARD) && !(buttons & IN_BACK))){
                        
                        //좌나 우중 하나 혹은 아무것도 눌려있어선 안된다
                        if(((buttons & IN_MOVELEFT) && !(buttons & IN_MOVERIGHT)) || (!(buttons & IN_MOVELEFT) && (buttons & IN_MOVERIGHT)) || (!(buttons & IN_MOVELEFT) && !(buttons & IN_MOVERIGHT))){
                            
                            //앞으로 가기 버튼이 눌린 경우
                            if(buttons & IN_FORWARD){
                                
                                //왼쪽이 눌린 경우
                                if(buttons & IN_MOVELEFT){
                                    
                                    clienteyeangle[1] = clienteyeangle[1] + 45.0;
                                    
                                }else if(buttons & IN_MOVERIGHT){
                                    
                                    //오른쪽이 눌린 경우
                                    clienteyeangle[1] = clienteyeangle[1] - 45.0;
                                    
                                }
                                
                            }else if(buttons & IN_BACK){
                                
                                //방향을 뒤로
                                clienteyeangle[1] = clienteyeangle[1] + 180.0;
                                
                                //왼쪽이 눌린 경우
                                if(buttons & IN_MOVELEFT){
                                    
                                    clienteyeangle[1] = clienteyeangle[1] - 45.0;
                                    
                                }else if(buttons & IN_MOVERIGHT){
                                    
                                    //오른쪽이 눌린 경우
                                    clienteyeangle[1] = clienteyeangle[1] + 45.0;
                                    
                                }
                                
                            }else{
                                
                                //왼쪽이 눌린 경우
                                if(buttons & IN_MOVELEFT){
                                    
                                    clienteyeangle[1] = clienteyeangle[1] + 90.0;
                                    
                                }else if(buttons & IN_MOVERIGHT){
                                    
                                    //오른쪽이 눌린 경우
                                    clienteyeangle[1] = clienteyeangle[1] - 90.0;
                                    
                                }
                                
                            }
                            
                        }
                        
                    }
                    
                    GetAngleVectors(clienteyeangle, anglevector, NULL_VECTOR, NULL_VECTOR);
                    NormalizeVector(anglevector, anglevector);
                    ScaleVector(anglevector, 40.0);
                    AddVectors(playerspeed, anglevector, playerspeed);
                    
                    if(GetVectorLength(playerspeed) >= SUIT_SPEED_MAXSPEED){
                        
                        NormalizeVector(playerspeed, playerspeed);
                        ScaleVector(playerspeed, SUIT_SPEED_MAXSPEED);
                        
                    }
                    
                    TeleportEntity(client, NULL_VECTOR, NULL_VECTOR, playerspeed);
                    
                    if(nextsuitactivetime[client] < nowtime){
                    
                        nextsuitactivetime[client] = nowtime + SUIT_SPEED_DELAY;
                        SetEntProp(client, Prop_Data, "m_ArmorValue", armorvalue - SUIT_SPEED_ENERGY); 
                        
                    }
                    
                }else{
                    
                    PrintToChat(client, "\x04%T", "suitenergydepleted", client);
                    nextsuitactivetime[client] = nowtime + SUIT_CHARGE_DELAY;
                    suitmode[client] = suitmode_charge;
                    
                    cancelreservesuithelpsound(client);
                    playsuithelpsound(client, SOUNDSUITNOENERGY);
                    
                }
                
            }
            
        }

rhelgeby

http://code.google.com/p/zombiereloa...repo=zr-3-0-b2

Have a look at:
g_flClassApplySpeed (array with speed values)
ClassPreThinkPost (pre think post hook by SDK Hooks)
Class_OnPlayerRunCmd (hack to bypass client speed limit)

javalia

as comment of rhelgeby, it was able to change client`s max move speed by
sdkhooks prethinkpost hook and setting m_flmaxspeed on that hook.
u must do it on prethinkpost hook, not other think hooks.