[TheFlyingApple]

Originally Posted by Dragokas TheFlyingApple, you have the problem somewhere else, not in the part of my code. Marttt, he wants to stop timer on round end, not only on map end.

When I copy your code 1to1, it is still giving me this error message:

[SM] Plugin "slap.smx" encountered error 23: Native detected error
[SM] Invalid timer handle 12ae07f8 (error 3) during timer end, displayed function is timer callback, not the stack trace
[SM] Unable to call function "CheckPlayerZone" due to above error(s).

[Dragokas]

Makes no sense for me. This one can only happen when destory timer handle inside callback.
Can timer callback and round_end event be executed during same ticks (?) ...

[Ilusion9]

Set timer variable to null in timer callback. The old timer value is kept, that's why is invalid handle.

PHP Code:

#pragma newdecls required 
#include <sourcemod>
#include <sdktools>
#include <multicolors>

Handle g_timerAntiCamp1;
Handle g_timerAntiCamp2;

public void OnPluginStart()
{
    HookEvent("round_start", Round_Start_Hook);
    HookEvent("round_end", Round_End_Hook);
}

public void OnMapEnd()
{
    delete g_timerAntiCamp1;
    delete g_timerAntiCamp2;
}

public Action Round_Start_Hook(Handle event, const char[] name, bool dontBroadcast)
{    
    g_timerAntiCamp1 = CreateTimer(30.0, CheckRoundTime, TIMER_FLAG_NO_MAPCHANGE);
}

public Action Round_End_Hook(Handle event, const char[] name, bool dontBroadcast)
{
    delete g_timerAntiCamp1;
    delete g_timerAntiCamp2;
    PrintToConsoleAll("Round ended, timers deleted");
}

public Action CheckRoundTime(Handle timer)
{
    g_timerAntiCamp2 = CreateTimer(2.0, CheckPlayerZone, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);
    g_timerAntiCamp1 = null;
}

public Action CheckPlayerZone(Handle timer) 
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && IsPlayerAlive(i))
        {

            SlapPlayer(i, 20, true);
            CPrintToChat(i, "{green}You are getting slapped");
        }
    }
    
    g_timerAntiCamp2 = null;
} 


[TheFlyingApple]

Originally Posted by Ilusion9 Set timer variable to null in timer callback. The old timer value is kept, that's why is invalid handle. PHP Code: #pragma newdecls required  #include <sourcemod> #include <sdktools> #include <multicolors> Handle g_timerAntiCamp1; Handle g_timerAntiCamp2; public void OnPluginStart() {     HookEvent("round_start", Round_Start_Hook);     HookEvent("round_end", Round_End_Hook); } public void OnMapEnd() {     delete g_timerAntiCamp1;     delete g_timerAntiCamp2; } public Action Round_Start_Hook(Handle event, const char[] name, bool dontBroadcast) {         g_timerAntiCamp1 = CreateTimer(30.0, CheckRoundTime, TIMER_FLAG_NO_MAPCHANGE); } public Action Round_End_Hook(Handle event, const char[] name, bool dontBroadcast) {     delete g_timerAntiCamp1;     delete g_timerAntiCamp2;     PrintToConsoleAll("Round ended, timers deleted"); } public Action CheckRoundTime(Handle timer) {     g_timerAntiCamp2 = CreateTimer(2.0, CheckPlayerZone, TIMER_FLAG_NO_MAPCHANGE|TIMER_REPEAT);     g_timerAntiCamp1 = null; } public Action CheckPlayerZone(Handle timer)  {     for (int i = 1; i <= MaxClients; i++)     {         if (IsClientInGame(i) && IsPlayerAlive(i))         {             SlapPlayer(i, 20, true);             CPrintToChat(i, "{green}You are getting slapped");         }     }          g_timerAntiCamp2 = null; }

With that code it wont repeat every round.

[Ilusion9]

Originally Posted by TheFlyingApple With that code it wont repeat every round.

You have createtimer(30.0, ...) in round_start event. What are you talking about?

[TheFlyingApple]

Originally Posted by Ilusion9 You have createtimer(30.0, ...) in round_start event. What are you talking about?

Yea. The first timer will start the second timer 30 seconds into the round. The second timer will slap people every 2 seconds... If I do it your way, the second timer will never repeat as it should.

[Ilusion9]

Try this:

PHP Code:

#pragma newdecls required 
#include <sourcemod>
#include <sdktools>
#include <multicolors>

Handle g_TimerRoundDelay;
Handle g_TimerSlap;

public void OnPluginStart()
{
    HookEvent("round_start", Event_RoundStart);
    HookEvent("round_end", Event_RoundEnd);
}

public void OnMapEnd()
{
    delete g_TimerRoundDelay;
    delete g_TimerSlap;
}

public Action Event_RoundStart(Handle event, const char[] name, bool dontBroadcast)
{    
    g_TimerRoundDelay = CreateTimer(30.0, Timer_RoundDelay);
}

public Action Timer_RoundDelay(Handle timer)
{
    g_TimerSlap = CreateTimer(2.0, Timer_SlapPlayer, TIMER_REPEAT);
    g_TimerRoundDelay = null;
}

public Action Event_RoundEnd(Handle event, const char[] name, bool dontBroadcast)
{
    delete g_TimerRoundDelay;
    delete g_TimerSlap;
    PrintToConsoleAll("Round ended, timers deleted");
}

public Action Timer_SlapPlayer(Handle timer) 
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && IsPlayerAlive(i))
        {
            SlapPlayer(i, 20, true);
            CPrintToChat(i, "{green}You are getting slapped");
        }
    }
} 


[Marttt]

Thanks about the feedback Dragokas, I didn't pay attention in the whole thread, my mistake.

Anyway, I still think that is not really necessary using Handles here...it is just increasing the complexity for a simple thing.

You can control that with a simple bool var.

Gonna try here again...

__________________

EDIT:
Here we go, worked for me in my L4D2 Versus Server

Spoiler

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <multicolors> 

#pragma semicolon 1
#pragma newdecls required

static bool g_StopTimer;

public void OnPluginStart()
{
    HookEvent("round_start", Round_Start_Hook);
    HookEvent("round_end", Round_End_Hook);
}

public Action Round_Start_Hook(Handle event, const char[] name, bool dontBroadcast)
{
    CreateTimer(30.0, CheckRoundTime);
}

public Action Round_End_Hook(Handle event, const char[] name, bool dontBroadcast)
{
    g_StopTimer = true;
}

public Action CheckRoundTime(Handle timer)
{
    g_StopTimer = false;
    CreateTimer(2.0, CheckPlayerZone, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action CheckPlayerZone(Handle timer)
{
    if (g_StopTimer)
        return Plugin_Stop;

    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientConnected(i) && IsClientInGame(i) && IsPlayerAlive(i))
        {
            SlapPlayer(i, 20, true);
            CPrintToChat(i, "{green}You are being slapped!");
        }
    }

    return Plugin_Continue;
} 


[Ilusion9]

You still need handles if the round ends too soon.
Should create a single timer in OnPluginStart (repeated timer), check if had passed 30 seconds since round start, then slap players.

[Marttt]

Ilusion, yeah you are correct.
Well I made another version that minimizes that error, but still can "be exploited" in rare (impossible?) cases (between 2 seconds).

Spoiler

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <multicolors> 

#pragma semicolon 1
#pragma newdecls required

#define WAIT_TIME 30.0

static float g_fRoundStartTime;

public void OnPluginStart()
{
    HookEvent("round_start", Round_Start_Hook);
    HookEvent("round_end", Round_End_Hook);
}

public Action Round_Start_Hook(Handle event, const char[] name, bool dontBroadcast)
{
    g_fRoundStartTime = GetEngineTime();

    CreateTimer(2.0, CheckPlayerZone, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE);
}

public Action Round_End_Hook(Handle event, const char[] name, bool dontBroadcast)
{
    g_fRoundStartTime = 0.0;
}

public Action CheckPlayerZone(Handle timer)
{
    if (g_fRoundStartTime == 0.0)
        return Plugin_Stop;
    
    if (GetEngineTime() - g_fRoundStartTime < WAIT_TIME)
        return Plugin_Continue;

    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientConnected(i) && IsClientInGame(i) && IsPlayerAlive(i))
        {
            SlapPlayer(i, 20, true);
            CPrintToChat(i, "{green}You are being slapped!");
            //PrintToChat(i, "{green}You are being slapped!");
        }
    }

    return Plugin_Continue;
}