[wicho]

Hi everybody, well I want to create a mini game that consists of the players only having the HE grenade and the objective is to throw them at the players, if the grenade touches the player he dies instantly, if the player throws the grenade and fails I want the moment he touches the ground disappears, I don't want it to explode just that it disappears and gives the player another grenade, my questions are first how can I make when the player receives the blow of the grenade dies instantly, second how can I make when the grenade touches the ground or anything other than the player removes the grenade and gives the player a new one, could you please give me an example? ... Thanks in advance

[Bugsy]

Try this

PHP Code:


#include <amxmodx>
#include <hamsandwich>
#include <engine>
#include <fakemeta>
#include <fun>

new const Version[] = "0.1";

#define MAX_PLAYERS 32

#define IsPlayer(%1)    (1<=%1<=MAX_PLAYERS)

public plugin_init() 
{
    register_plugin( "Grenades" , Version , "bugsy" );
    
    RegisterHam( Ham_Touch , "grenade" , "Grenade_Touch" );
    register_forward( FM_SetModel , "SetModel" , 1 );
}

public Grenade_Touch( iToucher , iTouched )
{
    if ( cs_get_grenade_type( iToucher ) == CSW_HEGRENADE )
    {
        new iGrenadeThrower = pev( iToucher , pev_owner );
        
        if ( IsPlayer( iTouched ) )
        {
            set_pev( iToucher , pev_dmgtime , 0.0 );
            ExecuteHam( Ham_TakeDamage , iTouched , iToucher , iGrenadeThrower , 999.9 , DMG_GRENADE );
        }
        else
        {
            set_pev( iToucher , pev_flags , pev( iToucher , pev_flags ) | FL_KILLME );
            call_think( iToucher );
        }
        
        if ( is_user_alive( iGrenadeThrower ) )
            give_item( iGrenadeThrower , "weapon_hegrenade" );

        return HAM_HANDLED;
    }
    
    return HAM_IGNORED;
} 


public SetModel( iEntity , const szModel[] )
{
    if ( cs_get_grenade_type( iEntity ) == CSW_HEGRENADE )
    {
        set_pev( iEntity , pev_dmgtime , 99999.0 );
    }
}
    
cs_get_grenade_type( index ) 
{
    if (!pev_valid(index))
        return 0
    
    new classname[9]
    pev(index, pev_classname, classname, 8)
    
    if (!equal(classname, "grenade"))
        return 0
    
    if (get_pdata_int(index, 96) & (1<<8))
        return CSW_C4
    
    new bits = get_pdata_int(index, 114)
    
    if (bits & (1<<0))
        return CSW_HEGRENADE
    else if (bits & (1<<1))
        return CSW_SMOKEGRENADE
    else if (!bits)
        return CSW_FLASHBANG
    
    return 0
} 


[wicho]

ok thanks i will try it when i get to my house, i just forgot to ask something else, how can i do so that the grenade doesn't explode in the air? I mean, when you throw the grenade in the air, it is only removed when it touches the ground or when it hits the player. Another thing if the player hits the player also gives him a grenade. thx for your help

[Bugsy]

Above code is updated based on your comments.

[JocAnis]

Good job Bugsy, one question, what is exactly 'call_think' doing? I hope it can be used for smth else beside hegrenade

[Natsheh]

He used it to safely remove the entity after giving the entity the Flag FL_KILLME

[Bugsy]

That is how I am killing the grenade entity, after setting the FL_KILLME flag.

[JocAnis]

Hm okay, interesting

Ps nice timing hah

[wicho]

bugsy I tested your code and it works fine but sometimes when I throw the grenade it doesn't give me a new grenade, I think that happens when I throw it to a map entity (func_wall, etc)

[Bugsy]

Originally Posted by wicho bugsy I tested your code and it works fine but sometimes when I throw the grenade it doesn't give me a new grenade, I think that happens when I throw it to a map entity (func_wall, etc)

Ok, try the above updated code.