[unnyquee]

PHP Code:

#include <amxmodx>

#pragma semicolon 1

new const g_szCommands[][] =
{
      "/rr",
      "!rr",
      ".rr"
};


public plugin_init()
{
      register_plugin("O", "M", "G");
      
      register_concmd("say", "ConsoleCommand_Say");
}

public ConsoleCommand_Say(iClient)
{
      new szSaid[192], szCommand[3], szValue[3], iValue;
      
      read_args(szSaid, charsmax(szSaid));
      
      for(new i = 0; i < sizeof(g_szCommands); i++)
      {
           if(equali(szSaid, g_szCommands[i], 3))
           {
                 strbreak(szSaid, szCommand, charsmax(szCommand), szValue, charsmax(szValue));
            
                 iValue = str_to_num(szValue);
            
                 if(iValue)
                       server_cmd("sv_restart %d", iValue);
            
                 else
                       server_cmd("sv_restart 1");
           }
      }

      return PLUGIN_CONTINUE;
} 


Not tested, though.

[Sylwester]

tested, without any const, you can type just part of "restart" and it will work

PHP Code:

#include <amxmodx>
public plugin_init(){
    register_clcmd("say", "handle_say")
    register_clcmd("say_team", "handle_say")
}

public handle_say(id){
    static args[32], cmd[16], tmp[16], pos
    read_args(args, 31)
    remove_quotes(args)
    parse(args, cmd, 15, tmp, 15)
    pos = (cmd[0] == '!' || cmd[0] == '/' || cmd[0] == '.')
    if(equali("rr", cmd[pos]) || containi("restart", cmd[pos]) == 0){
        new num = str_to_num(tmp)
        if(num<=0)
            num = 1
        else if(num>60)
            num = 60
        client_print(id, print_chat, "Restart por %d", num)
        server_cmd("sv_restart %d", num)
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
} 


[unnyquee]

I have put that const there to easily modify the commands .

[Sylwester]

But you also made a mistake and it will not work properly with longer commands.

[unnyquee]

Originally Posted by Sylwester But you also made a mistake and it will not work properly with longer commands.

I understand what you're saying. Didn't though about longer commands.

[meTaLiCroSS]

Wont be better something more easy?

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define MAX_RESTART_VALUE 10

public plugin_init() 
{
    register_clcmd("say /rr", "cmd_manual_restart")
    register_clcmd("say !rr", "cmd_manual_restart")
    register_clcmd("say .rr", "cmd_manual_restart")
}

public cmd_manual_restart(id)
{
    new szArgs[5]
    read_argv(1, szArgs, charsmax(szArgs))
    
    new iResult = clamp(str_to_num(szArgs), 1, 10)
    
    server_cmd("sv_restart ^"%d^"", iResult)
    client_print(id, print_chat, "[INFO] Restart Request Succesfully. The round will restart on %d seconds", iResult)
    
    return PLUGIN_HANDLED
} 


[ConnorMcLeod]

@meTaLiCroSS
Won't work.

"say /rr" is different from "say /rr ANYNUMBER", so commands won't be registered.



For other method, use Tries rather than succesive equal(), or use Sylwester method.

[#8 SickneSS]

Tested and done.(This is my method,and now it works). If someone have a suggestion or want to optimise the code I'll appreciate.

PHP Code:

public cmdSayRestart(id,level,cid) {
    
    if(!cmd_access(id,level,cid,1))
        return PLUGIN_HANDLED
    
    new said[192]
    read_args(said,191)
    remove_quotes(said)
    
    new name[32]
    get_user_name(id,name,31)
    
    new Restart[11]
    new Tmp[11]
    strbreak(said,Restart,10,Tmp,10)
    
    new Value = str_to_num(Tmp)

    new const Restrts[] = { "/restart","!restart",".restart","/rr","!rr",".rr","/r","!r",".r" }
    
    for(new i = 0;i <= sizeof (Restrts);i++)
        if(equali(Restart,Restrts[i]))
        {
            if(!is_str_num(Tmp) || Value > 60)
                Value = 1
                    
            if(equal(Tmp,""))
                server_cmd("sv_restart 1")
            else
                server_cmd("sv_restart %d",Value)
    
            ChatColor(0,"%s !yADMIN %s : Restarteo la ronda",szPrefix,name)
            return PLUGIN_HANDLED
        }

    return PLUGIN_CONTINUE
} 


[fysiks]

Originally Posted by #8 SickneSS If someone have a suggestion or want to optimise the code I'll appreciate.[

Originally Posted by ConnorMcLeod For other method, use Tries rather than succesive equal(), or use Sylwester method.

[#8 SickneSS]

Oh,sorry I dont see that .. (I deleted my other code and upload this)

Sorry,Im not to good in this,can someone tell me what means Connor