[mrshark45]

Hello, I wrote a simple credits plugin and sometimes , I don't know when, player's credits reset.
It doesn't show any error in the logs, I logged everytime the plugins load someone's credits from db and what it saves and sometimes it just saves 2 credits like when a player's kills someone its credits increment by 2 and then saves it, so if someone have 24 credits and kills another player the credits reset and it saves 2. I don't know when it happends. It doesn't happen to all players and not all the time.
Loading code:

PHP Code:

public void OnClientPostAdminCheck(client)
{
    if(IsFakeClient(client))
        return;

    LoadClientCredits(client);
}

public void LoadClientCredits(int client)
{
    if(!IsClientConnected(client))
        return;
    char query[256], steamid[32];
    GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
    FormatEx(query, sizeof(query), "SELECT * FROM store_players WHERE authid = '%s'", steamid);
    LogToFile(logPath, query);
    db.Query(T_LoadData, query, GetClientUserId(client));
}

public void T_LoadData(Database db1, DBResultSet results, const char[] error, any data)
{
    if(db1 == null || results == null)
    {
        LogError("T_LoadData returned error: %s", error);
        return;
    }

    int client = GetClientOfUserId(data); 

    if(!client || IsFakeClient(client) || !IsClientConnected(client))
        return;

    int creditsCol;
    results.FieldNameToNum("credits", creditsCol);


    if(results.FetchRow())
    {
        player_credits[client] = results.FetchInt(creditsCol);
        LogToFile(logPath, "%i", player_credits[client]);
    }
    else
    {
        //not found in db, insert data:
        char steamid[32], name[64], name_sanitazed[64]; GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid)); GetClientName(client, name, sizeof(name));
        db.Escape(name, name_sanitazed, sizeof(name_sanitazed));
        char query[256]; Format(query, sizeof(query), "INSERT INTO store_players (authid, name, credits) VALUES ('%s', '%s', 0);", steamid, name_sanitazed );
        LogToFile(logPath, "NOT IN DATABASE");
        db1.Query(T_Generic, query);
    }
}
public void T_Generic(Database db1, DBResultSet results, const char[] error, any data)
{
    if(db1 == null || results == null)
    {
        LogError("T_Generic returned error: %s", error);
        return;
    }
} 


Saving code:

PHP Code:

public Action Event_PlayerDeath(Event event, const char[] chName, bool bDontBroadcast)
{
    int credits = c_kill.IntValue;
    int attacker = GetClientOfUserId(GetEventInt(event, "attacker"));
    int victim = GetClientOfUserId(GetEventInt(event, "userid"));
    if(!attacker || !victim || IsFakeClient(victim) || IsFakeClient(attacker) || !IsClientConnected(attacker))
        return;

    kills[attacker]++;
    bool headshot = GetEventBool(event, "headshot");
    bool noscope = GetEventBool(event, "noscope");
    bool smoke = GetEventBool(event, "thrusmoke");
    int wallbang = GetEventInt(event, "noscope");
    bool blind = GetEventBool(event, "attackerblind");
    if(headshot)
        credits += c_headshot.IntValue;
    if(noscope)
        credits += c_noscope.IntValue;
    if(smoke)
        credits += c_smoke.IntValue;
    if(wallbang)
        credits += c_wall.IntValue;
    if(blind)
        credits += c_blind.IntValue;
    if(c_multikill.IntValue)
        credits += c_multikill.IntValue * kills[attacker];
    
    player_credits[attacker] += credits;
    

    UpdateCredits(attacker);

    return;
}
public void UpdateCredits(int client)
{
    char steamid[32]; GetClientAuthId(client, AuthId_Steam2, steamid, sizeof(steamid));
    LogToFile(logPath, "%s - %i SAVED", steamid, player_credits[client]);

    char query[256]; Format(query, sizeof(query), "UPDATE store_players SET credits = '%i' WHERE authid = '%s';", player_credits[client], steamid);
    db.Query(T_Generic, query);
} 


I also reset a player's credits when he disconnects

PHP Code:

public void OnClientDisconnect(int client)
{
    player_credits[client] = 0;
} 


[Rohanlogs]

Hey.
Some things I would change here.
Reset player_credits also on disconnect, create a global variable for clients steamid as you should fetch it only once since its used often.
You don't have to fetch it again everytime.
Try this as your load code:

Spoiler

PHP Code:

bool g_bLoaded[MAXPLAYERS + 1]; //Add this at the beginning
char g_sSteamID[MAXPLAYERS + 1][33]; //Add this at the beginning


public void OnClientDisconnect(int iClient)
{
    g_bLoaded[iClient] = false;
    g_sSteamID[iClient] = "";
    player_credits[iClient] = 0;
} 


public void OnClientPutInServer(int iClient)
{
    g_bLoaded[iClient] = false;
    g_sSteamID[iClient] = "";
    player_credits[iClient] = 0;
}


public void OnClientPostAdminCheck(iClient)
{
    LoadClientCredits(iClient);
}


public void LoadClientCredits(int iClient)
{
    if( !IsValidClient(iClient) ) return;
    
    GetClientAuthId( iClient, AuthId_Steam2, g_sSteamID[iClient], sizeof( g_sSteamID[] ) );

    if( StrContains( g_sSteamID[iClient], "STEAM_", true ) == -1 )
        CreateTimer( 10.0, fw_Refresh, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE );
        
    //Let's give it some time...
    if(db == null || db == INVALID_HANDLE)
        CreateTimer( 1.0, fw_WaitForDatabase, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE );
        
    else if( !IsFakeClient(iClient) )
    {
        char query[256];
        FormatEx( query, sizeof(query), "SELECT * FROM store_players WHERE authid = '%s'", g_sSteamID[iClient] );
        db.Query( T_LoadData, query, GetClientUserId(iClient), DBPrio_High );
        g_bLoaded[iClient] = true;
    } 
}


public Action fw_WaitForDatabase(Handle hTimer, int iUserID)
{
    int iClient = GetClientOfUserId(iUserID);
    if ( !IsValidClient(iClient) ) return;
        
    LoadClientCredits(iClient);
}


public Action fw_Refresh(Handle hTimer, int iUserID)
{
    int iClient = GetClientOfUserId(iUserID);
    
    if( !IsValidClient(iClient) ) return;

    GetClientAuthId( iClient, AuthId_Steam2, g_sSteamID[iClient], sizeof( g_sSteamID[] ) );
    
    if( StrContains( g_sSteamID[iClient], "STEAM_", true ) == -1 ) 
        CreateTimer(10.0, fw_Refresh, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE);
    
    else LoadClientCredits(iClient);
}


bool IsValidClient(int iClient) 
{ 
    if(iClient <= 0) 
        return false; 
    
    if(iClient > MaxClients) 
        return false; 
    
    if( !IsClientConnected(iClient) ) 
        return false; 
    
    return IsClientInGame(iClient); 
} 


Some of this code is based on headline's 'gangs' plugin IIRC which has been working well for me.
Remove the local string 'steamid' from everywhere and use the global variable g_sSteamID instead.

You could also replace all these:

PHP Code:

if(!client || IsFakeClient(client) || !IsClientConnected(client)) return; 


To this stock which I added in the code:

PHP Code:

if( !IsValidClient(client) || IsFakeClient(client) ) return; 


You can also use extra parameter 'DBPrio_High' in your query but its not necessary.

In Event_PlayerDeath, check if players stats are loaded before doing anything.
I added this boolean in the code above.
If they aren't loaded, return:

Spoiler

PHP Code:

public Action Event_PlayerDeath(Event event, const char[] chName, bool bDontBroadcast)
{
    int credits = c_kill.IntValue;
    int attacker = GetClientOfUserId(GetEventInt(event, "attacker"));
    int victim = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if( !IsValidClient(attacker) || !IsValidClient(victim)
    || IsFakeClient(attacker) || IsFakeClient(victim) ) return;
    
    if( !g_bLoaded[attacker] )
    {
        PrintToChat(attacker, "[SM] Your stats are still being loaded!");
        return;
    }

    //..... rest of the code 


But if you don't have to query on every single kill, perhaps you should just update the score once to the database during disconnect:

Spoiler

PHP Code:

public void OnClientDisconnect(int iClient)
{
    if( g_bLoaded[iClient] ) UpdateCredits(iClient);
    
    g_bLoaded[iClient] = false;
    g_sSteamID[iClient] = "";
    player_credits[iClient] = 0;
}


public void UpdateCredits(int client)
{
    //LogToFile( logPath, "%s - %i SAVED", g_sSteamID[client], player_credits[client] );

    char query[256]; 
    Format( query, sizeof(query), "UPDATE store_players SET credits = '%i' WHERE authid = '%s';", player_credits[client], g_sSteamID[client] );
    db.Query(T_Generic, query);
} 


[mrshark45]

Originally Posted by Rohanlogs Hey. Some things I would change here. Reset player_credits also on disconnect, create a global variable for clients steamid as you should fetch it only once since its used often. You don't have to fetch it again everytime. Try this as your load code: Spoiler PHP Code: bool g_bLoaded[MAXPLAYERS + 1]; //Add this at the beginning char g_sSteamID[MAXPLAYERS + 1][33]; //Add this at the beginning public void OnClientDisconnect(int iClient) {     g_bLoaded[iClient] = false;     g_sSteamID[iClient] = "";     player_credits[iClient] = 0; }  public void OnClientPutInServer(int iClient) {     g_bLoaded[iClient] = false;     g_sSteamID[iClient] = "";     player_credits[iClient] = 0; } public void OnClientPostAdminCheck(iClient) {     LoadClientCredits(iClient); } public void LoadClientCredits(int iClient) {     if( !IsValidClient(iClient) ) return;          GetClientAuthId( iClient, AuthId_Steam2, g_sSteamID[iClient], sizeof( g_sSteamID[] ) );     if( StrContains( g_sSteamID[iClient], "STEAM_", true ) == -1 )         CreateTimer( 10.0, fw_Refresh, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE );              //Let's give it some time...     if(db == null || db == INVALID_HANDLE)         CreateTimer( 1.0, fw_WaitForDatabase, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE );              else if( !IsFakeClient(iClient) )     {         char query[256];         FormatEx( query, sizeof(query), "SELECT * FROM store_players WHERE authid = '%s'", g_sSteamID[iClient] );         db.Query( T_LoadData, query, GetClientUserId(iClient), DBPrio_High );         g_bLoaded[iClient] = true;     }  } public Action fw_WaitForDatabase(Handle hTimer, int iUserID) {     int iClient = GetClientOfUserId(iUserID);     if ( !IsValidClient(iClient) ) return;              LoadClientCredits(iClient); } public Action fw_Refresh(Handle hTimer, int iUserID) {     int iClient = GetClientOfUserId(iUserID);          if( !IsValidClient(iClient) ) return;     GetClientAuthId( iClient, AuthId_Steam2, g_sSteamID[iClient], sizeof( g_sSteamID[] ) );          if( StrContains( g_sSteamID[iClient], "STEAM_", true ) == -1 )          CreateTimer(10.0, fw_Refresh, GetClientUserId(iClient), TIMER_FLAG_NO_MAPCHANGE);          else LoadClientCredits(iClient); } bool IsValidClient(int iClient)  {      if(iClient <= 0)          return false;           if(iClient > MaxClients)          return false;           if( !IsClientConnected(iClient) )          return false;           return IsClientInGame(iClient);  }  Some of this code is based on headline's 'gangs' plugin IIRC which has been working well for me. Remove the local string 'steamid' from everywhere and use the global variable g_sSteamID instead. You could also replace all these: PHP Code: if(!client || IsFakeClient(client) || !IsClientConnected(client)) return;  To this stock which I added in the code: PHP Code: if( !IsValidClient(client) || IsFakeClient(client) ) return;  You can also use extra parameter 'DBPrio_High' in your query but its not necessary. In Event_PlayerDeath, check if players stats are loaded before doing anything. I added this boolean in the code above. If they aren't loaded, return: Spoiler PHP Code: public Action Event_PlayerDeath(Event event, const char[] chName, bool bDontBroadcast) {     int credits = c_kill.IntValue;     int attacker = GetClientOfUserId(GetEventInt(event, "attacker"));     int victim = GetClientOfUserId(GetEventInt(event, "userid"));          if( !IsValidClient(attacker) || !IsValidClient(victim)     || IsFakeClient(attacker) || IsFakeClient(victim) ) return;          if( !g_bLoaded[attacker] )     {         PrintToChat(attacker, "[SM] Your stats are still being loaded!");         return;     }     //..... rest of the code  But if you don't have to query on every single kill, perhaps you should just update the score once to the database during disconnect: Spoiler PHP Code: public void OnClientDisconnect(int iClient) {     if( g_bLoaded[iClient] ) UpdateCredits(iClient);          g_bLoaded[iClient] = false;     g_sSteamID[iClient] = "";     player_credits[iClient] = 0; } public void UpdateCredits(int client) {     //LogToFile( logPath, "%s - %i SAVED", g_sSteamID[client], player_credits[client] );     char query[256];      Format( query, sizeof(query), "UPDATE store_players SET credits = '%i' WHERE authid = '%s';", player_credits[client], g_sSteamID[client] );     db.Query(T_Generic, query); }

Thanks, I did the changes yesterday and it doesn't seem to reset anymore, maybe some players connected before the db connection was made.

[eyal282]

Consider FormatQuery and incremental syntax

SQL_FormatQuery(db, query, sizeof(query), "UPDATE store_players SET credits = credits + '%i' WHERE authid = '%s';", credits, steamid);