[vegeta1241]

http://fast.verygames.net/18/610429/

You will find this files on sound/ideas

Its .wav

[Bacardi]

ok, there something different with that sound file, I don't know yeat what.

But you can test for example csgo in-game sound file

PHP Code:

PrecacheSound("commander/train_mainintro_01.wav");
EmitSoundToAll("commander/train_mainintro_01.wav", target); 


*edit
Now I understand, sound will work differently when it is either MONO or STEREO.
If you want sound work correctly in game, render sound file to MONO

*edit
Or try this first, use this ) in STEREO files

PHP Code:

PrecacheSound(")ideas/Whistle1.wav");
EmitSoundToAll(")ideas/Whistle1.wav", target); 


[vegeta1241]

thank you for your answers my friend

I try with this ")" before precache and emit but not sound are emit

PHP Code:

#include <sourcemod> 
#include <sdktools> 

char g_sSounds[][] =  
{ 
    "ideas/Whistle1.wav",
    "ideas/Whistle2.wav" 
}; 

ConVar g_cVarLevel; 

bool HasWhistle[64]; 
bool HasForceWhistle[64]; 

public Plugin myinfo =  
{ 
    name = "New Plugin", 
    author = "Unknown", 
    description = "<- Description ->", 
    version = "1.0", 
    url = "<- URL ->" 
} 

public void OnPluginStart() 
{ 
    g_cVarLevel = CreateConVar("sm_whistle_level", "70", "Pitch whistle"); 
    RegConsoleCmd("sm_whistle", Whistle); 
    RegConsoleCmd("sm_w", Whistle); 
    RegConsoleCmd("sm_forcewhistle", ForceWhistle); 
    RegConsoleCmd("sm_fw", ForceWhistle); 
} 

public void OnMapStart() 
{ 
    for(int i = 0; i < sizeof(g_sSounds); i++) 
    { 
        char varchar[64]; 
        Format(varchar, 64, "sound/%s", g_sSounds[i]); 
        AddFileToDownloadsTable(varchar); 
        PrecacheSound(")g_sSounds[i]", true); 
    } 
} 

public Action Whistle(int client, int args) 
{ 
    args = 0; 
    if(!IsValidClient(client)) return Plugin_Handled; 
    if(!IsPlayerAlive(client)) return Plugin_Handled; 
    if(GetClientTeam(client) != 2) 
    { 
        PrintToChat(client, "[IDEAS] You cant whistle as CT"); 
        return Plugin_Handled; 
    } 
    if(HasWhistle[client]) 
    { 
        PrintToChat(client, "[IDEAS] You can whistle only once very 30 seconds"); 
        return Plugin_Handled; 
    } 
     
    float pos[3]; 
    GetEntPropVector(client, Prop_Send, "m_vecOrigin", pos); 
    EmitSoundToAll(")g_sSounds[GetRandomInt(0, sizeof(g_sSounds)-1)]", pos, _, g_cVarLevel.IntValue); 
    HasWhistle[client] = true; 
    CreateTimer(5.0, WhistleAgain, GetClientUserId(client)); 
    return Plugin_Handled; 
} 

public Action WhistleAgain(Handle timer, int userid) 
{ 
    int client = GetClientOfUserId(userid); 
    if(IsValidClient(client)) 
    { 
        HasWhistle[client] = false; 
    } 
    delete timer; 
    return Plugin_Stop; 
} 

public Action ForceWhistle(int client, int args) 
{ 
    args = 0; 
    if(!IsValidClient(client)) return Plugin_Handled; 
    if(!IsPlayerAlive(client)) return Plugin_Handled; 
    if(GetClientTeam(client) != 3) 
    { 
        PrintToChat(client, "[IDEAS] You cant force whistle as T"); 
        return Plugin_Handled; 
    } 
    if(HasForceWhistle[client]) 
    { 
        PrintToChat(client, "[IDEAS] You can force whistle only once very 30 seconds"); 
        return Plugin_Handled; 
    } 
    HasForceWhistle[client] = true; 
    CreateTimer(5.0, ForceWhistleAgain, GetClientUserId(client)); 
    ForceRandomWhistle(); 
    return Plugin_Handled; 
} 

public Action ForceWhistleAgain(Handle timer, int userid) 
{ 
    int client = GetClientOfUserId(userid); 
    if(IsValidClient(client)) 
    { 
        HasForceWhistle[client] = false; 
    } 
    delete timer; 
    return Plugin_Stop; 
} 

void ForceRandomWhistle() 
{ 
    int count = 0, cts[32]; 
    for(int i = 1; i <= MaxClients; i++) 
    { 
        if(IsValidClient(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2) 
        { 
            cts[count] = i; 
            count++; 
        } 
    } 
    if(count == 0) 
    { 
        PrintToChatAll("Personne trouvé"); 
        return; 
    } 
    int target = cts[GetRandomInt(0, count-1)]; 
    PrintToChatAll("%N va siffler", target); 
    float pos[3]; 
    GetEntPropVector(target, Prop_Send, "m_vecOrigin", pos); 
    EmitSoundToAll(")g_sSounds[GetRandomInt(0, sizeof(g_sSounds)-1)]", pos, _, g_cVarLevel.IntValue); 
} 


bool IsValidClient(int client) 
{ 
    return client > 0 && client <= MaxClients && IsClientInGame(client); 
} 


[Bacardi]

Here. Keep practising

PHP Code:

#include <sdktools>

char samples[][] = 
{
    "ideas/Whistle1.wav",
    "ideas/Whistle2.wav"
}; 

public void OnPluginStart()
{
    RegConsoleCmd("sm_whistle", Whistle);
    RegConsoleCmd("sm_forcewhistle", ForceWhistle);
}

public void OnMapStart()
{
    char buffer[PLATFORM_MAX_PATH];
    int dot;

    for(int a = 0; a < sizeof(samples); a++)
    {
        dot = FindCharInString(samples[a], '.', true);

        if( dot != -1 && (StrEqual(samples[a][dot], ".wav", false) || StrEqual(samples[a][dot], ".mp3", false)) )
        {
        }
        else
        {
            SetFailState("Invalid file '%s' ", samples[a][dot]);
        }

        Format(buffer, sizeof(buffer), "sound/%s", samples[a]);

        if(!FileExists(buffer, true))
        {
            SetFailState("File '%s' not exist", buffer);
        }


        AddFileToDownloadsTable(buffer);

        Format(buffer, sizeof(buffer), "~%s", samples[a]);
        PrecacheSound(buffer);
    }
}

public Action Whistle(int client, int args)
{

    if( client == 0 || !IsClientInGame(client) || !IsPlayerAlive(client)) return Plugin_Handled;

    if(GetClientTeam(client) == 3)
    {
        ReplyToCommand(client, "[SM] You cant whistle as CT");
        return Plugin_Handled;
    }

    static float timestamps[MAXPLAYERS];
    float timenow = GetEngineTime();

    if(timestamps[client] >= timenow)
    {
        PrintToChat(client, " \x02[SM] You need wait %.1f sec for next whistle", timestamps[client] - timenow);
        return Plugin_Handled;
    }

    timestamps[client] = timenow + 30.0;

    char buffer[PLATFORM_MAX_PATH];
    Format(buffer, sizeof(buffer), "~%s", samples[GetRandomInt(0, sizeof(samples)-1)]);
    EmitSoundToAll(buffer, client, _, SNDLEVEL_CONVO);

    PrintToChatAll(" \x04[SM] ...%N whistled.", client);

    return Plugin_Handled;
}

public Action ForceWhistle(int client, int args)
{

    if( client == 0 || !IsClientInGame(client) || !IsPlayerAlive(client)) return Plugin_Handled;

    if(GetClientTeam(client) == 2)
    {
        ReplyToCommand(client, "[SM] You cant force whistle as T");
        return Plugin_Handled;
    }


    int[] targets = new int[MaxClients];
    int count;

    for(int i = 1; i <= MaxClients; i++)
    {
        if( i == client || !IsClientInGame(i) || !IsPlayerAlive(i) || GetClientTeam(i) != 2) continue;

        targets[count++] = i;
    }

    if(count == 0)
    {
        PrintToChat(client, "[SM] There is no alive players in another team to force whistle.");
        return Plugin_Handled;
    }

    int victim = targets[GetRandomInt(0, count-1)];

    static float timestamps[MAXPLAYERS];
    float timenow = GetEngineTime();

    if(timestamps[client] >= timenow)
    {
        PrintToChat(client, " \x02[SM] You need wait %.1f sec for next force whistle", timestamps[client] - timenow);
        return Plugin_Handled;
    }

    timestamps[client] = timenow + 30.0;



    char buffer[PLATFORM_MAX_PATH];
    Format(buffer, sizeof(buffer), "~%s", samples[GetRandomInt(0, sizeof(samples)-1)]);
    EmitSoundToAll(buffer, victim, _, SNDLEVEL_CONVO);

    PrintToChatAll(" \x04[SM] %N forced %N to whistle.", client, victim);

    return Plugin_Handled;
} 


*edit
I used sound character '~', those seems use in footsteps.

[vegeta1241]

PHP Code:

#include <sourcemod>
#include <sdktools>

char g_sSounds[][] = 
{
    ")ideas/Whistle1.wav",
    ")ideas/Whistle2.wav"
};

ConVar g_cVarLevel;

bool HasWhistle[64];
bool HasForceWhistle[64];

public Plugin myinfo = 
{
    name = "New Plugin",
    author = "Unknown",
    description = "<- Description ->",
    version = "1.0",
    url = "<- URL ->"
}

public void OnPluginStart()
{
    g_cVarLevel = CreateConVar("sm_whistle_level", "70", "Pitch whistle");
    RegConsoleCmd("sm_whistle", Whistle);
    RegConsoleCmd("sm_w", Whistle);
    RegConsoleCmd("sm_forcewhistle", ForceWhistle);
    RegConsoleCmd("sm_fw", ForceWhistle);
}

public void OnMapStart()
{
    for(int i = 0; i < sizeof(g_sSounds); i++)
    {
        char varchar[64];
        Format(varchar, 64, "sound/%s", g_sSounds[i]);
        AddFileToDownloadsTable(varchar);
        PrecacheSound(g_sSounds[i], true);
    }
}

public Action Whistle(int client, int args)
{
    args = 0;
    if(!IsValidClient(client)) return Plugin_Handled;
    if(!IsPlayerAlive(client)) return Plugin_Handled;
    if(GetClientTeam(client) != 2)
    {
        PrintToChat(client, "[IDEAS] You cant whistle as SEEKER");
        return Plugin_Handled;
    }
    if(HasWhistle[client])
    {
        PrintToChat(client, "[IDEAS] You have to wait to whistle again")
    }
    
    new Float:vecPos[3];
    GetClientAbsOrigin(client, vecPos);
    EmitSoundToAll(g_sSounds[GetRandomInt(0, sizeof(g_sSounds)-1)], client, SNDCHAN_AUTO, g_cVarLevel.IntValue, SND_NOFLAGS, 1.0, SNDPITCH_NORMAL, -1, vecPos, NULL_VECTOR, true, 0.0);
    HasWhistle[client] = true;
    CreateTimer(10.0, WhistleAgain, GetClientUserId(client));
    return Plugin_Handled;
}

public Action WhistleAgain(Handle timer, int userid)
{
    int client = GetClientOfUserId(userid);
    if(IsValidClient(client))
    {
        HasWhistle[client] = false;
    }
    delete timer;
    return Plugin_Stop;
}

public Action ForceWhistle(int client, int args)
{
    args = 0;
    if(!IsValidClient(client)) return Plugin_Handled;
    if(!IsPlayerAlive(client)) return Plugin_Handled;
    if(GetClientTeam(client) != 3)
    {
        PrintToChat(client, "[IDEAS] You cant force whistle as HIDER");
        return Plugin_Handled;
    }
    if(HasForceWhistle[client])
    {
        PrintToChat(client, "[IDEAS] You have to wait to force whistle again");
        return Plugin_Handled;
    }
    HasForceWhistle[client] = true;
    CreateTimer(10.0, ForceWhistleAgain, GetClientUserId(client));
    ForceRandomWhistle();
    return Plugin_Handled;
}

public Action ForceWhistleAgain(Handle timer, int userid)
{
    int client = GetClientOfUserId(userid);
    if(IsValidClient(client))
    {
        HasForceWhistle[client] = false;
    }
    delete timer;
    return Plugin_Stop;
}

void ForceRandomWhistle()
{
    int count = 0, cts[32];
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsValidClient(i) && IsPlayerAlive(i) && GetClientTeam(i) == 2)
        {
            cts[count] = i;
            count++;
        }
    }
    if(count == 0)
    {
        PrintToChatAll("[IDEAS] No HIDER found to force whistle");
        return;
    }
    int target = cts[GetRandomInt(0, count-1)];
    PrintToChatAll("[IDEAS] %N whistle", target);
    new Float:vecPos[3];
    GetClientAbsOrigin(target, vecPos); 
    EmitSoundToAll(g_sSounds[GetRandomInt(0, sizeof(g_sSounds)-1)], target, SNDCHAN_AUTO, SNDLEVEL_NORMAL, SND_NOFLAGS, 1.0, SNDPITCH_NORMAL, -1, vecPos, NULL_VECTOR, true, 0.0);
}


bool IsValidClient(int client)
{
    return client > 0 && client <= MaxClients && IsClientInGame(client);
} 


FIXED !! THANK YOU FOR YOUR HELP !!!!

[vegeta1241]

Your script run fine also, I take it and I add the cvar to up level when player is near another player and I like your colors for the time left

[Bacardi]

your welcome

[Bacardi]

I update my last code... There were GetGameTime(), this actually reset back 0 after map change.
So you can't use whistle in loong time in the next map

I replaced with GetEngineTime()