Cs 1.6 V.I.P/Admin model Plugin !

alilp · **Author**

Hey !
I tried some of V.I.P/Admin model plugins but non of them worked !
Could you pls make me a working model changer using "ADMIN_CHAT" (my vips has admin_chat permission too ) .

batu07040 · 08-06-2017 , 12:27 Re: Cs 1.6 V.I.P/Admin model Plugin !

Ohh, Basic

Code:

if ( get_user_flags (id) & ADMIN_CHAT )
{

	cs_set_user_model(id,"modelname");	

}

alilp · *Last edited by alilp; 08-06-2017 at 12:43.*

Quote:

Originally Posted by batu07040

Ohh, Basic

Code:

if ( get_user_flags (id) & ADMIN_CHAT )
{

	cs_set_user_model(id,"modelname");	

}

its my code after editing is it right ?

Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

public plugin_init() {
        register_plugin("AMX Admin Model", "1.1.1", "whitemike")
        register_event("ResetHUD", "resetModel", "b")
        return PLUGIN_CONTINUE
}

public plugin_precache() {
        precache_model("models/player/ALILP-VIP/VIP.mdl")
        precache_model("models/player/ALILP-VIP/vipt.mdl")

        return PLUGIN_CONTINUE
}

public resetModel(id, level, cid) {
        if (get_user_flags(id) & ADMIN_CHAT) {

                        cs_set_user_model(id, "VIP")

        }

        return PLUGIN_CONTINUE
}

my signature describe my condition

batu07040 · *Last edited by batu07040; 08-06-2017 at 12:50.*

@alilp;
If you want both teams to look different

Code:

if (get_user_flags (id) & ADMIN_CHAT) 
{

if (get_user_team(id) == 1)
{

cs_set_user_model(id, "vipt")

}

if (get_user_team (id) == 2)
{

cs_set_user_model(id, "VIP")

}


}

alilp · 08-06-2017 , 13:00 Re: Cs 1.6 V.I.P/Admin model Plugin !

@batu07040;
what should i do to use my own vip model instead of cs default vip model?

batu07040 · *Last edited by batu07040; 08-06-2017 at 13:14.*

Change paths you show

so

precache_model("models/player/yourmodel.mdl")
precache_model("models/player/yourmodelt.mdll")

Ayman Khaled · *Last edited by Ayman Khaled; 08-06-2017 at 13:42.*

Quote:

Originally Posted by batu07040

Change paths you show

so

precache_model("models/player/yourmodel.mdl")
precache_model("models/player/yourmodelt.mdll")

precache_model("models/player/yourmodel/yourmodel.mdl")
precache_model("models/player/yourmodelt/yourmodelt.mdll")

alilp · 08-07-2017 , 02:12 Re: Cs 1.6 V.I.P/Admin model Plugin !

i am using precache but it seems its not helping me because it will show default model when i use precache and want to use my own model.
here is my code

Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

public plugin_init() {
        register_plugin("AMX VIP Model", "0.0.1", "ALILP")
        register_event("ResetHUD", "resetModel", "b")
        return PLUGIN_CONTINUE
}

public plugin_precache() {
        precache_model("models/player/ALILP-VIP/ALILP-VIP.mdl")
        precache_model("models/player/ALILP-VIPT/ALILP-VIPT.mdl")
        return PLUGIN_CONTINUE
}

public resetModel(id, level, cid) {
	
if (get_user_flags (id) & ADMIN_CHAT) 
{

if (get_user_team(id) == 1)
{

cs_set_user_model(id, "ALILP-VIPT")

}

if (get_user_team (id) == 2)
{

cs_set_user_model(id, "ALILP-VIP")

}


}
        return PLUGIN_CONTINUE
}

Fuck For Fun · 08-07-2017 , 09:09 Re: Cs 1.6 V.I.P/Admin model Plugin !

Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"

#define FLAG ADMIN_CHAT

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	RegisterHam(Ham_Spawn,"player","FnHamSpawn",1)
}

public plugin_precache()
{
	precache_model("models/player/ALILP-VIPT/ALILP-VIPT.mdl")
	precache_model("models/player/ALILP-VIP/ALILP-VIP.mdl")
}

public FnHamSpawn(id)
{
	if(is_user_alive(id))
	{
		if(get_user_flags(id) & FLAG)
		{
			if(cs_get_user_team(id) == CS_TEAM_CT)
			{
				cs_set_user_model(id,"ALILP-VIP")
			}
			else
			{
				cs_set_user_model(id,"ALILP-VIPT")
			}
		}
	}
}

edon1337 · 08-08-2017 , 06:27 Re: Cs 1.6 V.I.P/Admin model Plugin !

PHP Code:


			
#include < amxmodx >
#include < hamsandwich >
#include < fakemeta >

#define VIP_FLAG ADMIN_LEVEL_H

new const g_szVipModelT[ ] = "vip_model_t" ;
new const g_szVipModelCT[ ] = "vip_model_ct" ;

public plugin_init( ) {

    register_plugin( "VIP Model", "1.0", "DoNii" ) ;

    register_forward( FM_SetClientKeyValue, "fw_FMSetClientKeyValuePre", 0 ) ;
    
    RegisterHam( Ham_Spawn, "player", "fw_HamSpawnPost", 1 ) ;
}

public plugin_precache( ) {

    new szModelT[ 64 ], szModelCT[ 64 ] ;
    
    formatex( szModelT, charsmax( szModelT ), "models/player/%s/%s.mdl", g_szVipModelT, g_szVipModelT ) ;
    precache_model( szModelT ) ;
    
    formatex( szModelCT, charsmax( szModelCT ), "models/player/%s/%s.mdl", g_szVipModelCT, g_szVipModelCT ) ;
    precache_model( szModelCT ) ;
}

public fw_HamSpawnPost( id ) {

    if( ! is_user_alive( id ) )
    return HAM_IGNORED ;
    
    if( ~ get_user_flags( id ) & VIP_FLAG )
    return HAM_IGNORED ;
    
    switch( get_user_team( id ) ) {
        
    case 1: {
            
            set_user_info( id, "model", g_szVipModelT ) ;
        }
        
    case 2: {
            
            set_user_info( id, "model", g_szVipModelCT ) ;
        }
    }

    return HAM_IGNORED ;
}

public fw_FMSetClientKeyValuePre( iPlayer, const szBuffer[ ], const szKey[ ] ) {

    if( equal( szKey, "model" ) ) {
        
        if( get_user_flags( iPlayer ) & VIP_FLAG ) {

            switch( get_user_team( iPlayer ) ) {
                
            case 1: {
                    
                    set_user_info( iPlayer, "model", g_szVipModelT ) ;
                    return FMRES_SUPERCEDE ;
                }
                
            case 2: {
                    
                    set_user_info( iPlayer, "model", g_szVipModelCT ) ;
                    return FMRES_SUPERCEDE ;
                }
            }
        }
    }
    
    return FMRES_IGNORED ;
}