[Airkish]

It doesn't work or am I doing something wrong?
I get -1 even tho Array String is filled with user's name and I'm searching using same variable.

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "PLUGIN"
#define VERSION "1.0.0"
#define AUTHOR "AUTHOR"

enum _:MarketData
{
    RowId,
    Seller[32],
    SkinId,
    CaseId,
    KeyId,
    Quantity,
    Float:Price
}


new Array:g_aArray;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("say test", "testout");

    g_aArray = ArrayCreate(MarketData);
}

public testout(id) {
    new Data[MarketData];

    new szName[32];
    get_user_name(id, szName, charsmax(szName));

    for (new i; i < 5; i++)
    {
        Data[RowId] = i;
        copy(Data[Seller], charsmax(Data[Seller]), szName);
        Data[SkinId] = random_num(1, 59);
        Data[CaseId] = random_num(1, 59);
        Data[KeyId] = random_num(1, 59);
        Data[Quantity] = random_num(1, 59);
        Data[Price] = random_float(1.0, 59.0);
        ArrayPushArray(g_aArray, Data);
    }

    new ItemExists = ArrayFindString(g_aArray, szName);
    client_print_color(id, print_team_default, "%d", ItemExists);
} 


[CrazY.]

What you did doesn't make any sense, you should probably use celltrie instead.
Untested.

#include <amxmodx> 
#include <amxmisc> 

#define PLUGIN "PLUGIN" 
#define VERSION "1.0.0" 
#define AUTHOR "AUTHOR" 

enum _:MarketData 
{ 
    RowId, 
    Seller[32], 
    SkinId, 
    CaseId, 
    KeyId, 
    Quantity, 
    Float:Price 
} 


new Trie:g_trieArray; 

public plugin_init() 
{ 
    register_plugin(PLUGIN, VERSION, AUTHOR) 
    register_clcmd("say test", "testout"); 

    g_trieArray = TrieCreate(); 
} 

public testout(id) { 
    new Data[MarketData]; 

    new szName[32]; 
    get_user_name(id, szName, charsmax(szName)); 
    Data[RowId] = 1; 
    copy(Data[Seller], charsmax(Data[Seller]), szName); 
    Data[SkinId] = random_num(1, 59); 
    Data[CaseId] = random_num(1, 59); 
    Data[KeyId] = random_num(1, 59); 
    Data[Quantity] = random_num(1, 59); 
    Data[Price] = random_float(1.0, 59.0); 
    TrieSetArray(g_trieArray, szName, Data, sizeof Data);

    /*for (new i; i < 5; i++) 
    { 
        Data[RowId] = i; 
        copy(Data[Seller], charsmax(Data[Seller]), szName); 
        Data[SkinId] = random_num(1, 59); 
        Data[CaseId] = random_num(1, 59); 
        Data[KeyId] = random_num(1, 59); 
        Data[Quantity] = random_num(1, 59); 
        Data[Price] = random_float(1.0, 59.0); 
        ArrayPushArray(g_aArray, Data); 
    }*/



    new ItemExists = TrieKeyExists(g_trieArray, szName); // Return true if the key is set, false otherwise
    client_print_color(id, print_team_default, "%d", ItemExists); 
}

[edon1337]

Not sure what you're trying to do but try this.

PHP Code:

#include < amxmodx >

new const g_szNames[ ] =
{
    "John",
    "Mark",
    "Jimmy",
    "Charles",
    "Tim"
}

enum _:MarketData
{
    szSeller[ 32 ],
    iSkinId,
    iCaseId,
    iKeyId,
    iQuantity,
    Float:fPrice
}

const iItemsCount = 5;

new Array:g_aArray;

public plugin_init( )
{
    register_clcmd( "say /market", "@Market" );

    g_aArray = ArrayCreate( MarketData );
}

@Market( id )
{
    new eData[ MarketData ];
    
    for( new i; i < iItemsCount; i++ )
    {
        eData[ szSeller ] = g_szNames[ i ];
        eData[ iSkinId ] = random_num( 1, 59 );
        eData[ iCaseId ] = random_num( 1, 59 );
        eData[ iKeyId ] = random_num( 1, 59 );
        eData[ iQuantity ] = random_num( 1, 59 );
        eData[ fPrice ] = _:random_float( 1.0, 59.0 );
        
        ArrayPushArray( g_aArray, eData );
    }

    arrayset( eData, 0, sizeof( eData[ ] ) );
    
    new szName[ 32 ], iExists;
    get_user_name( id, szName, charsmax( szName ) );
    
    for( new i; i < ArraySize( g_aArray ); i++ )
    {
        ArrayGetArray( g_aArray, i, eData );
        
        if( equal( szName, eData[ szSeller ] ) )
        {
            iExists = i;
            break;
        }
    }
    client_print_color( id, print_team_default, "%d", iExists );
} 


[Airkish]

Thanks for answers, both working fine, gonna use 'em.
But can anyone tell me why exactly is ArrayFindString doesn't work?

P.S. This plugin is just for testing purposes, since u asked what I'm trying to achieve.

[CrazY.]

It doesn't work because you're searching for a string in an "array of arrays", I mean, a cellarray where arrays are stored.

for (new i; i < 5; i++) { Data[RowId] = i; copy(Data[Seller], charsmax(Data[Seller]), szName); Data[SkinId] = random_num(1, 59); Data[CaseId] = random_num(1, 59); Data[KeyId] = random_num(1, 59); Data[Quantity] = random_num(1, 59); Data[Price] = random_float(1.0, 59.0); ArrayPushArray(g_aArray, Data); }

ArrayFindString will only work properly if you search through an array of strings as the example below.

new Array:aStrings = ArrayCreate(32, 1);
ArrayPushString(aStrings, "String 2");
ArrayPushString(aStrings, "String 1");
ArrayPushString(aStrings, "String 5");
ArrayPushString(aStrings, "String 3");
ArrayPushString(aStrings, "String 4");
server_print("^"String 5^" index = %d", ArrayFindString(aStrings, "String 5"))

If you're searching for a string in an array of arrays, edon's code it's the solution.