(req) menu

bazhenov93 · **Author**

i readed some tutorials, but cant understand

if you know how to make a menu that i want, please just write the code, thanks|

i need this:

\r[ \wMenu Title \r]

\r01.\wItem 1
\r02.\wItem 2
\r03.\wItem 3
\r04.\wItem 4
\r05.\wItem 5

\r06.\wPlugin Info
\r0.\wExit

when player choose item 1, a URL to my site with item1MOTD will open
when player choose item 2, a URL to my site with item2MOTD will open and same to 3,4,5

when player choose an item the url is like this:
<html><head><meta http-equiv=^"Refresh^" content=^"2;url=http://mysite_ITEM1.com"></head><body bgcolor='#000000'><center><img src='http://www.mysite.com/loading.gif'></center></body></html>

<html><head><meta http-equiv=^"Refresh^" content=^"2;url=http://mysite_ITEM2.com"></head><body bgcolor='#000000'><center><img src='http://www.mysite.com/loading.gif'></center></body></html>

AND SAME TO 2/3/4/5

when player choose 'Plugin Info', then this plugin will print the text in chat (colorchat | ^x03Plugin by Author. ^x04 visit ^x01 blablabla.com | ^x03Special thanks to YOU for helping.)

AND, to open this MENU, player need to write '/mymenu' (just an example...)
after pressing an item (1/2/3/4/5) , the url to my MOTD will open, but the menu still opened, to not write '/mymenu' again...

IF POSSIBLE, player can write '/menuITEM1' = url blablablaMENU1.com will open | '/menuITEM2' = url blablablaMENU2.com .... etc...

I will very glad if YOU HELP, thanks and GOOD LUCK!

SORRY for my english...

CeDeee · 03-13-2012 , 19:16 Re: (req) menu

Tomorrow I'll do it for you

fysiks · 03-13-2012 , 19:46 Re: (req) menu

Ok, try this. It requires Connor's colorchat.inc to compile.

PHP Code:


			
#include <amxmodx>

#include <colorchat> // Requires: http://forums.alliedmods.net/showpost.php?p=1417992&postcount=90



new const g_szHTMLformat[] = "<html><head><meta http-equiv=^"Refresh^" content=^"2;url=http://mysite_ITEM%d.com^" /></head><body bgcolor=^"#000000^"><center><img src=^"http://www.mysite.com/loading.gif^" /></center></body></html>";

new const g_szPluginInfo[] = "(colorchat | ^x03Plugin by Author. ^x04 visit ^x01 blablabla.com | ^x03Special thanks to YOU for helping.)"

new g_pMenu;



public plugin_init()

{

    register_plugin("Custom Menu", "0.1", "Ford Prefect");

    register_clcmd("say /mymenu", "cmdMyMenu");

    

    g_pMenu = menu_create("\r[ \wMenu Title \r]", "handleMyMenu");

    new szBuffer[12];

    for( new i = 0; i < 5; i++ )

    {

        formatex(szBuffer, charsmax(szBuffer), "Item %d", i+1);

        menu_additem(g_pMenu, szBuffer, "");

        formatex(szBuffer, charsmax(szBuffer), "say menuitem%d", i+1);

        register_clcmd(szBuffer, "cmdOneURL");

    }

    menu_additem(g_pMenu, "Plugin Info", "");

    menu_setprop(g_pMenu, MPROP_EXIT, MEXIT_ALL);

}



public cmdMyMenu(id)

{

    menu_display(id, g_pMenu);

}



public handleMyMenu(id, menu, item)

{

    if( item == MENU_EXIT )

        return;

    

    switch( item )

    {

        case 0..4:

        {

            // MOTD

            static szURL[230];

            formatex(szURL, charsmax(szURL), g_szHTMLformat, item+1);

            show_motd(id, szURL);

            cmdMyMenu(id);

        }

        case 5:

        {

            // Plugin Info

            client_print_color(id, _, g_szPluginInfo);

            cmdMyMenu(id)

        }

    }

    return;

}



public cmdOneURL(id)

{

    new szArg[12];

    static szURL[230];

    

    read_argv(1, szArg, charsmax(szArg));

    formatex(szURL, charsmax(szURL), g_szHTMLformat, szArg[8] - '0');

    show_motd(id, szURL);

}

bazhenov93 · 03-14-2012 , 17:32 Re: (req) menu

Quote:

Originally Posted by fysiks

Ok, try this. It requires Connor's colorchat.inc to compile.

PHP Code:


			
#include <amxmodx>

#include <colorchat> // Requires: http://forums.alliedmods.net/showpost.php?p=1417992&postcount=90



new const g_szHTMLformat[] = "<html><head><meta http-equiv=^"Refresh^" content=^"2;url=http://mysite_ITEM%d.com^" /></head><body bgcolor=^"#000000^"><center><img src=^"http://www.mysite.com/loading.gif^" /></center></body></html>";

new const g_szPluginInfo[] = "(colorchat | ^x03Plugin by Author. ^x04 visit ^x01 blablabla.com | ^x03Special thanks to YOU for helping.)"

new g_pMenu;



public plugin_init()

{

    register_plugin("Custom Menu", "0.1", "Ford Prefect");

    register_clcmd("say /mymenu", "cmdMyMenu");

    

    g_pMenu = menu_create("\r[ \wMenu Title \r]", "handleMyMenu");

    new szBuffer[12];

    for( new i = 0; i < 5; i++ )

    {

        formatex(szBuffer, charsmax(szBuffer), "Item %d", i+1);

        menu_additem(g_pMenu, szBuffer, "");

        formatex(szBuffer, charsmax(szBuffer), "say menuitem%d", i+1);

        register_clcmd(szBuffer, "cmdOneURL");

    }

    menu_additem(g_pMenu, "Plugin Info", "");

    menu_setprop(g_pMenu, MPROP_EXIT, MEXIT_ALL);

}



public cmdMyMenu(id)

{

    menu_display(id, g_pMenu);

}



public handleMyMenu(id, menu, item)

{

    if( item == MENU_EXIT )

        return;

    

    switch( item )

    {

        case 0..4:

        {

            // MOTD

            static szURL[230];

            formatex(szURL, charsmax(szURL), g_szHTMLformat, item+1);

            show_motd(id, szURL);

            cmdMyMenu(id);

        }

        case 5:

        {

            // Plugin Info

            client_print_color(id, _, g_szPluginInfo);

            cmdMyMenu(id)

        }

    }

    return;

}



public cmdOneURL(id)

{

    new szArg[12];

    static szURL[230];

    

    read_argv(1, szArg, charsmax(szArg));

    formatex(szURL, charsmax(szURL), g_szHTMLformat, szArg[8] - '0');

    show_motd(id, szURL);

}

yes it work fine, but how to add items?

1. menu title 1
2. menu title 2
3. menu title 3
4. menu title 3
5. menu title 4

and can't understand the redirect to motd.

menu title 1 = mysite.com/1.html
menu title 2 = mysite.com/2.html
menu title 3 = mysite.com/3.html
menu title 4 = mysite.com/4.html
menu title 5 = mysite.com/5.html

fysiks · 03-14-2012 , 23:52 Re: (req) menu

Ok, so I made it a little more user friendly for you. You just need to edit what you see in quotes starting after the "You should customize stuff here." Note, however, that I did not implement the chat commands in this one because another method must be used when customizability is allowed.

PHP Code:


			
#include <amxmodx>

#include <colorchat> // Requires: http://forums.alliedmods.net/showpost.php?p=1417992&postcount=90



new g_szHTMLformat[250] = "<html><head><meta http-equiv=^"Refresh^" content=^"2;url=%s%s^" /></head><body bgcolor=^"#000000^"><center><img src=^"%s%s^" /></center></body></html>";



// You should customize stuff here.

new const g_szPluginInfo[] = "(colorchat | ^x03Plugin by Author. ^x04 visit ^x01 blablabla.com | ^x03Special thanks to YOU for helping.)";

new const g_szDomain[] = "http://www.mysite.com/";  // You must have the last slash here.



// This shows up as the menu options

new const g_szMenuItems[][] = {

    "Item 1",

    "Item 2",

    "Item 3",

    "Item 4",

    "Item 5"

};



// This is the webpage it goes to at the domain site (e.g. The first one will go do http://www.mysite.com/1.html)

new const g_szWebpages[][] = {

    "1.html",

    "2.html",

    "3.html",

    "4.html",

    "5.html"

};



// This is the thing that will be registered in chat (e.g. say /item1 will be equivalent to choosing option 1.  No spaces.  Each item must be unique.

new const g_szClientCmd[][] = {

    "item1",

    "item2",

    "item3",

    "item4",

    "item5"

};

    

new const g_szImage[] = "loading.gif";

// End Customization



new g_pMenu;



public plugin_init()

{

    register_plugin("Custom Menu", "0.1", "Ford Prefect");

    register_clcmd("say /mymenu", "cmdMyMenu");

    

    format(g_szHTMLformat, charsmax(g_szHTMLformat), g_szHTMLformat, g_szDomain, "%s", g_szDomain, g_szImage);

    

    g_pMenu = menu_create("\r[ \wMenu Title \r]", "handleMyMenu");

    for( new i = 0; i < 5; i++ )

    {

        menu_additem(g_pMenu, g_szMenuItems[i], "");

    }

    menu_additem(g_pMenu, "Plugin Info", "");

    menu_setprop(g_pMenu, MPROP_EXIT, MEXIT_ALL);

}



public cmdMyMenu(id)

{

    menu_display(id, g_pMenu);

}



public handleMyMenu(id, menu, item)

{

    if( item == MENU_EXIT )

        return;

    

    switch( item )

    {

        case 0..4:

        {

            // MOTD

            static szURL[250];

            formatex(szURL, charsmax(szURL), g_szHTMLformat, g_szWebpages[item]);

            show_motd(id, szURL);

            cmdMyMenu(id);

        }

        case 5:

        {

            // Plugin Info

            client_print_color(id, _, g_szPluginInfo);

            cmdMyMenu(id)

        }

    }

    return;

}

bazhenov93 · 03-15-2012 , 08:26 Re: (req) menu

Quote:

Originally Posted by fysiks

Ok, so I made it a little more user friendly for you. You just need to edit what you see in quotes starting after the "You should customize stuff here." Note, however, that I did not implement the chat commands in this one because another method must be used when customizability is allowed.

thankYOU very much! you helped, this plugin work perfect...