[supertimor]

Hi!
Can someone write simple code, to teleport myself to place where i'am aiming? Not max lenght, but for example for 300 unites, with collision point (if there's a wall -10 units or something) or if player will be stuck after teleport - teleport back
help me guys pls

[alex123pavlov]

2$

[supertimor]

go on, put here .smx on command and i need test if it works

[alex123pavlov]

full afterwards (write alex123)

[LenHard]

PHP Code:

#include <sourcemod>
#include <sdktools>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    RegConsoleCmd("sm_tp", Cmd_Teleport, "Teleports you at where you aim");    
}

public Action Cmd_Teleport(int client, int args)
{
    if (0 < client <= MaxClients && IsClientInGame(client) && IsPlayerAlive(client))
    {
        float fPos[3], fBackwards[3];
        float fOrigin[3]; GetClientEyePosition(client, fOrigin); 
        float fAngles[3]; GetClientEyeAngles(client, fAngles);
        
        Handle trace = TR_TraceRayFilterEx(fOrigin, fAngles, MASK_PLAYERSOLID, RayType_Infinite, TraceRayDontHitPlayers, client);
        
        bool failed;
        
        int loopLimit = 100;
        
        GetAngleVectors(fAngles, fBackwards, NULL_VECTOR, NULL_VECTOR);
        NormalizeVector(fBackwards, fBackwards);
        ScaleVector(fBackwards, 10.0); 
        
        if (TR_DidHit(trace))
        {
            TR_GetEndPosition(fPos, trace);
            
            while (IsPlayerStuck(fPos, client) && !failed)
            {
                SubtractVectors(fPos, fBackwards, fPos); 
                
                if (GetVectorDistance(fPos, fOrigin) < 10 || loopLimit-- < 1)
                {
                    failed = true;
                    fPos = fOrigin;   
                }
            }
        }
        delete trace;
        
        TeleportEntity(client, fPos, NULL_VECTOR, NULL_VECTOR);
        PrintCenterText(client, "You have teleported!");
    }
    return Plugin_Handled;
}

bool IsPlayerStuck(float pos[3], int client)
{
    float mins[3]; GetClientMins(client, mins);
    float maxs[3]; GetClientMaxs(client, maxs);
    
    for (int i = 0; i < 3; ++i)
    {
        mins[i] -= 3;
        maxs[i] += 3;
    }

    TR_TraceHullFilter(pos, pos, mins, maxs, MASK_SOLID, TraceRayDontHitPlayers, client);
    return TR_DidHit();
}  

public bool TraceRayDontHitPlayers(int iEntity, int iMask, any iData)
{
    if (0 < iEntity <= MaxClients)
        return false;
    return true;
} 


Try this

[Zyten]

i am using this https://forums.alliedmods.net/showthread.php?p=2323724 for example u want to tp yourself /bring super . you will be tp to your crosshair

[zwetch]

Lol this plugin is crazy fun, thanks for the share! (would be better if there was a option to set the amount of time between teleports tho) So player cant just abuse the shit outa it lol.

[RedSword]

Originally Posted by alex123pavlov full afterwards (write alex123)

Removed attachment as no source is provided.

[supertimor]

Love u, LenHard. I've got nothing more to say <3

[jillchang917]

Originally Posted by alex123pavlov 2$

... what's the point of charging $2? plugin exists anyways.

Here is the one I use that gives some extra functionality that I feel is necessary. Thanks to htcarnage for making it.
https://forums.alliedmods.net/showthread.php?p=2004356
Hope that helps.


oh nvm, it doesn't teleport where you aim. I'll leave this anyways just incase.