[Solved] troubles with TextMsg

kww · **Author**

Hello. I'm trying to show defuser's/planter's name on dhud but defuser's name is not showing. what i'm doing wrong?

PHP Code:


			
//including all i need

#include <amxmodx>

#include <csx> //to get who's planted/defused the bomb

#include <dhudmessage> //to show message on screen



//created some vars

new g_teamname_ct, g_teamname_t // for custom teamnames

new g_planter_name[32], g_defuser_name[32]



//registered cvars

public plugin_init() {

    register_message(get_user_msgid("TextMsg"), "onMessageSent")

    

    register_logevent("onFreezeEnd", 2, "1=Round_Start")

    

    g_teamname_ct = register_cvar("mp_teamname_ct", "Counter-Terrorists", FCVAR_SERVER)

    g_teamname_t = register_cvar("mp_teamname_t", "Terrorists", FCVAR_SERVER)

}

//clear playernames on freezetime end

public onFreezeEnd() {

    g_defuser_name = ""

    g_planter_name = ""

}



//get player name depending on the event

public bomb_defused(defuser) {

    get_user_name(defuser, g_defuser_name, charsmax(g_defuser_name))

}



public bomb_planted(planter) {

    get_user_name(planter, g_planter_name, charsmax(g_planter_name))

}



//catch bombed or defused

public onMessageSent(iMessage, iDest, id) {

    static szMessage[64]

    get_msg_arg_string(2, szMessage, charsmax(szMessage))

    

    static teamname[32]

    new szText[64*2]



    if(equali(szMessage, "#Bomb_Defused")) {

        get_pcvar_string(g_teamname_ct, teamname, charsmax(teamname))

        formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for defusing the bomb", teamname, g_defuser_name)

        

         //these values are predefined so dhud messages showng

        set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)

        show_dhudmessage(id, szText)

        return PLUGIN_HANDLED

    }

    else if(equali(szMessage, "#Target_Bombed")) {

        get_pcvar_string(g_teamname_t, teamname, charsmax(teamname))

        formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for planting the bomb", teamname, g_planter_name)

        

        set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)

        show_dhudmessage(id, szText)

        return PLUGIN_HANDLED

    }

    

    return PLUGIN_CONTINUE

}

redivcram · 03-16-2021 , 14:23 Re: troubles with TextMsg

How are bomb_defused() and bomb_planted() called in your code?

kww · *Last edited by kww; 03-16-2021 at 14:34.*

Quote:

Originally Posted by redivcram

How are bomb_defused() and bomb_planted() called in your code?

I've included <csx> and used mentioned forwards. Or what do u mean?

jimaway · 03-16-2021 , 17:07 Re: troubles with TextMsg

send the dhud messages straight from the csx forwards and get rid of the textmsg forward.

Shadows Adi · 03-16-2021 , 17:11 Re: troubles with TextMsg

You can solve this in two ways:
1. Setting a task when your message is triggered, because bomb_defused() forward is called after #Bomb_Defused cstrike message. Example:

PHP Code:


			
#include <amxmodx>
#include <csx> //to get who's planted/defused the bomb
#include <dhudmessage> //to show message on screen

//created some vars
new g_teamname_ct, g_teamname_t // for custom teamnames
new g_planter_name[32], g_defuser_name[32]

//registered cvars
public plugin_init() {
    register_message(get_user_msgid("TextMsg"), "onMessageSent")
    
    register_logevent("onFreezeEnd", 2, "1=Round_Start")
    
    g_teamname_ct = register_cvar("mp_teamname_ct", "Counter-Terrorists", FCVAR_SERVER)
    g_teamname_t = register_cvar("mp_teamname_t", "Terrorists", FCVAR_SERVER)
}
//clear playernames on freezetime end
public onFreezeEnd() {
    g_defuser_name = ""
    g_planter_name = ""
}

//get player name depending on the event
public bomb_defused(defuser) {
    get_user_name(defuser, g_defuser_name, charsmax(g_defuser_name))
}

public bomb_planted(planter) {
    get_user_name(planter, g_planter_name, charsmax(g_planter_name))
}

//catch bombed or defused
public onMessageSent(iMessage, iDest, id) {
    static szMessage[64]
    get_msg_arg_string(2, szMessage, charsmax(szMessage))
    
    static teamname[32]
    new szText[64*2]

    if(equali(szMessage, "#Bomb_Defused")) {
        set_task(0.2, "task_show_defuser")
        return PLUGIN_HANDLED
    }
    else if(equali(szMessage, "#Target_Bombed")) {
        get_pcvar_string(g_teamname_t, teamname, charsmax(teamname))
        formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for planting the bomb", teamname, g_planter_name)
        
        set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)
        show_dhudmessage(0, szText)
        return PLUGIN_HANDLED
    }
    
    return PLUGIN_CONTINUE
}

public task_show_defuser()
{
    static teamname[32]
    new szText[128]
    get_pcvar_string(g_teamname_ct, teamname, charsmax(teamname))
    formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for defusing the bomb", teamname, g_defuser_name)
    
     //these values are predefined so dhud messages showng
    set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)
    show_dhudmessage(0, szText)
}

2. You can do it in called forward for every event. Example:

PHP Code:


			
#include <amxmodx>
#include <csx> //to get who's planted/defused the bomb
#include <dhudmessage> //to show message on screen

enum _:Event
{
    BombPlanted = 0,
    BombDefused
}

//created some vars
new g_teamname_ct, g_teamname_t // for custom teamnames
new g_planter_name[32], g_defuser_name[32]

//registered cvars
public plugin_init() {
    register_logevent("onFreezeEnd", 2, "1=Round_Start")
    
    g_teamname_ct = register_cvar("mp_teamname_ct", "Counter-Terrorists", FCVAR_SERVER)
    g_teamname_t = register_cvar("mp_teamname_t", "Terrorists", FCVAR_SERVER)
}
//clear playernames on freezetime end
public onFreezeEnd() {
    g_defuser_name = ""
    g_planter_name = ""
}

//get player name depending on the event
public bomb_defused(defuser) {
    get_user_name(defuser, g_defuser_name, charsmax(g_defuser_name))
    ShowEvent(BombDefused)
}

public bomb_planted(planter) {
    get_user_name(planter, g_planter_name, charsmax(g_planter_name))
    ShowEvent(BombPlanted)
}

public ShowEvent(Event:iType)
{
    static teamname[32]
    new szText[128]

    switch(iType)
    {
        case BombPlanted:
        {
            get_pcvar_string(g_teamname_t, teamname, charsmax(teamname))
            formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for planting the bomb", teamname, g_planter_name)
        
            set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)
            show_dhudmessage(0, szText)
        }
        case BombDefused:
        {
            get_pcvar_string(g_teamname_ct, teamname, charsmax(teamname))
            formatex(szText, charsmax(szText), "%s Wins The Round^nMVP: %s for defusing the bomb", teamname, g_defuser_name)
        
             //these values are predefined so dhud messages showng
            set_dhudmessage(DH_R_STD, DH_G_STD, DH_B_STD, DH_XPOS, DH_YPOS, DH_FX, DH_FX_TIME, DH_HOLD_TIME, DH_FADEIN, DH_FADEOUT)
            show_dhudmessage(0, szText)
        }
    }
}

Not tested the codes provided above.

Also, you could take a look on this MVP Plugin which provides more functionalities: https://forums.alliedmods.net/showthread.php?t=327690

kww · *Last edited by kww; 03-17-2021 at 09:56.*

Quote:

Originally Posted by Shadows Adi

... because bomb_defused() forward is called after #Bomb_Defused cstrike message

hmm... interesting. I didn't know about it. I'll try 1st way because it would suit me better, i think
EDIT: task give me many errors

Shadows Adi · 03-17-2021 , 11:10 Re: troubles with TextMsg

Quote:

Originally Posted by kww

hmm... interesting. I didn't know about it. I'll try 1st way because it would suit me better, i think
EDIT: task give me many errors

Edited the first code given, try it now. I didn't tested codes, could you post the errors?

kww · 03-18-2021 , 06:37 Re: troubles with TextMsg

Quote:

Originally Posted by Shadows Adi

Edited the first code given, try it now. I didn't tested codes, could you post the errors?

Ok, i compiled the code and it works but dhud not appears on bomb defuse.

Shadows Adi · 03-18-2021 , 06:59 Re: troubles with TextMsg

Quote:

Originally Posted by kww

Ok, i compiled the code and it works but dhud not appears on bomb defuse.

Did you tried both codes?
Also, debug the code:

PHP Code:


			
public bomb_defused(defuser) {

    get_user_name(defuser, g_defuser_name, charsmax(g_defuser_name))

    client_print(0, print_chat, "forward bomb_defused() called")

}

kww · *Last edited by kww; 03-18-2021 at 07:36.*

Quote:

Originally Posted by Shadows Adi

Did you tried both codes?

no. should i?

Quote:

Originally Posted by Shadows Adi

Also, debug the code:

PHP Code:


			
public bomb_defused(defuser) {

    get_user_name(defuser, g_defuser_name, charsmax(g_defuser_name))

    client_print(0, print_chat, "forward bomb_defused() called")

}

I made it right after starting this topic and it calling successfully every time it needed

Ok, I'll send dhud message right in bomb_defused() forward (but I didn't want to do it)