[shanapu]

hi, I'm still in learn progress...

I dont want a master plugin and subplugins. I want several plugins with equal rights and without dependencies.
it this way a "clean" solution?
can i write a include like this?
can i add CreateNative/APLRes:AskPluginLoad2 in the include without getting headache?

inc.

PHP Code:

#if defined _mytestinc_included_
  #endinput
#endif
#define _mytestinc_included_

char IsTest[128] = "none";

public APLRes:AskPluginLoad2(Handle:myself, bool:late, String:error[], err_max)
{

    CreateNative("SetTest", Native_SetTest);
    CreateNative("GetTest", Native_GetTest);
}


native SetTest(const String:name[]);

public Native_SetTest(Handle:plugin, argc)
{
    decl String:buffer[64];
    GetNativeString(1, buffer, 64);
    
    Format(IsTest, sizeof(IsTest), buffer);
    
}


native GetTest(String:CurrentString[]);

public Native_GetTest(Handle:plugin, argc)
{
    SetNativeString(1, IsTest, sizeof(IsTest));
} 


PHP Code:

#include <sourcemod>
#include <mytestinc>

public OnPluginStart()
{
    
    RegConsoleCmd("sm_test1", TestOn);
}

public Action:TestOn(client, args)
{
    decl String:buffer[64];
    GetTest(buffer);
    PrintToChatAll("Old string: %s" ,buffer);
    
    PrintToChatAll("Set new string: Test1");
    SetTest("Test1");
} 


PHP Code:

#include <sourcemod>
#include <mytestinc>

public OnPluginStart()
{
    
    RegConsoleCmd("sm_test2", TestOn);
}

public Action:TestOn(client, args)
{
    decl String:buffer[64];
    GetTest(buffer);
    PrintToChatAll("Old string: %s" ,buffer);
    
    PrintToChatAll("Set new string: Test2");
    SetTest("Test2");
} 


and so on...

thanks for reading!

[WildCard65]

Unfortunately, you'll run into the problem of unable to bind the fake natives as internally in SM, only unique native names can be bound so multiple plugins trying to bind natives to the same name will run into 1 getting it first, others going into a failed state.

[Phil25]

Originally Posted by shanapu I dont want a master plugin and subplugins.

In a majority of cases, if you want to have numerous of plugins working together, having a master plugin is the most convenient and efficient way.

Here's a quick code on how to set up a basic native:

testplugin.inc

PHP Code:

#if defined _testplugin_included
  #endinput
#endif
#define _testplugin_included

public SharedPlugin:__pl_testplugin = {
    name = "My Plugin's Name",
    file = "testplugin.smx",
#if defined REQUIRE_PLUGIN
    required = 1,
#else
    required = 0,
#endif
};

#if !defined REQUIRE_PLUGIN
public __pl_testplugin_SetNTVOptional(){

    MarkNativeAsOptional("MyPlugin_TestNative");

}
#endif

//The above should be a standard when setting up an .inc file. Simply replace each "testplugin" with your (master) plugin's file name.

/**
 * This is this native's description used by various text editors to display info about it.
 *
 * @param client        Client Index.
 * @param iSomeValue This is some value.
 *
 * @return            Returns iSomeValue.
 */
native MyPlugin_TestNative(client, iSomeValue); 


testplugin.sp

PHP Code:

include <testplugin>

public APLRes AskPluginLoad2(Handle hMyself, bool bLate, char[] sError, int iErrorSize){

    CreateNative("MyPlugin_TestNative", Native_TestNative);

    return APLRes_Success;

}

public int Native_TestNative(Handle hPlugin, int iParams){

    int client = GetNativeCell(1);
    int iSomeValue = GetNativeCell(2);

    PrintToChatClient(client, "Isn't this number cool? %d", iSomeValue);

    return iSomeValue;

} 


[shanapu]

thanks for the replys!

ok, i accept it, need a master/core/api plugin.
I tinkered just before phil25 answered this version.

inc.

Spoiler

PHP Code:

#if defined _mytestinc_included_
  #endinput
#endif
#define _mytestinc_included_

/** 
 * some info about it. 
 *
 */
native SetEventDay(const String:name[]);

/** 
 * some info about it. 
 *
 */
native GetEventDay(String:CurrentEventDay[]); 


master

Spoiler

PHP Code:

char IsTest[128] = "none"; 

public APLRes:AskPluginLoad2(Handle:myself, bool:late, String:error[], err_max) 
{ 

    CreateNative("SetTest", Native_SetTest); 
    CreateNative("GetTest", Native_GetTest); 
} 

public Native_SetTest(Handle:plugin, argc) 
{ 
    decl String:buffer[64]; 
    GetNativeString(1, buffer, 64); 
     
    Format(IsTest, sizeof(IsTest), buffer); 
     
} 

public Native_GetTest(Handle:plugin, argc) 
{ 
    SetNativeString(1, IsTest, sizeof(IsTest)); 
} 


sub

Spoiler

PHP Code:

#include <sourcemod>
#include <mytestinc>

public OnPluginStart()
{
    
    RegConsoleCmd("sm_test2", TestOn);
}

public Action:TestOn(client, args)
{
    decl String:buffer[64];
    GetTest(buffer);
    PrintToChatAll("Old string: %s" ,buffer);
    
    PrintToChatAll("Set new string: Test2");
    SetTest("Test2");
} 


and i will implement this!

Spoiler

PHP Code:

public SharedPlugin:__pl_testplugin = { 
    name = "My Plugin's Name", 
    file = "testplugin.smx", 
#if defined REQUIRE_PLUGIN 
    required = 1, 
#else 
    required = 0, 
#endif 
}; 

#if !defined REQUIRE_PLUGIN 
public __pl_testplugin_SetNTVOptional(){ 

    MarkNativeAsOptional("MyPlugin_TestNative"); 

} 
#endif 


[Kailo]

name = "My Plugin's Name",

This is not exactly right. More info in: Optional_Requirements_(SourceMod_Scripting)#C reating_a_Dependency

[Neuro Toxin]

Dynamic could be usefull here.

To create shared plugin settings you could.

Dynamic settings = new Dynamic();
settings.SetName("Plugin_Name");

Any plugin then can access this object by:

Dynamic settings = Dynamic.FindByName("Plugin_Name");

This is an example of how you can set members / settings in the dynamic object taken from the example plugin.

	// Creating dynamic objects is straight foward
	Dynamic someobj = Dynamic();

	// Setting integers, floats and booleans also
	someobj.SetInt("someint", 1);
	someobj.SetFloat("somefloat", 512.7);
	someobj.SetBool("somebool", true);

	// When dealing with strings...
	// you want to set an appropriate length if the value will change
	someobj.SetString("somestring", "What did you say?", 64);

	// If the value of a string will never change you might as well
	someobj.SetString("our_planets_name", "Earth");

	// Getting integers, floats and booleans is also straight foward
	int someint = someobj.GetInt("someint");
	float somefloat = someobj.GetFloat("somefloat");
	bool somebool = someobj.GetBool("somebool");

	// You can also include default values in case a member doesn't exist
	someint = someobj.GetInt("someint1", -1);
	somefloat = someobj.GetFloat("somefloat2", 7.25);
	somebool = someobj.GetBool("somebool2", false);

	// And the normal "extra" stuff to get a string in sourcespawn
	char somestring[64];
	someobj.GetString("somestring", somestring, sizeof(somestring));

	// You can also get an exact string by size
	int length = someobj.GetStringLength("our_planets_name");
	char[] our_planets_name = new char[length];
	someobj.GetString("our_planets_name", our_planets_name, length);

	// Dynamic supports type conversion!!!!!!!!!!!
	someint = someobj.GetInt("somefloat"); // rounds to floor
	somefloat = someobj.GetFloat("someint");
	someobj.GetString("somefloat", somestring, sizeof(somestring));
	someobj.GetString("somebool", somestring, sizeof(somestring));

	// You can even set dynamic objects within themselves
	Dynamic anotherobj = Dynamic();
	anotherobj.SetInt("someint", 128);
	someobj.SetObject("anotherobj", anotherobj);

	// You can also get and set Handles
	someobj.SetHandle("somehandle", CreateArray());
	Handle somehandle = someobj.GetHandle("somehandle");
	PushArrayCell(somehandle, 1);

	// Vectors are also supported like so
	float somevec[3] = {1.0, 2.0, 3.0};
	someobj.SetVector("somevec", somevec);
	someobj.GetVector("somevec", somevec);