[Dragonshadow]

I remember seeing it in several plugins (naris made them I think?) detects the mod based on the mod folder... I just can't find it.

Anyone know what I'm talking about and have it?

[Antithasys]

PHP Code:

new String:sGameType[64];
GetGameFolderName(sGameType, sizeof(sGameType));
    
if (StrEqual(sGameType, "cstrike", false))
{
    //something
} 


[exvel]

PHP Code:

#define GAME_ANY 0
#define GAME_CS 1
#define GAME_TF 2
#define GAME_HL 3
#define GAME_DOD 4

new Game = GAME_ANY;

public OnPluginStart()
{    
    // Getting a game name and doing game specific stuff
    decl String:gameName[30];
    GetGameFolderName(gameName, sizeof(gameName));
    
    // CS stuff
    if (StrEqual(gameName, "cstrike", false))
    {
        Game = GAME_CS;
        
        CS_Stuff();
    }
    // TF stuff
    else if (StrEqual(gameName, "tf", false))
    {
        Game = GAME_TF;
        
        TF_Stuff();
    }
    // HL stuff
    else if (StrEqual(gameName, "hl2mp", false))
    {
        Game = GAME_HL;
        
        HL_Stuff();
    }
    // L4D is completely unsupported
    else if (StrEqual(gameName, "left4dead", false))
    {
        SetFailState("This game is not supported");
    }
    // For all other games we will do standart stuff
    else
    {
        Game = GAME_ANY;
        
        // Hooking commands for detecting of new game start
        cvar_restartgame = FindConVar("mp_restartgame");
        if (cvar_restartgame != INVALID_HANDLE)
            HookConVarChange(cvar_restartgame, NewGameCommand);
        
        cvar_restartround = FindConVar("mp_restartround");
        if (cvar_restartround != INVALID_HANDLE)
            HookConVarChange(cvar_restartround, NewGameCommand);
        
        // Hooking events for detecting of new game start
        HookEvent("round_start", Event_NewGameStart);
        HookEvent("round_end", Event_RoundEnd);
    }
} 


This is an example from my savescores plugin. It looks a little bit big... I know but the main idea is that you only need GetGameFolderName function for getting game short name (folder name) and then just use StrEqual to match game names and do specific stuff.
In my example there is also Game variable that is integer and stores defined game number. This is useful during the plugin work because always using GetGameFolderName when there are many players on the server isn't a good idea. This will work much faster:

PHP Code:

if (Game == GAME_CS)
{
    // do something
} 


[javalia]

i am agreeing at all to exvel.
i made almost same thing with exvel`s one for my new mod, tremulous(in dev)
but i used enum lolf it is just my favorite lol

[exvel]

I think enums are better because there is no difference which number contains in the Game variable. But I wrote this code a long time ago and I didn't know about enums

[Antithasys]

Ya. Take a look at the simple-plugins.inc file. It basically does this for you. And yes, it uses enums. lol.

[naris]

I use the attached include file with this function/enum:

PHP Code:

enum Mod { undetected, tf2, cstrike, dod, hl2mp, insurgency, other };
stock Mod:GameType = undetected;

stock Mod:GetGameType()
{
    if (GameType == undetected)
    {
        new String:modname[30];
        GetGameFolderName(modname, sizeof(modname));
        if (StrEqual(modname,"cstrike",false))
            GameType=cstrike;
        else if (StrEqual(modname,"tf",false)) 
            GameType=tf2;
        else if (StrEqual(modname,"dod",false)) 
            GameType=dod;
        else if (StrEqual(modname,"hl2mp",false)) 
            GameType=hl2mp;
        else if (StrEqual(modname,"Insurgency",false)) 
            GameType=insurgency;
        else
            GameType=other;
    }
    return GameType;
} 


[Dragonshadow]

Originally Posted by naris I use the attached include file with this function/enum: PHP Code: enum Mod { undetected, tf2, cstrike, dod, hl2mp, insurgency, other }; stock Mod:GameType = undetected; stock Mod:GetGameType() {     if (GameType == undetected)     {         new String:modname[30];         GetGameFolderName(modname, sizeof(modname));         if (StrEqual(modname,"cstrike",false))             GameType=cstrike;         else if (StrEqual(modname,"tf",false))              GameType=tf2;         else if (StrEqual(modname,"dod",false))              GameType=dod;         else if (StrEqual(modname,"hl2mp",false))              GameType=hl2mp;         else if (StrEqual(modname,"Insurgency",false))              GameType=insurgency;         else             GameType=other;     }     return GameType; }

thank you