For starters, Avalanche did provide adequate help (but missed the write_coord(origin[id][2]) + 10 bit
), you just didn't specify exactly what you wanted.. it seems more clear from your second post, so I will guess at what it is you want and try to provide a brief explanation..
Well, you dont need origin[33][3] if you are using the origins locally only, so use origin[3] instead, since you dont need to store the origins of every player when you are only using the origins of one player..
Basically, get_user_origin() function accepts 2 parameters: the id of the user to get the origin of (which I am sure you understood that) and secondly is an array of 3 variables which specify the X, Y, Z coordinates of the user in 3D Space... You simply make an array of 3 like:
new MyOriginArray[3]
Then pass it to the function like:
get_user_origin( id, MyOriginArray )
Then, after the call to that function, the array will hold the users coordinates:
MyOriginArray[0] will equal the X Coordinate
MyOriginArray[1] will equal the Y Coordinate
MyOriginArray[2] will equal the Z Coordinate
Also, try not to return PLUGIN_HANDLED from AMXX Forwards like plugin_init() or plugin_precache() etc.. , return PLUGIN_CONTINUE instead..
You dont need to include <amxconst> since it is included already by <amxmodx>
This block is completely wrong:
Code:
if(get_user_flags(id)&&ADMIN_KICK)
set_user_godmode(id)
return PLUGIN_HANDLED
else (!get_user_flags(id)&&ADMIN_KICK)
client_print(id, print_chat, "[AMXX] HAHAHA nice try!")
if(get_user_flags(id)&&ADMIN_KICK)
should be:
if(get_user_flags(id)&ADMIN_KICK)
Notice the single ampersand (&) which specifies Bit-Wise Comparison...
Also there should be Curly-Brackets around the first IF clause (because you have more than one statement), the "else" should be "else if" since you are specifying an additional comparison (otherwise leave out everything after "else" on the same line)
Plus your logic is wrong, you have: If the user has Access give god mode then exit function, else if user doesnt have access then print a message and do the lightning effect (which seems wrong, maybe that was your intentions, idk)...
Lastly, you had:
write_coord(origin[2]) + 10 // z2 coord
which should be:
write_coord(origin[2] + 10) // z2 coord
Notice the + 10 is inside the brackets, so that the sum is calculated first, then the resulting value is passed to the write_coord() function..
I hope that helps a bit, also here is a revised version (not tested)..
Code:
#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <engine>
new light
public plugin_init()
{
register_plugin("Unknown", "0.5", "Garrett")
register_clcmd("say givemegod", "saygod", ADMIN_KICK, "-gives player godmode")
}
public plugin_precache()
{
light = precache_model("sprites/lgtning.spr")
return PLUGIN_CONTINUE
}
public saygod(id)
{
if( !(get_user_flags(id)&ADMIN_KICK) )
{
client_print(id, print_chat, "[AMXX] HAHAHA nice try!")
return PLUGIN_HANDLED
}
// Set God Mode on User
set_user_godmode(id)
// Generate Lightning at user origin
new origin[3]
get_user_origin(id,origin)
message_begin(MSG_ALL,SVC_TEMPENTITY)
write_byte(7) // number of tempevent
write_coord(origin[0]) // x coord
write_coord(origin[1]) // y coord
write_coord(origin[2]) // z coord
write_coord(origin[0]) // x2 coord
write_coord(origin[1]) // y2 coord
write_coord(origin[2] + 10) // z2 coord
write_byte(2) // life
write_byte(5) // width
write_byte(5) // amplitude
write_short(light) // sprite index
message_end()
return PLUGIN_HANDLED
}
heehee, i guess that was a bit much..
Linear Mode
