[step]

Ok, now it's fixed :)
Thanks a lot for the tips!

PHP Code:

CreateFilePath(String:buffer[], maxlength)
{
    static String:game[32];
    static String:version[32];
    decl String:date[32];
    decl String:temp[128];
    
    // game name
    if (strlen(game) == 0)
    {
        GetGameFolderName(game, sizeof(game));
    }
    
    // game version
    if (strlen(version) == 0)
    {
        new Handle:file = OpenFile("steam.inf", "r");
        ReadFileLine(file, temp, sizeof(temp));
        CloseHandle(file);
        TrimString(temp);
        new int;
        int = FindCharInString(temp, '=', false);
        StrCat(version, sizeof(version), temp[int]);
        ReplaceString(version, sizeof(version), "=", "v");
        ReplaceString(version, sizeof(version), ".", "");
    }
    
    // date & time
    FormatTime(date, sizeof(date), NULL_STRING);
    ReplaceString(date, sizeof(date), "/", "_");
    ReplaceString(date, sizeof(date), " - ", "_");
    ReplaceString(date, sizeof(date), ":", "_");
    ReplaceString(date, sizeof(date), " ", "_");
    
    // path
    BuildPath(Path_SM, temp, sizeof(temp), "logs\\%s_%s_%s.txt", game, version, date);
    
    // return
    strcopy(buffer, maxlength, temp);
} 


[Greyscale]

I'm not sure if static empties the string. Does anyone know? You should leave the = ""; to be safe.

[step]

Originally Posted by Greyscale I'm not sure if static empties the string. Does anyone know? You should leave the = ""; to be safe.

I tested several times with PrintConsole's inside the if's and it's always 0.
It acts like decl, but it only does it once, which was the problem with decl in the first place.
So, I guess that I could always use static for strings, when inside loops, instead of decl, since I don't assign any values in the declarations.

[Seta00]

Originally Posted by Greyscale I'm not sure if static empties the string. Does anyone know? You should leave the = ""; to be safe.

static only means it will allocate (exactly as 'new' does) the variable only once. If you assign a value on declaration the compiler will give you an error.
By the way, you should know this as a plugin approver.

[p3tsin]

Originally Posted by Seta00 If you assign a value on declaration the compiler will give you an error.

No it won't. It will initialize the var with that value, as long as its a constant.
You should know this as a veteran member.

[Greyscale]

From SourceMod entity_prop_stocks.inc

/**
 * Sets an entity's movetype.
 *
 * @param entity	Entity index.
 * @param mt		Movetype, see enum above.
 * @noreturn
 * @error			Invalid entity index, or lack of mod compliance.
 */
stock SetEntityMoveType(entity, MoveType:mt)
{
	static bool:gotconfig = false;
	static String:datamap[32];
	
	if (!gotconfig)
	{
		new Handle:gc = LoadGameConfigFile("core.games");
		new bool:exists = GameConfGetKeyValue(gc, "m_MoveType", datamap, sizeof(datamap));
		CloseHandle(gc);
		
		if (!exists)
		{
			strcopy(datamap, sizeof(datamap), "m_MoveType");
		}
		
		gotconfig = true;
	}
	
	SetEntProp(entity, Prop_Data, datamap, mt);
}

And by the way 'decl' allocates, 'new' allocates AND initializes to a value. So I think you mean static is like 'decl' but allocates only once.

[Seta00]

Originally Posted by p3tsin as long as its a constant.

bah, details

Originally Posted by Greyscale And by the way 'decl' allocates, 'new' allocates AND initializes to a value. So I think you mean static is like 'decl' but allocates only once.

No, I meant static initializes to zero.

[rhelgeby]

About those strings, just do this:

PHP Code:

decl String:myString[SOME_HIGH_VALUE];
myString[0] = 0; 


That will do a quick initialization. On long strings this will save some time. Although, if you're going to access a random index in the string for the first time, you have to use new instead of decl.

[step]

Originally Posted by rhelgeby About those strings, just do this: PHP Code: decl String:myString[SOME_HIGH_VALUE]; myString[0] = 0;  That will do a quick initialization. On long strings this will save some time. Although, if you're going to access a random index in the string for the first time, you have to use new instead of decl.

That is the same as

decl String:myString[SOME_HIGH_VALUE] = "";

right?