[Napoleon_be]

Update 1.4: Added a hitmarker sound which can be enabled/disabled with a cvar.

new .sma file uploaded and the sound has been attached to the first post aswell.

[HamletEagle]

For the people who wonder why i didn't make an extra cvar to change the hitmarker symbol, here's the reason. I tried it and tested it out, the problem is that when i use a pcvar for that, the symbol moves to the right and so the position isn't centered anymore.

This seems extremely unlikely/weird. Are you sure you didn't simply have some spaces in the string/cvar value?
Give it a try again and if you can't figure it out post the code here so we can take a look.

PHP Code:

new iRed, iGreen, iBlue; 


should be moved inside bShowHitMarker check because that's where you need the variables. If one of the 2 checks is false then they are not needed. Try to limit the scope to where the variable is really needed.

PHP Code:

set_task(0.110, "PlaySound", iAttacker + TASKID); 


Is your intent to slightly delay the sound? Because if you want it to be played at the same time you can simply do:

PHP Code:

PlaySound(iAttacker) 


I'm asking because the task time seems weird.

[Napoleon_be]

Okay,

1) I have tried it again using a pcvar and eventually it worked, i was probably doing something wrong before like you said.
2) Done
3) I've been testing the sound for over a 100 times and it appears that the gun shots or knife sounds are louder than the .wav file. I've used multiple sound files and tried them all out and i had the same problem with all of them. So then i began searching when was the right time to trigger the sound, and that's the reason i'm using such a weird value.

Thanks for the suggestions and the feedback.

First post and code got updated, new cvar is called amx_hmsymbol "x"

[HamletEagle]

About 3: whatever, not like it really matters and I don't want to drag this anymore.

I could not find a similar plugin, if anyone can link to an already existing plugin that has more features then I will reconsider, but for now, I'll approve this one.

[Napoleon_be]

Awesome thanks.

[georgik57]

Add the following check inside the post-damage hook to make sure the damage hasn't been blocked by another plug-in because the forward will still trigger anyway:

PHP Code:

GetHamReturnStatus() != HAM_SUPERCEDE 


[Napoleon_be]

Originally Posted by georgik57 Add the following check inside the post-damage hook to make sure the damage hasn't been blocked by another plug-in because the forward will still trigger anyway: PHP Code: GetHamReturnStatus() != HAM_SUPERCEDE

Will wait for an approver or a mod to see if this should be added, thanks for the suggestion.

[Napoleon_be]

Okay so a few questions:

1) Should the check that georgik57 gave me get added?
2) I've been suggested to change the hitmarker to be red when the victim is killed. Allthough, if i add this, a lot of cvars should be added too. (Honestly i think that would be too much for a simple plugin like this, but the modifications will be endless imo.)

Cvars that should get added when i do this:

• amx_hmdead "1" - Will set the red hitmarker enabled/disabled.
• amx_hmdeadrcolor "255" // Sets the red RGB code for the dead hitmarker.
• amx_hmdeadgcolor "0" // Sets the green RGB code for the dead hitmarker.
• amx_hmdeadbcolor "0" // Sets the blue RGB code for the dead hitmarker.

I would like some feedback on this before i add all this.

I have already prepared the code to get updated in case this is a good idea. Code can be found in spoiler

Spoiler

/* Plugin generated by AMXX-Studio */


/* Credits:
    - DJEarthQuake aka SPiNX: random symbol & rainbow color idea.
    - Bugsy: Thanks for showing me how to use bitsums, comes in very handy & optimizing my code alot.
    - HamletEagle: Thanks for helping me out with the snipers cvar.
    - WarrioR: For delivering me the hitmarker sound.
*/

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "COD: Hitmarkers Snipers"
#define VERSION "1.5"
#define AUTHOR "NapoleoN#"

#define iRainbow random_num(10, 255)
#define TASKID 85621

new pPlugin;
new pRainbow;
new pRandomHitmarkers;
new pSnipersOnly;
new pSounds;
new pSymbol;
new pDead;
new pColorRed;
new pColorGreen;
new pColorBlue;
new pDeadColorRed;
new pDeadColorGreen;
new pDeadColorBlue;
new pXPosition;
new pYPosition;
new pHoldTime;

new const szSymbols[][] = 
{
    "-",
    "\",
    "|",
    "/",
    "*",
    "+",
    "x"
};

new const szSound[] = "hitmarkers/hitmarkers.wav";

new gWeaponList = (1 << CSW_SCOUT) | (1 << CSW_AWP) | (1 << CSW_SG550) | (1 << CSW_G3SG1)

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    RegisterHam(Ham_TakeDamage, "player", "PostTakeDamage", 1);
    
    pPlugin =     register_cvar("amx_hitmarkers", "1"); // Enables/disables plugin
    pRainbow =   register_cvar("amx_hmrainbow", "1"); // Enables/disables random colors on every hit.
    pRandomHitmarkers =     register_cvar("amx_hmrandom", "1"); //Enables/disables random hit markers.
    pSnipersOnly =    register_cvar("amx_hmsnipers", "1"); // Enables/disables hitmarkers on snipers only.
    pSounds =     register_cvar("amx_hmsounds", "1"); // Enables/disables hitmarker sound on hit.
    pSymbol =     register_cvar("amx_hmsymbol", "x"); // Sets the symbol of the hitmarker (only works when amx_hmrandom "0")
    pDead =   register_cvar("amx_hmdead", "1"); // Will show a RED hitmarker if victim is killed by the shot.
    pColorRed =  register_cvar("amx_hmrcolor", "165"); // RGB - Red (This won't work when amx_hmrainbow = 1)
    pColorGreen =      register_cvar("amx_hmgcolor", "165"); // RGB - Green (This won't work when amx_hmrainbow = 1)
    pColorBlue =        register_cvar("amx_hmbcolor", "165"); // RGB - Blue (This won't work when amx_hmrainbow = 1)
    pDeadColorRed =  register_cvar("amx_hmdeadrcolor", "255"); // Sets the red RGB code for the dead hitmarker
    pDeadColorGreen =   register_cvar("amx_hmdeadgcolor", "0"); // Sets the green RGB code for the dead hitmarker
    pDeadColorBlue =    register_cvar("amx_hmdeadbcolor", "0"); // Sets the blue RGB code for the dead hitmarker
    pXPosition =       register_cvar("amx_hmxpos", "-1.0"); // x pos
    pYPosition =       register_cvar("amx_hmypos", "-1.0"); // y pos
    pHoldTime =         register_cvar("amx_hmholdtime", "0.5"); // hud hold time
}

public plugin_precache()
{
    precache_sound(szSound);
}

public client_disconnect(id) 
{
    if(task_exists(id + TASKID))
    {
        remove_task(id + TASKID)
    }
}

public PostTakeDamage(iVictim, iInflictor, iAttacker, Float:iDamage, iDamagebits)
{
    if(get_pcvar_num(pPlugin) && is_user_connected(iAttacker) && (get_user_team(iVictim) != get_user_team(iAttacker)))
    {
        new bool:bShowHitMarker;
        
        if(get_pcvar_num(pSnipersOnly))
        {
            if(gWeaponList & (1 << get_user_weapon(iAttacker)))
            {
                bShowHitMarker = true;
            }
        }
        
        else 
        {
            bShowHitMarker = true;
        }
        
        if(bShowHitMarker)
        {
            new iRed, iGreen, iBlue, szSymbol[2];
            get_pcvar_string(pSymbol, szSymbol, charsmax(szSymbol));
            
            if(is_user_alive(iVictim))
            {
                if(get_pcvar_num(pRainbow))
                {
                    iRed = iRainbow;
                    iGreen = iRainbow;
                    iBlue = iRainbow;
                }
                else
                {
                    iRed = get_pcvar_num(pColorRed);
                    iGreen = get_pcvar_num(pColorGreen);
                    iBlue = get_pcvar_num(pColorBlue);
                }
        
                set_hudmessage(iRed, iGreen, iBlue, get_pcvar_float(pXPosition), get_pcvar_float(pYPosition) , 0, 2.0, get_pcvar_float(pHoldTime) , 0.0, 0.0, -1);
            }
            else if(!is_user_alive(iVictim) && get_pcvar_num(pDead))
            {
                iRed = get_pcvar_num(pDeadColorRed);
                iGreen = get_pcvar_num(pDeadColorGreen);
                iBlue = get_pcvar_num(pDeadColorBlue);
                
                set_hudmessage(iRed, iGreen, iBlue, get_pcvar_float(pXPosition), get_pcvar_float(pYPosition) , 0, 2.0, get_pcvar_float(pHoldTime) , 0.0, 0.0, -1);
            }
            
            if(get_pcvar_num(pSounds))
            {
                set_task(0.110, "PlaySound", iAttacker + TASKID);
            }
            show_hudmessage(iAttacker, "%s" , get_pcvar_num(pRandomHitmarkers) ? szSymbols[random(sizeof(szSymbols))] : szSymbol);
        }
    }
}

public PlaySound(iAttacker)
{
    iAttacker -= TASKID
    client_cmd(iAttacker, "spk %s", szSound);
} 

Thanks in advance.

[georgik57]

Get rid of some cvars by doing the following:

Use amx_hitmarkers as a universal cvar for random, 1 symbol only or to disable the plug-in by using it as a string with the following logic:
amx_hitmarkers set as "-\|/*+x" will choose a random character between those by printing szCVarHitMarkers[random_num(0, strlen(szCVarHitmarkers) - 1)]
amx_hitmarkers set as "" will disable the plug-in.
This way, you've just eliminated the need for amx_hmrandom and amx_hmsymbol and you've added customizability through cvar for the symbols that should be displayed, getting rid of the hardcoded ones.

Use amx_hmsnipers as a cvar for listing the weapons that should be (dis)considered instead of just an integer. Use letters along with read_flags for better readability.
Example: the cvar containing letters "cmsy" will (dis)consider CSW_SCOUT, CSW_SG550, CSW_AWP, CSW_G3SG1 since "c" is the 3rd letter in the alphabet and CSW_SCOUT has ID 3, etc.

PHP Code:

new szHmWeapons[32];
get_pcvar_string(pSnipersOnly, szHmWeapons, charsmax(szHmWeapons))

if (read_flags(szHmWeapons) & (1 << get_user_weapon(iAttacker)))
{
...
} 


Side note: get_user_weapon only returns the weapon the player is currently holding, not the weapon he's done the damage with. So he can do damage with a thrown grenade while holding and AWP and the condition will return true.

Use color cvars do define whether or not to use random colors instead of having a separate cvar for it and it will add the ability to also choose which of the colors to get randomized. Use the following example:

PHP Code:

    set_dhudmessage
    (
        (iCVarRed >= 0) ? iCVarRed : random_num(-iCVarRed - 1, 255),
        (iCVarGreen >= 0) ? iCVarGreen : random_num(-iCVarGreen - 1, 255),
        (iCVarBlue >= 0) ? iCVarBlue : random_num(-iCVarBlue - 1, 255),
        -1.0, 0.0, 0, 0.0, fCVarInterval + ((fCVarInterval >= 0.2) ? 0.1 : 0.05), 0.0, 0.0, false
    ) 


As for my previous suggestion, try it out yourself. Make a separate plug-in which will block the damage in Ham_TakeDamage Pre and you will see.

PS: You should also cache the string cvars in this case(either per round or once every X seconds), as TakeDamage can be spammed very much.

[Napoleon_be]

1) I will consider using amx_hitmarkers as the universal cvar for this plugin. Seems fair enough to me.
2) Can u explain again what you're trying to do with read_flags() right there? I don't really get it
3) I don't really mind a HE grenade showing a hitmarker as it is also damage done to the victim
4) Won't be using that style, people consider using 255 0 0 to get the red color, the way you're doing it it will always choose a random number if one of the cvars is 0, which is not what we want.
5) I'll take you on your word about the HAM check and add it later on.