[alphaearth]

15 seconds. How can I change this time with cvar?

PHP Code:

#pragma semicolon 1
#define DEBUG
#define PLUGIN_AUTHOR "LazHoroni"
#define PLUGIN_VERSION "0.00"
#include <sourcemod>
#include <sdktools>
/// #pragma newdecls required

public Plugin myinfo = 
{
    name = "",
    author = PLUGIN_AUTHOR,
    description = "",
    version = PLUGIN_VERSION,
    url = ""
};

public void OnPluginStart()
{
    HookEvent("round_start", laz_RoundStart, EventHookMode_Post);
}

public Action laz_RoundStart(Handle hEvent, const char[] Name, bool dontbroadcast)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i))
        {
            SetCvar("sm_hgr_hook_enable", 0);
            SetCvar("sm_hgr_grab_enable", 0);
            SetCvar("sm_hgr_rope_enable", 0);
            CreateTimer(15.0, HgrTimer);
        }
    }        
}

public Action HgrTimer(Handle timer)
{
    SetCvar("sm_hgr_hook_enable", 1);
    SetCvar("sm_hgr_grab_enable", 1);
    SetCvar("sm_hgr_rope_enable", 1);
}

SetCvar(char cvarName[64], int value)
{
    Handle IntCvar = FindConVar(cvarName);
    if (IntCvar == null)
    return;
    int flags = GetConVarFlags(IntCvar);
    flags &= ~FCVAR_NOTIFY;
    SetConVarFlags(IntCvar, flags);
    SetConVarInt(IntCvar, value);
    flags |= FCVAR_NOTIFY;
    SetConVarFlags(IntCvar, flags);
} 


[Ilusion9]

PHP Code:

#include <sourcemod>
#include <sdktools>

ConVar g_Cvar_Timer;

public void OnPluginStart()
{
    HookEvent("round_start", laz_RoundStart, EventHookMode_Post);
    g_Cvar_Timer = CreateConVar("cvar_name", "15.0");
}

public Action laz_RoundStart(Handle hEvent, const char[] Name, bool dontbroadcast)
{
    SetCvar("sm_hgr_hook_enable", "0");
    SetCvar("sm_hgr_grab_enable", "0");
    SetCvar("sm_hgr_rope_enable", "0");

    CreateTimer(g_Cvar_Timer.FloatValue, HgrTimer);    
}

public Action HgrTimer(Handle timer, any data)
{
    SetCvar("sm_hgr_hook_enable", "1");
    SetCvar("sm_hgr_grab_enable", "1");
    SetCvar("sm_hgr_rope_enable", "1");
}

void SetCvar(const char[] name, const char[] value)
{
    ConVar cvar = FindConVar(name);
    
    if (cvar)
    {
        cvar.flags &= ~FCVAR_NOTIFY;
        cvar.SetString(value);
        cvar.flags |= FCVAR_NOTIFY;
    }
} 


[alphaearth]

C:\Users\User\Desktop\.sp(42) : error 105: cannot find method or property ConVar.flags
C:\Users\User\Desktop\.sp(42) : warning 213: tag mismatch
C:\Users\User\Desktop\.sp(44) : error 105: cannot find method or property ConVar.flags
C:\Users\User\Desktop\.sp(44) : warning 213: tag mismatch

error line:

PHP Code:

cvar.flags &= ~FCVAR_NOTIFY;
cvar.flags |= FCVAR_NOTIFY; 


[farawayf]

create cvar, then

PHP Code:

new Float:htimer = GetConVarFloat(FindConVar("convarname"));
CreateTimer(htimer, HgrTimer); 


[Ilusion9]

PHP Code:

cvar.Flags &= ~FCVAR_NOTIFY;
cvar.Flags |= FCVAR_NOTIFY; 


PHP Code:

#include <sourcemod> 
#include <sdktools> 

ConVar g_Cvar_Timer; 

public void OnPluginStart() 
{ 
    HookEvent("round_start", laz_RoundStart, EventHookMode_Post); 
    g_Cvar_Timer = CreateConVar("sm_hgr_commands_timer", "15.0"); 
} 

public void laz_RoundStart(Event event, const char[] name, bool dontbroadcast) 
{ 
    SetCvar("sm_hgr_hook_enable", "0"); 
    SetCvar("sm_hgr_grab_enable", "0"); 
    SetCvar("sm_hgr_rope_enable", "0"); 

    CreateTimer(g_Cvar_Timer.FloatValue, HgrTimer);     
} 

public void HgrTimer(Handle timer, any data) 
{ 
    SetCvar("sm_hgr_hook_enable", "1"); 
    SetCvar("sm_hgr_grab_enable", "1"); 
    SetCvar("sm_hgr_rope_enable", "1"); 
} 

void SetCvar(const char[] name, const char[] value) 
{ 
    ConVar cvar = FindConVar(name); 
     
    if (cvar) 
    { 
        cvar.Flags &= ~FCVAR_NOTIFY; 
        cvar.SetString(value); 
        cvar.Flags |= FCVAR_NOTIFY; 
    } 
} 


[alphaearth]

I couldn't compile the codes. got an error. I was able to compile these codes without errors.

PHP Code:

#include <sourcemod>
#include <sdktools>
/// #pragma newdecls required
ConVar cvarHgrTime

public void OnPluginStart()
{
    HookEvent("round_start", laz_RoundStart, EventHookMode_Post);
    cvarHgrTime = CreateConVar("sm_hgrtimer", "15.0");
}

public Action laz_RoundStart(Handle hEvent, const char[] Name, bool dontbroadcast)
{
    SetCvar("sm_hgr_hook_enable", "0");
    SetCvar("sm_hgr_grab_enable", "0");
    SetCvar("sm_hgr_rope_enable", "0");
    CreateTimer(GetConVarFloat(cvarHgrTime), HgrTimer);      
}

public Action HgrTimer(Handle timer)
{
    SetCvar("sm_hgr_hook_enable", "1");
    SetCvar("sm_hgr_grab_enable", "1");
    SetCvar("sm_hgr_rope_enable", "1");
}

void SetCvar(const char[] name, const char[] value)  
{  
    ConVar cvar = FindConVar(name);
    if (cvar)
    {
        cvar.Flags &= ~FCVAR_NOTIFY;
        cvar.SetString(value);
        cvar.Flags |= FCVAR_NOTIFY;
    }
}