[vuki12]

can you add radar when you say /radar it shows you menu with 3 options 1.see your team on radar 2.see opposite team on radar 3.see all teams ?

[GHW_Chronic]

1. cant make an admin only version, would be unethical
2. vac safe
3. i dont know about the radar idea, maybe

[GHW_Chronic]

updated for multi mod support, as well had to update chr_engine to do so

[ElliottG]

Never mind

[Mog12345]

Hey when I type /esp, the server crashes and gives me this error...

FATAL ERROR (shutting down): Mod_ExtraData called with mod_brush!

[A1r*M4x]

The aim bot also crashes the server when several players use it..

[dustball]

Hey, so basically I wanted to create a modification of the GHW Hacks script, although I don't know pawn. So what I tried to do was make it so instead of having to say it to everyone, have someone say the commands in team chat.

It went from:

public plugin_init()
{
    register_clcmd("say /aimbot","hack1")
    register_clcmd("say /esp","hack2")
    register_clcmd("say /speed","hack3")
    register_clcmd("say /norecoil","hack4")
    register_forward(FM_PlayerPreThink,"FM_PreThink")
    register_forward(FM_TraceLine, "FM_traceline_hook",1)
}

to

register_clcmd("say_team /aimbot","hack1")
    register_clcmd("say_team /esp","hack2")
    register_clcmd("say_team /speed","hack3")
    register_clcmd("say_team /norecoil","hack4")

(Note: The code that I didn't put is there, its just I didn't change it).

Now the thing is, I thought this would make it so when I said it in team chat it would work. The second thing I did is tried to remove the glow and message from when you would type these things and they would activate.

For the speed it went from:

public hack3(id)
{
    if(get_pcvar_num(speed_on_pcvar))
    {
        if(!speed[id])
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(0,print_chat,"[GHW] Speed Hack Enabled on %s (hold use key to use)",name)
            speed[id]=true
        }
        else
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(0,print_chat,"[GHW] Speed Hack Disabled on %s",name)
            speed[id]=false
            set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
        }
    }
}

to me deleting that. I thought you didn't need it because it had the glow and a message. I pretty much deleted the rest of this thinking that the include file would be all I needed considering the code just looked like it was giving off messages and glow things.

Now, when I test this, before it worked. It does nothing now. The command doesn't register at all.

What did I do wrong?

If you want to look at it, the entire modified script is here:

#define VERSION    "1.3"

#include <amxmodx>
#include <amxmisc>
#include <chr_engine>

#define HEAD_BONE    8

new bool:esp[33]
new bool:aimbot[33]
new bool:speed[33]
new bool:recoil[33]
new speed_pcvar
new esp_on_pcvar
new aimbot_on_pcvar
new speed_on_pcvar
new recoil_on_pcvar

public plugin_init()
{
    register_plugin("Hacks Plugin",VERSION,"Dustball_Edit")
    speed_pcvar = register_cvar("speedhack_speed","500.0")
    esp_on_pcvar = register_cvar("esp_on","1")
    aimbot_on_pcvar = register_cvar("aimbot_on","1")
    speed_on_pcvar = register_cvar("speed_on","1")
    recoil_on_pcvar = register_cvar("recoil_on","1")
    register_clcmd("say_team /aimbot","hack1")
    register_clcmd("say_team /esp","hack2")
    register_clcmd("say_team /speed","hack3")
    register_clcmd("say_team /norecoil","hack4")
    register_forward(FM_PlayerPreThink,"FM_PreThink")
    register_forward(FM_TraceLine, "FM_traceline_hook",1)
}

public client_disconnect(id)
{
    esp[id]=false
    aimbot[id]=false
    speed[id]=false
    recoil[id]=false
}


public FM_traceline_hook(Float:blah1[3],Float:blah2[3],blah3,id)
{
    if(is_user_alive(id) && recoil[id])
    {
        static vec1[3], Float:vec2[3]
        get_user_origin(id,vec1,3)

        vec2[0] = float(vec1[0])
        vec2[1] = float(vec1[1])
        vec2[2] = float(vec1[2])

        set_tr(TR_vecEndPos,vec2)
    }
}

//teame06's function that he shared with me quiet a while ago.
public set_rendering2(index,fx,r,g,b,render,amount)
{
    set_pev(index, pev_renderfx, fx);
    new Float:RenderColor[3];
    RenderColor[0] = float(r);
    RenderColor[1] = float(g);
    RenderColor[2] = float(b);
    set_pev(index, pev_rendercolor, RenderColor);
    set_pev(index, pev_rendermode, render);
    set_pev(index, pev_renderamt, float(amount));
}

Is there anything I can do to make this work? What/what would I not have to remove to make it work?

Thanks a ton.

[Rosenstein]

You can try this code:

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <chr_engine>
#include <cstrike>

#define HEAD_BONE    8

new bool:esp[33]
new bool:aimbot[33]
new bool:speed[33]
new bool:recoil[33]
new speed_pcvar
new esp_on_pcvar
new aimbot_on_pcvar
new speed_on_pcvar
new recoil_on_pcvar

public plugin_init()
{
    register_plugin("Hacks Plugin","1.2","GHW_Chronic")
    speed_pcvar = register_cvar("speedhack_speed","500.0")
    esp_on_pcvar = register_cvar("esp_on","1")
    aimbot_on_pcvar = register_cvar("aimbot_on","1")
    speed_on_pcvar = register_cvar("speed_on","1")
    recoil_on_pcvar = register_cvar("recoil_on","1")
    register_clcmd("say /aimbot","hack1")
    register_concmd("/aimbot","hack1")
    register_clcmd("say /esp","hack2")
    register_concmd("/esp","hack2")
    register_clcmd("say /speed","hack3")
    register_concmd("/speed","hack3")
    register_clcmd("say /norecoil","hack4")
    register_concmd("/norecoil","hack4")
    register_forward(FM_PlayerPreThink,"FM_PreThink")
    register_forward(FM_TraceLine, "FM_traceline_hook",1)
}

public client_disconnect(id)
{
    esp[id]=false
    aimbot[id]=false
    speed[id]=false
    recoil[id]=false
}

public hack1(id)
{
    if(get_pcvar_num(aimbot_on_pcvar))
    {
        if(!aimbot[id])
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] Aimbot Enabled on %s",name)
            aimbot[id]=true
        }
        else
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] Aimbot Disabled on %s",name)
            aimbot[id]=false
            //set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
        }
    }
}

public hack2(id)
{
    if(get_pcvar_num(esp_on_pcvar))
    {
        if(!esp[id])
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] ESP Enabled on %s",name)
            esp[id]=true
        }
        else
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] ESP Disabled on %s",name)
            esp[id]=false
            //set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
        }
    }
}

public hack3(id)
{
    if(get_pcvar_num(speed_on_pcvar))
    {
        if(!speed[id])
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] Speed Hack Enabled on %s (hold use key to use)",name)
            speed[id]=true
        }
        else
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] Speed Hack Disabled on %s",name)
            speed[id]=false
            //set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
        }
    }
}

public hack4(id)
{
    if(get_pcvar_num(recoil_on_pcvar))
    {
        if(!recoil[id])
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] No Recoil Enabled on %s",name)
            recoil[id]=true
        }
        else
        {
            new name[32]
            get_user_name(id,name,31)
            client_print(id,print_chat,"[GHW] No Recoil Hack Disabled on %s",name)
            recoil[id]=false
            //set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
        }
    }
}

public FM_PreThink(id)
{
    if(is_user_alive(id))
    {
        static name[32], Float:origin[3], Float:angles[3], players[32], num, num2
        arrayset(players,0,32)
        if(esp[id])
        {
            if(get_pcvar_num(esp_on_pcvar))
            {
                pev(id,pev_origin,origin)
                if(cs_get_user_team(id)==CS_TEAM_T)
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                    get_players_distance(origin,players,num,"ae",0,"CT")
                }
                else
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                    get_players_distance(origin,players,num,"ae",0,"TERRORIST")
                }
                static Float:hudpos[2]
                static Float:distance
                static Float:origin2[3]
                num2=0
                for(new i=0;i<num;i++)
                {
                    pev(players[i],pev_origin,origin2)
                    if(get_hudmessage_locs(id,origin2,hudpos))
                    {
                        distance = vector_distance(origin,origin2)
                        num2++
                        set_hudmessage(255,255,0,hudpos[0],hudpos[1],0,6.0,0.2,0.1, 0.2,num2)
                        show_hudmessage(id, "%d",floatround(distance / 10.0))
                        if(num2==4) break;
                    }
                }
            }
            else
            {
                get_user_name(id,name,31)
                client_print(id,print_chat,"[GHW] ESP Disabled on %s",name)
                esp[id]=false
                //set_rendering2(id,kRenderFxNone,0,0,0,kRenderTransAlpha,255)
            }
        }
        if(aimbot[id])
        {
            if(get_pcvar_num(aimbot_on_pcvar))
            {
                engfunc(EngFunc_GetBonePosition,id,HEAD_BONE,origin,angles)
                if(cs_get_user_team(id)==CS_TEAM_T)
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                    get_players_distance(origin,players,num,"aeij",id,"CT")
                }
                else
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                    get_players_distance(origin,players,num,"aeij",id,"TERRORIST")
                }
                if(num)
                {
                    engfunc(EngFunc_GetBonePosition,players[0],HEAD_BONE,origin,angles)
                    entity_set_aim(id,origin,HEAD_BONE)
                }
            }
            else
            {
                get_user_name(id,name,31)
                client_print(id,print_chat,"[GHW] Aimbot Disabled on %s",name)
                aimbot[id]=false
                //set_rendering2(id,kRenderFxNone,255,255,255,kRenderTransAlpha,255)
            }
        }
        if(speed[id])
        {
            if(get_pcvar_num(speed_on_pcvar))
            {
                if(pev(id,pev_button) & IN_USE)
                {
                    set_speed(id,get_pcvar_float(speed_pcvar),3)
                    static Float:velocity[3]
                    pev(id,pev_velocity,velocity)
                    velocity[2] = -320.0
                    set_pev(id,pev_velocity,velocity)
                }
                if(cs_get_user_team(id)==CS_TEAM_T)
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                }
                else
                {
                    //set_rendering2(id,kRenderFxGlowShell,255,255,255,kRenderTransAlpha,255)
                }
            }
            else
            {
                get_user_name(id,name,31)
                client_print(id,print_chat,"[GHW] Speed Hack Disabled on %s",name)
                speed[id]=false
                //set_rendering2(id,kRenderFxNone,255,255,255,kRenderTransAlpha,255)
            }
        }
        if(recoil[id])
        {
            if(get_pcvar_num(recoil_on_pcvar))
            {
                set_pev(id,pev_punchangle, Float:{0.0, 0.0, 0.0})
            }
            else
            {
                get_user_name(id,name,31)
                client_print(id,print_chat,"[GHW] No Recoil Disabled on %s",name)
                recoil[id]=false
                //set_rendering2(id,kRenderFxNone,255,255,255,kRenderTransAlpha,255)
            }
        }
    }
}

public FM_traceline_hook(Float:blah1[3],Float:blah2[3],blah3,id)
{
    if(is_user_alive(id) && recoil[id])
    {
        static vec1[3], Float:vec2[3]
        get_user_origin(id,vec1,3)

        vec2[0] = float(vec1[0])
        vec2[1] = float(vec1[1])
        vec2[2] = float(vec1[2])

        set_tr(TR_vecEndPos,vec2)
    }
}

//teame06's function that he shared with me quiet a while ago.
public set_rendering2(index,fx,r,g,b,render,amount)
{
    set_pev(index, pev_renderfx, fx);
    new Float:RenderColor[3];
    RenderColor[0] = float(r);
    RenderColor[1] = float(g);
    RenderColor[2] = float(b);
    set_pev(index, pev_rendercolor, RenderColor);
    set_pev(index, pev_rendermode, render);
    set_pev(index, pev_renderamt, float(amount));
} 


You can type commands in console or bind them:
/aimbot
/esp
/speed
/norecoil

Users won't get glow, and it will only be printed to you that you've used commands.

[Blunr552]

Originally Posted by A1r*M4x The aim bot also crashes the server when several players use it..

yeah. Got the same problem.

Is tehre any solution so far?