[JocAnis]

then i guess no need for checking origin but pev_v_angle

[Bugsy]

I don't know what that means, Cirovic

[Cirovic]

Plugin slay players that does not move, but map have on spawn move platform that will kill players that dont play, and plugin dont detect that and wont kill player bcs he moves bcs of map

[Bugsy]

Edit: This detects AFK by monitoring button presses instead of player location.

PHP Code:


#include <amxmodx> 
#include <fakemeta>
#include <hamsandwich>

new const Version[] = "0.4";

#define MAX_PLAYERS 32

const ButtonBits = ( IN_FORWARD | IN_BACK | IN_MOVELEFT | IN_MOVERIGHT | IN_JUMP | IN_DUCK | IN_USE | IN_ATTACK | IN_ATTACK2 | IN_SCORE );

new g_LastMoveTime[ MAX_PLAYERS + 1 ];  
new g_iSysTime;
new g_pSlayTime;
new g_pFreezeTime;
new bool:g_bInRound;

public plugin_init()  
{  
    register_plugin( "AFK Slay" , Version , "bugsy" );

    g_pSlayTime = register_cvar( "as_slaytime" , "30" );
    g_pFreezeTime = get_cvar_pointer( "mp_freezetime" );
    
    RegisterHam( Ham_Spawn , "player" , "HamSpawn_Post" , true );
    register_forward( FM_CmdStart , "CmdStart" );
    register_logevent( "RoundStart" , 2 , "1=Round_Start" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );
    
    set_task( 1.0 , "CheckAFK" , .flags="b" );
}  

public HamSpawn_Post( iPlayer )
{
    if ( is_user_alive( iPlayer ) )
    {
        g_LastMoveTime[ iPlayer ] = g_iSysTime + ( g_bInRound ? 0 : get_pcvar_num( g_pFreezeTime ) );
    }
}

public RoundStart()
{
    g_bInRound = true;
}

public RoundEnd()
{
    g_bInRound = false;
}

public CmdStart( id , handle , seed )
{
    if ( g_bInRound && ( get_uc( handle , UC_Buttons ) & ButtonBits ) )
    {
        g_LastMoveTime[ id ] = g_iSysTime;
    }
}  

public CheckAFK()  
{  
    new iPlayers[ 32 ] , iNum , iPlayer;
        
    g_iSysTime = get_systime();
    
    get_players( iPlayers , iNum , "ae" , "CT" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        if ( g_LastMoveTime[ iPlayer ] && ( ( g_iSysTime - g_LastMoveTime[ iPlayer ] ) >= get_pcvar_num( g_pSlayTime ) ) )
        {
            user_kill( iPlayer );
        }
    }
} 


[Cirovic]

Should max_players be defined?

[Bugsy]

Done. I use 1.9 which it's defined for already, you should upgrade.

[Carrion]

@Bugsy can u make it for any player? its for CT only

[Bugsy]

Originally Posted by Carrion @Bugsy can u make it for any player? its for CT only

Just replace

get_players( iPlayers , iNum , "ae" , "CT" );

with

get_players( iPlayers , iNum , "a" );

[Carrion]

Originally Posted by Bugsy Just replace get_players( iPlayers , iNum , "ae" , "CT" ); with get_players( iPlayers , iNum , "a" );

i also added moving to spect
please check need the code correction?

sma

PHP Code:

/* Plugin generated by AMXX-Studio */
#include <amxmodx> 
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>

new const Version[] = "0.4";
#define MAX_PLAYERS 32
const ButtonBits = ( IN_FORWARD | IN_BACK | IN_MOVELEFT | IN_MOVERIGHT | IN_JUMP | IN_DUCK | IN_USE | IN_ATTACK | IN_ATTACK2 | IN_SCORE );
new g_LastMoveTime[ MAX_PLAYERS + 1 ];  
new g_iSysTime;
new g_pSlayTime;
new g_pSlays;
new g_pFreezeTime;
new bool:g_bInRound;
stock slaysnumber[MAX_PLAYERS+1];

public plugin_init()  
{  
    register_plugin( "AFK Slay" , Version , "bugsy" );
    g_pSlayTime = register_cvar( "as_slaytime" , "30" );
    g_pSlays = register_cvar( "as_slays" , "5" );
    g_pFreezeTime = get_cvar_pointer( "mp_freezetime" );
    RegisterHam( Ham_Spawn , "player" , "HamSpawn_Post" , true );
    register_forward( FM_CmdStart , "CmdStart" );
    register_logevent( "RoundStart" , 2 , "1=Round_Start" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );
    set_task( 1.0 , "CheckAFK" , .flags="b" );
}  

public HamSpawn_Post( iPlayer )
{
    if ( is_user_alive( iPlayer ) )
    {
        g_LastMoveTime[ iPlayer ] = g_iSysTime + ( g_bInRound ? 0 : get_pcvar_num( g_pFreezeTime ) );
    }
}

public RoundStart()
{
    g_bInRound = true;
}

public RoundEnd()
{
    g_bInRound = false;
}

public CmdStart( id , handle , seed )
{
    if ( g_bInRound && ( get_uc( handle , UC_Buttons ) & ButtonBits ) )
    {
        g_LastMoveTime[ id ] = g_iSysTime;
    }
}  

public CheckAFK()  
{  
    new iPlayers[ 32 ] , iNum , iPlayer;
    g_iSysTime = get_systime();
    get_players( iPlayers , iNum , "a" );
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        if ( g_LastMoveTime[ iPlayer ] && ( ( g_iSysTime - g_LastMoveTime[ iPlayer ] ) >= get_pcvar_num( g_pSlayTime ) ) )
        {
            user_kill( iPlayer );
            new name[33]; 
            get_user_name(iPlayer, name, 32); 
            client_print(0, print_chat, "[AMXX] %s was killed for AFK.", name);
            if(++slaysnumber[iPlayer] >= get_pcvar_num(g_pSlays)) {
                cs_set_user_team(iPlayer, CS_TEAM_SPECTATOR);
                client_print(0, print_chat, "[AMXX] %s was MOVIED to spectator for AFK.", name);
                slaysnumber[iPlayer] = 0;
            }
        }
    }
} 

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1049\\ f0\\ fs16 \n\\ par }
*/ 


[Bugsy]

You misspelled moved
You should add a slaysnumber reset to 0 at client_connect()
Use charsmax() in get_user_name() instead of 32