[Skippy]

So what I'm trying to do is get the command to show the image on the screen of the client.

Here is the sp

#pragma semicolon 1
#include <sdktools>
#include <sourcemod>

public Plugin:myinfo =
{
	name = "Rules Image",
	author = "Skipper",
	description = "Rules Agreement Image",
};

#define RulesVTF	"custom/rules.vtf"
#define RulesVMT	"custom/rules.vmt"

public OnPluginStart()
{
	RegAdminCmd("sm_rule", Command_Rule, ADMFLAG_BAN, "sm_rule <name>");
}

public OnMapStart()
{
	PrecacheGeneric(RulesVTF, true);
	AddFileToDownloadsTable("materials/custom/rules.vtf");
	
	PrecacheGeneric(RulesVMT, true);
	AddFileToDownloadsTable("materials/custom/rules.vmt");
}	

public Action:Command_Rule(client, args)
{
	if ( args < 1 )
	{
		ReplyToCommand(client, "[SM] Usage: sm_rule <client>");
		return Plugin_Handled;
	}

	decl String:player[64];
	GetCmdArg(1, player, sizeof(player));

	new String:target_name[MAX_TARGET_LENGTH];
	new target_list[MAXPLAYERS], target_count;
	new bool:tn_is_ml;
 
	if ( (target_count = ProcessTargetString(
			player,
			client,
			target_list,
			MAXPLAYERS,
			COMMAND_FILTER_CONNECTED|COMMAND_FILTER_NO_BOTS,
			target_name,
			sizeof(target_name),
			tn_is_ml)) <= 0 )
	{
		ReplyToCommand(client, "[SM] No matching client");
		return Plugin_Handled;
	}

	for ( new i=0; i<target_count; i++ )
	{
		Rules(client, target_list[i]);
	}

	return Plugin_Handled;
}

stock Rules(client, target)
{
	new Handle:cvarCheats;
	cvarCheats = FindConVar("sv_cheats");

	if ( target > 0 && target <= MaxClients )
	{
		if ( IsClientConnected(target) && IsClientInGame(target) )
		{
			SendConVarValue(target, cvarCheats, "1");
			ClientCommand(target, "r_screenoverlay custom/rules");
			SendConVarValue(target, cvarCheats, "0");

			CreateTimer(5.0, Timer_Rules, target, TIMER_FLAG_NO_MAPCHANGE);
		}
	}
}

public Action:Timer_Rules(Handle:timer, any:client)
{
	new Handle:cvarCheats;
	cvarCheats = FindConVar("sv_cheats");

	if ( IsClientConnected(client) && IsClientInGame(client) )
	{
		SendConVarValue(client, cvarCheats, "1");
		ClientCommand(client, "r_screenoverlay off");
		SendConVarValue(client, cvarCheats, "0");
	}
}

This is the vmt code. (The VTF is 2048 x 2048 )

"LightmappedGeneric"
{
	"$basetexture" "custom/rules"
}

So the problem is that the image isn't coming up on the screen. It downloads fine and there aren't any errors within console or error log. I was wondering if anyone knew how to fix this?

[TnTSCS]

did you look at the code of this plugin to compare how it's done vs how you're doing it?

[Skippy]

Originally Posted by TnTSCS did you look at the code of this plugin to compare how it's done vs how you're doing it?

Only difference from that and mine is that they used PrecacheDecal and I tried using PrecacheDecal and it just either came up as an error in console or it crashed my tf2.

[TnTSCS]

that and you're changing sv_cheats? Also, maybe validate !IsFakeClient(target)

I've never messed with overlays, so I don't know if what I'm helping you with will work or not

[Skippy]

I changed the coding to take out the cheats thing and the same thing happened. Nothing showed up.

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

#define PLUGIN_VERSION "1.0"

public Plugin:myinfo =
{
	name = "Rules Image",
	author = "Skipper",
	description = "Rules Agreement Image",
	version = PLUGIN_VERSION,
};

#define RulesVTF	"custom/rules.vtf"
#define RulesVMT	"custom/rules.vmt"

public OnPluginStart()
{
	RegAdminCmd("sm_rule", Command_Rule, ADMFLAG_SLAY, "sm_rule <#userid|name>");
}

public OnMapStart()
{
	PrecacheGeneric(RulesVTF, true);
	AddFileToDownloadsTable("materials/custom/rules.vtf");
	
	PrecacheGeneric(RulesVMT, true);
	AddFileToDownloadsTable("materials/custom/rules.vmt");
}	

public Action:Command_Rule(client, args)
{
	if ( args < 1 )
	{
		ReplyToCommand(client, "[SM] Usage: sm_rule <client>");
		return Plugin_Handled;
	}

	decl String:player[64];
	GetCmdArg(1, player, sizeof(player));

	new String:target_name[MAX_TARGET_LENGTH];
	new target_list[MAXPLAYERS], target_count;
	new bool:tn_is_ml;
 
	if ( (target_count = ProcessTargetString(
			player,
			client,
			target_list,
			MAXPLAYERS,
			COMMAND_FILTER_CONNECTED|COMMAND_FILTER_NO_BOTS,
			target_name,
			sizeof(target_name),
			tn_is_ml)) <= 0 )
	{
		ReplyToCommand(client, "[SM] No matching client");
		return Plugin_Handled;
	}

	for ( new i=0; i<target_count; i++ )
	{
		Rules(client, target_list[i]);
	}

	return Plugin_Handled;
}

stock Rules(client, target)
{
	if ( target > 0 && target <= MaxClients )
	{
		if ( IsClientConnected(target) && IsClientInGame(target) && !IsFakeClient(client) )
		{
			ClientCommand(target, "r_screenoverlay decals/rules");

			CreateTimer(5.0, Timer_Rules, target, TIMER_FLAG_NO_MAPCHANGE);
		}
	}
}

public Action:Timer_Rules(Handle:timer, any:client)
{
	if ( IsClientConnected(client) && IsClientInGame(client) && !IsFakeClient(client) )
	{
		ClientCommand(client, "r_screenoverlay off");
	}
}

[TnTSCS]

and if you type
r_screenoverlay decals/rules
into your game console, you see the overlay?

[andi67]

#define RulesVTF "custom/rules.vtf" #define RulesVMT "custom/rules.vmt"

try:

#define RulesVTF "materials/custom/rules.vtf" #define RulesVMT "materials/custom/rules.vmt"

[Skippy]

Originally Posted by TnTSCS and if you type r_screenoverlay decals/rules into your game console, you see the overlay?

Okay I typed that into console and nothing came up.

[TnTSCS]

maybe the file isn't setup correctly for an overlay? I've never made an overlay, so I don't know... but there is an overlay over in the zombie:reloaded forums you could grab for trying out

[ajr1234]

I made these stocks a while back.

Just PrecacheImageOnServer() for all your screen images during OnMapStart, and use DisplayScreenImage() when you want to display it to a client.

Also, change the shader from LightmappedGeneric to MonitorScreen. Although the wiki says "you can use any shader you want," I found that the pixel shader would blend alphas with any shader other than MonitorScreen, so the wiki's statement appears to be false.

PHP Code:

/**
* PrecacheImageOnServer()
*   Prepares an image stored on the server to be transferred
*   to the client on connect, and also precache the image
*   for use in-game.
*
* Example use:
*   If an image called img.vtf existed in materials/foo/
*   folder, we would call the function like so:
*       PrecacheImageOnServer("foo/img");
*
*   Do not include the "materials/" or the extension in the
*   argument.
*
* Returns: true when successful, NULL or 0 when something failed.
**/
public bool:PrecacheImageOnServer(const String:imgfile[])
{
    new String:overlays_file[64];
    new String:overlays_dltable[64];

    Format(overlays_file, sizeof(overlays_file), "%s.vtf", imgfile);
    PrecacheDecal(overlays_file, true);
    Format(overlays_dltable, sizeof(overlays_dltable), "materials/%s.vtf", imgfile);
    AddFileToDownloadsTable(overlays_dltable);

    Format(overlays_file, sizeof(overlays_file), "%s.vmt", imgfile);
    PrecacheDecal(overlays_file, true);
    Format(overlays_dltable, sizeof(overlays_dltable), "materials/%s.vmt", imgfile);
    AddFileToDownloadsTable(overlays_dltable);

    return true;
}

/**
* ClearScreen() clears all images on the client's screen
**/
public ClearScreenImages(client)
{
    if(client > 0 && IsValidEntity(client))
    ClientCommand(client, "r_screenoverlay \"\"");
}

/**
* DisplayScreenImage() displays an image to the screen
**/
public DisplayScreenImage(client, const String:imgfile[])
{
    if(client > 0 && IsValidEntity(client))
    ClientCommand(client, "r_screenoverlay \"%s.vtf\"", imgfile);
}

/**
* DisplayScreenImageAndRemove()
*    Displays an image to the screen for a period of time
**/
public DisplayScreenImageAndRemove(client, const String:imgfile[], Float:duration)
{
    if(client > 0 && IsValidEntity(client))
    {
        ClientCommand(client, "r_screenoverlay \"%s.vtf\"", imgfile);
        CreateTimer(duration, RemoveScreenImage, client);
    }
}

// timer remove image
public Action:RemoveScreenImage(Handle:timer, any:client)
{
    ClearScreenImages(client);
    return Plugin_Stop;
}