|
Member
Join Date: May 2020
Location: Brazil, Curitiba, PR
|
05-20-2020
, 20:40
Re: AWP Models [XP System Support]
|
#54
|
This worked perfectly!
Follow de codes:
configs > M4A1Models.ini
Code:
#============================================#
# M4A1 Models by OciXCrom: Configuration file #
#============================================#
# You can add an M4A1 by following this example:
# [M4A1 Name]
# V_MODEL = location of v_ model
# P_MODEL = location of p_ model
# You don't have to add a p_ or v_ model if the M4A1 doesn't have one.
# You can also add some of the parameters below:
# FLAG = if you want the M4A1 to be for VIP users/admins, enter the flag here
# SELECT_SOUND = sound when you select the M4A1 from the menu
# If you are using OciXCrom's Rank System, the following options are also available:
# LEVEL = required level from the rank system to use the M4A1
# SHOW_RANK = if set to 1, the rank name will be displayed instead of the level number in the menu
# XP = amount of XP required from the rank system to use the M4A1
[Defalut]
V_MODEL = models/v_m4a1.mdl
P_MODEL = models/p_m4a1.mdl
data > lang> M4A1Models.txt
Code:
[en] -- OciXCrom
AM_CHAT_PREFIX = &x04[M4A1 Models]&x01
AM_CHAT_SELECTED = You have selected the sniper &x04%s
AM_MENU_TITLE = \y< \rChoose your M4A1 model \y>
AM_MENU_TITLE_PAGE = ^n\r-- \yPage:\r
AM_MENU_SELECTED = \y~ \rSELECTED \y~
AM_MENU_VIP_ONLY = \y~ \rVIP \y~
AM_MENU_LEVEL = \r[LVL %i]
AM_MENU_RANK = \r[RANK: %s]
AM_MENU_XP = \r[XP: %i]
[mk] -- OciXCrom
AM_CHAT_PREFIX = &x04[M4A1 Models]&x01
AM_CHAT_SELECTED = Go izbra snajperot &x04%s
AM_MENU_TITLE = \y< \rIzberi model za M4A1 \y>
AM_MENU_TITLE_PAGE = ^n\r-- \yStranica:\r
AM_MENU_SELECTED = \y~ \rIZBRAN \y~
AM_MENU_VIP_ONLY = \y~ \rVIP \y~
AM_MENU_LEVEL = \r[LVL %i]
AM_MENU_RANK = \r[RANK: %s]
AM_MENU_XP = \r[XP: %i]
[bg] -- OciXCrom
AM_CHAT_PREFIX = &x04[M4A1 Models]&x01
AM_CHAT_SELECTED = Izbra snaipera &x04%s
AM_MENU_TITLE = \y< \rIzberi model za M4A1 \y>
AM_MENU_TITLE_PAGE = ^n\r-- \yStranica:\r
AM_MENU_SELECTED = \y~ \rIZBRAN \y~
AM_MENU_VIP_ONLY = \y~ \rVIP \y~
AM_MENU_LEVEL = \r[LVL %i]
AM_MENU_RANK = \r[RANK: %s]
AM_MENU_XP = \r[XP: %i]
[bp] -- artYY
AM_CHAT_PREFIX = &x04[M4A1 Models]&x01
AM_CHAT_SELECTED = Voce selecionou a &x04%s
AM_MENU_TITLE = \y< \rEscolha seu modelo de M4A1 \y>
AM_MENU_TITLE_PAGE = ^n\r-- \yPagina:\r
AM_MENU_SELECTED = \y~ \rSELECIONADO \y~
AM_MENU_VIP_ONLY = \y~ \rVIP \y~
AM_MENU_LEVEL = \r[LVL %i]
AM_MENU_RANK = \r[RANK: %s]
AM_MENU_XP = \r[XP: %i]
crx_m4a1_models.sma
PHP Code:
#include <amxmodx>
#include <amxmisc>
#include <cromchat>
#include <fakemeta>
#include <hamsandwich>
#include <nvault>
native crxranks_get_max_levels()
native crxranks_get_rank_by_level(level, buffer[], len)
native crxranks_get_user_level(id)
native crxranks_get_user_xp(id)
new const g_szNatives[][] =
{
"crxranks_get_max_levels",
"crxranks_get_rank_by_level",
"crxranks_get_user_level",
"crxranks_get_user_xp"
}
#if !defined m_pPlayer
#define m_pPlayer 41
#endif
#if defined client_disconnected
#define client_disconnect client_disconnected
#endif
#define PLUGIN_VERSION "2.1.4"
#define DEFAULT_V "models/v_m4a1.mdl"
#define DEFAULT_P "models/p_m4a1.mdl"
#define MAX_SOUND_LENGTH 128
#define MAX_AUTHID_LENGTH 35
#if !defined MAX_NAME_LENGTH
#define MAX_NAME_LENGTH 32
#endif
#if !defined MAX_PLAYERS
#define MAX_PLAYERS 32
#endif
enum _:M4A1
{
NAME[MAX_NAME_LENGTH],
V_MODEL[MAX_SOUND_LENGTH],
P_MODEL[MAX_SOUND_LENGTH],
SELECT_SOUND[MAX_SOUND_LENGTH],
FLAG,
LEVEL,
bool:SHOW_RANK,
XP
}
new Array:g_aM4A1,
bool:g_bFirstTime[MAX_PLAYERS + 1],
bool:g_bRankSystem,
bool:g_bGetLevel,
bool:g_bGetXP,
g_eM4A1[MAX_PLAYERS + 1][M4A1],
g_szAuth[MAX_PLAYERS + 1][MAX_AUTHID_LENGTH],
g_iM4A1[MAX_PLAYERS + 1],
g_iCallback,
g_pAtSpawn,
g_pSaveChoice,
g_iSaveChoice,
g_iM4A1Num,
g_iVault
public plugin_init()
{
register_plugin("M4A1 Models", PLUGIN_VERSION, "OciXCrom")
register_cvar("CRXM4A1Models", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
if(!g_iM4A1Num)
set_fail_state("No M4A1s found in the configuration file.")
register_dictionary("M4A1Models.txt")
RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
RegisterHam(Ham_Item_Deploy, "weapon_m4a1", "OnSelectM4A1", 1)
register_clcmd("say /m4a1", "ShowMenu")
register_clcmd("say .m4a1", "ShowMenu")
register_clcmd("say_team /m4a1", "ShowMenu")
register_clcmd("say_team .m4a1", "ShowMenu")
g_iCallback = menu_makecallback("CheckM4A1Access")
g_pAtSpawn = register_cvar("am_open_at_spawn", "0")
g_pSaveChoice = register_cvar("am_save_choice", "0")
}
public plugin_precache()
{
if(LibraryExists("crxranks", LibType_Library))
g_bRankSystem = true
g_aM4A1 = ArrayCreate(M4A1)
ReadFile()
}
public plugin_cfg()
{
g_iSaveChoice = get_pcvar_num(g_pSaveChoice)
if(g_iSaveChoice)
g_iVault = nvault_open("M4A1Models")
}
public plugin_natives()
set_native_filter("native_filter")
public native_filter(const szNative[], id, iTrap)
{
if(!iTrap)
{
static i
for(i = 0; i < sizeof(g_szNatives); i++)
{
if(equal(szNative, g_szNatives[i]))
return PLUGIN_HANDLED
}
}
return PLUGIN_CONTINUE
}
public plugin_end()
{
ArrayDestroy(g_aM4A1)
if(g_iSaveChoice)
nvault_close(g_iVault)
}
ReadFile()
{
new szConfigsName[256], szFilename[256]
get_configsdir(szConfigsName, charsmax(szConfigsName))
formatex(szFilename, charsmax(szFilename), "%s/M4A1Models.ini", szConfigsName)
new iFilePointer = fopen(szFilename, "rt")
if(iFilePointer)
{
new eM4A1[M4A1], szData[160], szKey[32], szValue[128], iMaxLevels
if(g_bRankSystem)
iMaxLevels = crxranks_get_max_levels()
while(!feof(iFilePointer))
{
fgets(iFilePointer, szData, charsmax(szData))
trim(szData)
switch(szData[0])
{
case EOS, '#', ';': continue
case '[':
{
if(szData[strlen(szData) - 1] == ']')
{
if(g_iM4A1Num)
PushM4A1(eM4A1)
g_iM4A1Num++
replace(szData, charsmax(szData), "[", "")
replace(szData, charsmax(szData), "]", "")
copy(eM4A1[NAME], charsmax(eM4A1[NAME]), szData)
eM4A1[V_MODEL][0] = EOS
eM4A1[P_MODEL][0] = EOS
eM4A1[SELECT_SOUND][0] = EOS
eM4A1[FLAG] = ADMIN_ALL
if(g_bRankSystem)
{
eM4A1[LEVEL] = 0
eM4A1[SHOW_RANK] = false
eM4A1[XP] = 0
}
}
else continue
}
default:
{
strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), '=')
trim(szKey); trim(szValue)
if(equal(szKey, "FLAG"))
eM4A1[FLAG] = read_flags(szValue)
else if(equal(szKey, "LEVEL") && g_bRankSystem)
{
eM4A1[LEVEL] = clamp(str_to_num(szValue), 0, iMaxLevels)
if(!g_bGetLevel)
g_bGetLevel = true
}
else if(equal(szKey, "SHOW_RANK") && g_bRankSystem)
eM4A1[SHOW_RANK] = _:clamp(str_to_num(szValue), false, true)
else if(equal(szKey, "XP") && g_bRankSystem)
{
eM4A1[XP] = _:clamp(str_to_num(szValue), 0)
if(!g_bGetXP)
g_bGetXP = true
}
else if(equal(szKey, "V_MODEL"))
{
if(!file_exists(szValue))
log_amx("ERROR: model ^"%s^" not found!", szValue)
else
{
precache_model(szValue)
copy(eM4A1[V_MODEL], charsmax(eM4A1[V_MODEL]), szValue)
}
}
else if(equal(szKey, "P_MODEL"))
{
if(!file_exists(szValue))
log_amx("ERROR: model ^"%s^" not found!", szValue)
else
{
precache_model(szValue)
copy(eM4A1[P_MODEL], charsmax(eM4A1[P_MODEL]), szValue)
}
}
else if(equal(szKey, "SELECT_SOUND"))
{
precache_sound(szValue)
copy(eM4A1[SELECT_SOUND], charsmax(eM4A1[SELECT_SOUND]), szValue)
}
}
}
}
if(g_iM4A1Num)
PushM4A1(eM4A1)
fclose(iFilePointer)
}
}
public client_connect(id)
{
g_bFirstTime[id] = true
ArrayGetArray(g_aM4A1, 0, g_eM4A1[id])
g_iM4A1[id] = 0
if(g_iSaveChoice)
{
get_user_authid(id, g_szAuth[id], charsmax(g_szAuth[]))
UseVault(id, false)
}
}
public client_disconnect(id)
{
if(g_iSaveChoice)
UseVault(id, true)
}
public ShowMenu(id)
{
static eM4A1[M4A1]
new szTitle[128], szItem[128], iLevel, iXP
formatex(szTitle, charsmax(szTitle), "%L", id, "AM_MENU_TITLE")
if(g_bGetLevel)
iLevel = crxranks_get_user_level(id)
if(g_bGetXP)
iXP = crxranks_get_user_xp(id)
new iMenu = menu_create(szTitle, "MenuHandler")
for(new iFlags = get_user_flags(id), i; i < g_iM4A1Num; i++)
{
ArrayGetArray(g_aM4A1, i, eM4A1)
copy(szItem, charsmax(szItem), eM4A1[NAME])
if(g_bRankSystem)
{
if(eM4A1[LEVEL] && iLevel < eM4A1[LEVEL])
{
if(eM4A1[SHOW_RANK])
{
static szRank[32]
crxranks_get_rank_by_level(eM4A1[LEVEL], szRank, charsmax(szRank))
format(szItem, charsmax(szItem), "%s %L", szItem, id, "AM_MENU_RANK", szRank)
}
else
format(szItem, charsmax(szItem), "%s %L", szItem, id, "AM_MENU_LEVEL", eM4A1[LEVEL])
}
if(eM4A1[XP] && iXP < eM4A1[XP])
format(szItem, charsmax(szItem), "%s %L", szItem, id, "AM_MENU_XP", eM4A1[XP])
}
if(eM4A1[FLAG] != ADMIN_ALL && !(iFlags & eM4A1[FLAG]))
format(szItem, charsmax(szItem), "%s %L", szItem, id, "AM_MENU_VIP_ONLY")
if(g_iM4A1[id] == i)
format(szItem, charsmax(szItem), "%s %L", szItem, id, "AM_MENU_SELECTED")
menu_additem(iMenu, szItem, eM4A1[NAME], eM4A1[FLAG], g_iCallback)
}
if(menu_pages(iMenu) > 1)
{
formatex(szItem, charsmax(szItem), "%s%L", szTitle, id, "AM_MENU_TITLE_PAGE")
menu_setprop(iMenu, MPROP_TITLE, szItem)
}
menu_display(id, iMenu)
return PLUGIN_HANDLED
}
public MenuHandler(id, iMenu, iItem)
{
if(iItem != MENU_EXIT)
{
g_iM4A1[id] = iItem
ArrayGetArray(g_aM4A1, iItem, g_eM4A1[id])
if(is_user_alive(id) && get_user_weapon(id) == CSW_M4A1)
RefreshM4A1Model(id)
new szName[MAX_NAME_LENGTH], iUnused
menu_item_getinfo(iMenu, iItem, iUnused, szName, charsmax(szName), .callback = iUnused)
CC_SendMessage(id, "%L %L", id, "AM_CHAT_PREFIX", id, "AM_CHAT_SELECTED", szName)
if(g_eM4A1[id][SELECT_SOUND][0])
engfunc(EngFunc_EmitSound, id, CHAN_AUTO, g_eM4A1[id][SELECT_SOUND], 1.0, ATTN_NORM, 0, PITCH_NORM)
}
menu_destroy(iMenu)
return PLUGIN_HANDLED
}
public CheckM4A1Access(id, iMenu, iItem)
return ((g_iM4A1[id] == iItem) || !HasM4A1Access(id, iItem)) ? ITEM_DISABLED : ITEM_ENABLED
public OnPlayerSpawn(id)
{
if(is_user_alive(id) && get_pcvar_num(g_pAtSpawn) && !g_iM4A1[id] && g_bFirstTime[id])
{
g_bFirstTime[id] = false
ShowMenu(id)
}
}
public OnSelectM4A1(iEnt)
{
new id = get_pdata_cbase(iEnt, m_pPlayer, 4)
if(is_user_connected(id))
RefreshM4A1Model(id)
}
RefreshM4A1Model(const id)
{
set_pev(id, pev_viewmodel2, g_eM4A1[id][V_MODEL])
set_pev(id, pev_weaponmodel2, g_eM4A1[id][P_MODEL])
}
PushM4A1(eM4A1[M4A1])
{
if(!eM4A1[V_MODEL][0])
copy(eM4A1[V_MODEL], charsmax(eM4A1[V_MODEL]), DEFAULT_V)
if(!eM4A1[P_MODEL][0])
copy(eM4A1[P_MODEL], charsmax(eM4A1[P_MODEL]), DEFAULT_P)
ArrayPushArray(g_aM4A1, eM4A1)
}
bool:HasM4A1Access(const id, const iM4A1)
{
static eM4A1[M4A1]
ArrayGetArray(g_aM4A1, iM4A1, eM4A1)
if(g_bRankSystem)
{
if(eM4A1[LEVEL] && crxranks_get_user_level(id) < eM4A1[LEVEL])
return false
if(eM4A1[XP] && crxranks_get_user_xp(id) < eM4A1[XP])
return false
}
if(eM4A1[FLAG] != ADMIN_ALL && !(get_user_flags(id) & eM4A1[FLAG]))
return false
return true
}
UseVault(const id, const bool:bSave)
{
if(bSave)
{
static szData[4]
num_to_str(g_iM4A1[id], szData, charsmax(szData))
nvault_set(g_iVault, g_szAuth[id], szData)
}
else
{
static iM4A1
iM4A1 = nvault_get(g_iVault, g_szAuth[id])
if(iM4A1 > g_iM4A1Num)
iM4A1 = 0
if(iM4A1 && HasM4A1Access(id, iM4A1))
{
g_iM4A1[id] = iM4A1
ArrayGetArray(g_aM4A1, iM4A1, g_eM4A1[id])
if(is_user_alive(id) && get_user_weapon(id) == CSW_M4A1)
RefreshM4A1Model(id)
}
}
}
Tks for the help!
|
|
Linear Mode
