[kww]

After changing knife model. we need to manually redeploy knife to see changes. Is there any way to do this automatically?

PHP Code:

public Ham_Knife_Deploy_Post(iEnt)
{
    static id; id = get_pdata_cbase(iEnt, m_pPlayer, 4)
    
    if(!g_bot[id] && g_connected[id] || g_bot[id] && g_botsWithRandomKnives)
    {
        refreshKnifeModel(id)
    }
    
    return HAM_IGNORED
}

refreshKnifeModel(id)
{
    static index; index = g_selectedKnife[id]
    
    set_pev(id, pev_viewmodel2, g_models[index][v_model])
    set_pev(id, pev_weaponmodel2, g_models[index][p_model])
}

// knife choose from menu:

public ck_menu(id)
{
    new menu, szLine[MAX_RESOURCE_PATH_LENGTH]
    formatex(szLine, charsmax(szLine), "\yChoose knife:")
    menu = menu_create(szLine, "ck_menu_handler")
    
    for(new i; i < sizeof(g_models); i++)
    {
        formatex(szLine, charsmax(szLine), "%s", g_models[i][name])
        menu_additem(menu, szLine)
    }
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL)
    
    menu_display(id, menu)
    return PLUGIN_HANDLED
}

public ck_menu_handler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    
    g_selectedKnife[id] = item
    
    client_print(id, print_chat, "* Chosen ^"%s^" knife", g_models[item][name])
    client_print(id, print_chat, "* Redeploy knife to see changes")
    
    ck_menu(id)
    return PLUGIN_HANDLED
} 


[iceeedr]

Originally Posted by kww After changing knife model. we need to manually redeploy knife to see changes. Is there any way to do this automatically?

If I understood the request correctly, I believe this works, I haven't had a chance to test it.

public ck_menu_handler(id, menu, item)
{
        if(item == MENU_EXIT)
        {
                menu_destroy(menu)
                return PLUGIN_HANDLED
        }
        
        g_selectedKnife[id] = item
        
        client_print(id, print_chat, "* Chosen ^"%s^" knife", g_models[item][name])
        client_print(id, print_chat, "* Redeploy knife to see changes")
        
        if (get_user_weapon(id) == CSW_KNIFE)
                refreshKnifeModel(id)

        ck_menu(id)
        return PLUGIN_HANDLED
}

[kww]

Originally Posted by iceeedr If I understood the request correctly, I believe this works, I haven't had a chance to test it. public ck_menu_handler(id, menu, item) { if(item == MENU_EXIT) { menu_destroy(menu) return PLUGIN_HANDLED } g_selectedKnife[id] = item client_print(id, print_chat, "* Chosen ^"%s^" knife", g_models[item][name]) client_print(id, print_chat, "* Redeploy knife to see changes") if (get_user_weapon(id) == CSW_KNIFE) refreshKnifeModel(id) ck_menu(id) return PLUGIN_HANDLED }

It is. Thank you
P.s. I was so stupid to notice that