[alasfourom]

Hello guys

I would love to see if there is a way for only ghost infected to execute commands like:
1- sm_goto > ghost infected will be able to go to any player (survivors, SI both ghost and non ghost)
2- sm_bring > which u can bring only ghost infected and can be executed by both ghost and non ghost infected > this command should have delay time once executed like 30 seconds or if "sm_bring XXX" executed, The XXX player will have a panel to accept or refuse the teleportation request

I don't know if that is possible

I would suggest this mainly for two reasons:
I was playing in few "Competitive Versus" with +8 players, and its chaos, sometimes someone wants you to steel a player or helping him/her but you are far away and you don't have a lot of time to search or spectate.

The second reason is, many times specially when there are +8 players, spectating will bugged and only focus on few players not able to spectate rest and even unable to press "E" to check for others as a ghost. This is really common, last game it was 10 v 10, 2 ppl rushed, rest are back, and I only able to spectate those who rushed and went to the saferoom. costing me a lot of time, I had to move as a ghost to reach to back players every time which is really annoying.

I hope I made my point clear

thanks

[Toranks]

I'm sure I saw a plugin that was dedicated to solving just those versus issues when more than 8 players.
It had some demo images. But now I can't find it! Dammit
Another problem that it solved is that it does not count the score properly when some survivors are too far away from the others. And only count the points of the first 4 survivors.
Do a search, and if I happen to find it, I'll put the link here.

[alasfourom]

If that would fix this annoying issue, I would be really glad to try it out.

Thanks Toranks

[alasfourom]

Is there a way to make commands executable only by ghosts at least?

If so, please share the way, thanks

[Marttt]

Just check the netprop:

PHP Code:

bool IsPlayerGhost(int client)
{
    return (GetEntProp(client, Prop_Send, "m_isGhost") == 1);
} 


[alasfourom]

Thanks Marttt

I will try, thanks as always ����

[alasfourom]

Hey Marttt, I was able to make it work

Thanks a lot

[alasfourom]

Here is the script


This will allow only ghost infected to use the "sm_goto" command, which will save you time specially in +4 players versus

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo =
{
    name = "Ghost Goto Command",
    author = "alasfourom",
    description = "Ghost Infected Can Use Goto Command",
    version = "1.0",
    url = "https://www.sourcemod.net/"
};

public void OnPluginStart()
{
    RegConsoleCmd("sm_goto", Command_Goto, "Allow Ghost Infected To Use Goto Command");
        
    LoadTranslations("common.phrases");
}

bool IsPlayerGhost (int client)
{
    return (GetEntProp(client, Prop_Send, "m_isGhost") == 1);
}

public Action Command_Goto(int client, int args)
{
    
    if (args == 0)
    {
        ReplyToCommand(client, "\x04[Ghost] \x01Usage: sm_goto \x03<#userid|name>");
        return Plugin_Handled;
    }
    
    if (!IsPlayerGhost(client))
    {
        ReplyToCommand(client, "\x04[Ghost] \x01Only \x03ghost infected \x01can teleport to players.");
        return Plugin_Handled;
    }
    
    if (IsPlayerGhost(client))
    {
        float fTeleportOrigin[3];
        float fPlayerOrigin[3];

        char sArg1[MAX_NAME_LENGTH];
        GetCmdArg(1, sArg1, sizeof(sArg1));
        int destination = FindTarget(client, sArg1);
        
        if (!IsPlayerAlive(destination))
        {
            ReplyToCommand(client, "\x04[Ghost] \x01Player \x03%N \x01is currently dead.", destination);
            return Plugin_Stop;
        }
        
        GetClientAbsOrigin(destination, fPlayerOrigin);

        fTeleportOrigin[0] = fPlayerOrigin[0];
        fTeleportOrigin[1] = fPlayerOrigin[1];
        fTeleportOrigin[2] = (fPlayerOrigin[2] + 5);
    
        TeleportEntity(client, fTeleportOrigin, NULL_VECTOR, NULL_VECTOR);
        ReplyToCommand(client, "\x04[Ghost] \x01You have been successfully brought to \x03%N\x01.", destination);
        return Plugin_Handled;
        
    }
    return Plugin_Handled;
} 


You can also remove these lines if you want to be teleported even to the location of the last destination of dead players.

PHP Code:

        if (!IsPlayerAlive(destination))
        {
            ReplyToCommand(client, "\x04[Ghost] \x01Player \x03%N \x01is currently dead.", destination);
            return Plugin_Stop;
        } 


[alasfourom]

can someone tell me why I have this error and how to fix it

PHP Code:

L 06/06/2022 - 12:07:58: [SM] Exception reported: Invalid client index -1
L 06/06/2022 - 12:07:58: [SM] Blaming: ghost_goto.smx
L 06/06/2022 - 12:07:58: [SM] Call stack trace:
L 06/06/2022 - 12:07:58: [SM]   [0] IsPlayerAlive
L 06/06/2022 - 12:07:58: [SM]   [1] Line 52, /home/groups/sourcemod/upload_tmp/phpG6TWU8.sp::Command_Goto 


[Marttt]

You should always check if is a valid client index (between 0~32 L4D2) and if the client is in-game (IsClientInGame) when not sure if it will return a client or while trying to access "client" props values.

Usually, I create a stock with that helpers:

PHP Code:

bool IsValidClient(int client)
{
    return (1 <= client && client <= MaxClients && IsClientInGame(client));
} 


According to the docs FindTarget

PHP Code:

Return Value
Index of target client, or -1 on error. 


So you should check if FindTarget returned -1, in this case ignore/exit the function.

Also you probably will get "Client not in game" error if you call sm_goto from the server console.