[Austin]

What is the scripting technique to keep bots from using the he nade?

I don't want to set bot_allow_grenades 0 because I only want to limit their use for the first 20 seconds into the round and only limit the he nade and allow the others.

[BallGanda]

I bet the hack way to do it for all nades is

I am assuming that bots do not buy nades if bot_allow_grenades 0... which might not be the case.

in config:
bot_allow_grenades 1

plugin:
onroundstart
bot_allow_grenades 1
wait buytime
bot_allow_grenades 0
wait 20 seconds
bot_allow_grenades 1


If bots still buy nades with bot_allow_grenades 0

in config:
bot_allow_grenades 0

onroundstart
bot_allow_grenades 0
wait 20 seconds
bot_allow_grenades 1

but I am probably not one with the best idea.

To do the specific nade type would look at weapon restrict plugin sourcecode and get the specific code that does not allow the player/bot to equip the nade.

[luki1412]

Just remove the weapon if it gets equipped. Could also store if you did remove it and give it back to them after the timeout.

[Bacardi]

PHP Code:


#include <sdkhooks>


bool botpreventgrenade;

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }

    HookEvent("round_start", round_start);
}

public void OnClientPutInServer(int client)
{
    if(IsFakeClient(client) && !IsClientReplay(client) && !IsClientSourceTV(client))
    {
        SDKHook(client, SDKHook_WeaponSwitch, WeaponSwitch);
        //SDKHook(client, SDKHook_WeaponCanSwitchTo, WeaponCanSwitchTo);
    }
}

public Action WeaponSwitch(int client, int weapon)
{
    if(botpreventgrenade && HasEntProp(weapon, Prop_Send, "m_bPinPulled"))
    {
        char clsname[35];
        GetEntityClassname(weapon, clsname, sizeof(clsname));

        if(!StrEqual(clsname, "weapon_hegrenade", false))
            return Plugin_Continue;

        return Plugin_Handled;
    }

    return Plugin_Continue;
}

public Action WeaponCanSwitchTo(int client, int weapon)
{
    if(botpreventgrenade && HasEntProp(weapon, Prop_Send, "m_bPinPulled"))
    {
        char clsname[35];
        GetEntityClassname(weapon, clsname, sizeof(clsname));

        if(!StrEqual(clsname, "weapon_hegrenade", false))
            return Plugin_Continue;

        return Plugin_Handled;
    }
    
    return Plugin_Continue;
}



public void round_start(Event event, const char[] name, bool dontBroadcast)
{
    botpreventgrenade = true;
    CreateTimer(30.0, delay); // + mp_round_restart_delay
}

public Action delay(Handle timer)
{
    botpreventgrenade = false;
    return Plugin_Continue;
} 


[Austin]

bacardi,
thanks again!

I added some logging and it seems to work really well.

L 12/27/2022 - 028:16: Ron - Denied bot from using HE Nade...
L 12/27/2022 - 028:16: Gary - Denied bot from using HE Nade...

I needed this for my bot server where I wrote a plugin to boost the HE damage and radius (so they are actually useable) and this along with the csgo bots tendency to fire off HEs right at the start was a bad combination! This is a perfect solution thank you.

To anyone that may want this I attached a plugin with a cvar to set the time for the delay.
abs_bot_nade_delay

The default delay is ten seconds.