[Franc1sco]

Hello, I want to create a big horizontal circle.


TE_SetupBeamRingPoint dont work because is radius limit is 4096.


I have this stocks for a vertical circle but I want to convert it on horizontal circle:

PHP Code:

Circle(Float:vecLocation[3], Float:radius)
{
    new Float:angle=0.0, Float:x, Float:y;
    
    new Float:pos1[3];
    new Float:pos2[3];
        
    //Create the start position for the first part of the beam
    pos2[0] = vecLocation[0];
    pos2[1] = vecLocation[1] + radius;
    pos2[2] = vecLocation[2];
    
    while (angle <= 2 * PI)
    {            
        x = radius * Cosine(angle);
        y = radius * Sine(angle);
        
        pos1[0] = vecLocation[0];
        pos1[1] = vecLocation[1] + x;
        pos1[2] = vecLocation[2] + y;

        TE_SetupBeamPoints(pos1, pos2, BeamSprite, HaloSprite, 0, 0, 8.0, Float:5.0, Float:5.0, 5, 0.0, {255,255,255,255}, 3);
        TE_SendToAll();
        
        pos2[0] = pos1[0];
        pos2[1] = pos1[1];
        pos2[2] = pos1[2];
        
        angle += 0.1;
    }
} 


Any help? I will continue testing.


EDIT: Solved.

PHP Code:

void Circle(float vecLocation[3], float radius) {
    float angle = 0.0, x, y;

    float pos1[3];
    float pos2[3];

    //Create the start position for the first part of the beam
    pos2[0] = vecLocation[0] + radius;
    pos2[1] = vecLocation[1];
    pos2[2] = vecLocation[2];

    while (angle <= 2 * FLOAT_PI) {
        x = radius * Cosine(angle);
        y = radius * Sine(angle);

        pos1[0] = vecLocation[0] + x;
        pos1[1] = vecLocation[1] + y;
        pos1[2] = vecLocation[2];

        TE_SetupBeamPoints(pos1, pos2, g_sprite, g_HaloSprite, 0, 0, 0.1, view_as<float>(5.0), view_as<float>(5.0), 5, 0.0, {255, 0, 0, 255}, 3);
        TE_SendToAll();

        pos2[0] = pos1[0];
        pos2[1] = pos1[1];
        pos2[2] = pos1[2];

        angle += DegToRad(6.0);
    }
} 


[SHUFEN]

Simply

void HorizontalCircle(float vecLocation[3], float radius) {
	float angle = 0.0, x, y;

	float pos1[3];
	float pos2[3];

	//Create the start position for the first part of the beam
	pos2[0] = vecLocation[0] + radius;
	pos2[1] = vecLocation[1];
	pos2[2] = vecLocation[2];

	while (angle <= 2 * FLOAT_PI) {
		x = radius * Cosine(angle);
		y = radius * Sine(angle);

		pos1[0] = vecLocation[0] + x;
		pos1[1] = vecLocation[1] + y;
		pos1[2] = vecLocation[2];

		TE_SetupBeamPoints(pos1, pos2, g_BeamSprite, g_HaloSprite, 0, 0, 8.0, view_as<float>(5.0), view_as<float>(5.0), 5, 0.0, {255, 255, 255, 255}, 3);
		TE_SendToAll();

		pos2[0] = pos1[0];
		pos2[1] = pos1[1];
		pos2[2] = pos1[2];

		angle += DegToRad(6.0);
	}
}

public Action TEST_CIR(int client, int args) {
	float pos[3];
	GetClientEyePosition(client, pos);

	ArrayList arr = new ArrayList(3);
	arr.PushArray(pos);
	arr.Push(4096.0);
	CreateTimer(0.1, Timer_ExpensiveBeacon_Reversed, arr, TIMER_REPEAT);

	return Plugin_Handled;
}

public Action Timer_ExpensiveBeacon_Reversed(Handle timer, any arr_) {
	ArrayList arr = view_as<ArrayList>(arr_);
	float pos[3];
	arr.GetArray(0, pos, 3);
	float radius = arr.Get(1);

	if (radius <= 16.0) {
		delete arr;
		return Plugin_Stop;
	}
	HorizontalCircle(pos, radius);
	radius -= 16.0;
	arr.Set(1, radius);

	return Plugin_Continue;
}