[leonardo121]

Hello, everyone!,

Okay, Suppose i have this:

PHP Code:

new arr1[ ] = { 1, 2 }
new arr2[ ] = { 3, 1 } 


check the value 1!

I already tried with 2 for loop, dynamic arrays, tries and nothing

help?!

[HamletEagle]

arr1[0] == 1?
arr2[1] == 1?

[leonardo121]

you're right but the problem is i dont know the index

 
arr1[ 0 ] 
arr2[ 1 ]

the value 1 Can be the index 1 or 0, So I have to check all, I guess
i think the for loop is solution, but no success

[leonardo121]

bump

[Black Rose]

How to store and access your data. This is one of the first things you consider because it is the most central function of a plugin.

It's not worth using a static array for something like this. You only create limitations and the speed is really nothing to talk about.

One dynamic array (array) that contains all the information about the skins (unique id, model, name, w/e...).
One dynamic array (integer) for each player containing the unique id of all the skins they own.
ArraySize() will replace iPlayerSkinsCount.

The problem here is how to make a unique id for each skin so if one skin is removed from the server it won't corrupt the whole array and shift all of the skins.
That problem could be solved by storing all of the information of the skin in each player array, but that's just bad practice and will increase the data size of each player, both online and offline.
The simple solution would be to store a separate vault containing a unique identifier of a skin (a model name?) and connect that to a unique id. That way there's no possibility for corruption. Load it when the plugin loads the skins and give all the skins an unique id. If they don't have a unique id because they are new, give them one.

[leonardo121]

Originally Posted by Black Rose How to store and access your data. This is one of the first things you consider because it is the most central function of a plugin. It's not worth using a static array for something like this. You only create limitations and the speed is really nothing to talk about. One dynamic array (array) that contains all the information about the skins (unique id, model, name, w/e...). One dynamic array (integer) for each player containing the unique id of all the skins they own. ArraySize() will replace iPlayerSkinsCount. The problem here is how to make a unique id for each skin so if one skin is removed from the server it won't corrupt the whole array and shift all of the skins. That problem could be solved by storing all of the information of the skin in each player array, but that's just bad practice and will increase the data size of each player, both online and offline. The simple solution would be to store a separate vault containing a unique identifier of a skin (a model name?) and connect that to a unique id. That way there's no possibility for corruption. Load it when the plugin loads the skins and give all the skins an unique id. If they don't have a unique id because they are new, give them one.

you're right, thanks for this, i will try it!
What is the best way to create a unique id for each one skin ?

One dynamic array (integer) for each player containing the unique id of all the skins they own.

How to make it ?

I have a problem whean im storing a skin data on plugin_precache

when i put this *testing*

PHP Code:

 ArrayPushCell(g_aSkins, *SKIN UNIQUE ID*) 


the plugin giveme one error

 invalid array handle provided (0)

i initialize the array like this

PHP Code:

g_aSkins = ArrayCreate( 1 ) 


what is this error ?

[Black Rose]

Perhaps you are initiating the array after you try to add data to it.
For example, plugin_precache is called before plugin_init and plugin_cfg.
Move array initialization to precache.

I'm going to create a complete example on the whole system I had in mind.

[leonardo121]

Originally Posted by Black Rose Perhaps you are initiating the array after you try to add data to it. For example, plugin_precache is called before plugin_init and plugin_cfg. Move array initialization to precache. I'm going to create a complete example on the whole system I had in mind.

Ahh thats wayyy give-me the error!!

thankss for the help!

I'm going to create a complete example on the whole system I had in mind.

Thanks

[Black Rose]

I will gladly integrate it more into your plugin if you give me more information or the code.

This will keep track of all skins, their unique ID's and which skins the player has been given. Everything saved in nVault of course.
Use AddSkinToPlayer() to give users skins and GetSkinInfo() to retrieve the information about a certain skin.
If you want it more efficient you can use the trie directly instead of using GetSkinInfo().

To enumerate all skins (for a buy menu):

new tempSkinID, NumSkins = ArraySize(ghAllSkins);
for ( new i ; i < NumSkins ; i++ ) {
    tempSkinID = ArrayGetCell(ghAllSkins, i);
}

To enumerate a player's skins (for a selection menu):

new tempSkinID, NumSkins = ArraySize(ghPlayerSkins[id]);
for ( new i ; i < NumSkins ; i++ ) {
    tempSkinID = ArrayGetCell(ghPlayerSkins[id], i);
}

If you have any questions just ask.

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <nvault>

#define INI_FILENAME    "myskins.ini"
#define VAULT_FILENAME  "myskins"

enum enumSkinInformation {
    _NAME[32],
    _FILENAME[128]
}

new Trie:ghSkinInformation;
new Array:ghAllSkins;
new Array:ghPlayerSkins[33];

new ghSkinsVault;
new ghPlayerVault;

public plugin_init() {
    register_plugin("Test Plugin 1", "1.0", "[ --{-@ ]");
}

stock AddSkinToPlayer(id, SkinID, SaveToVault = 1) {

    if ( PlayerHasSkin(id, SkinID) )
        return 0;

    if ( ! IsSkinIDValid(SkinID) )
        return 0;

    ArrayPushCell(ghPlayerSkins[id], SkinID);

    if ( SaveToVault )
        SavePlayerSkinsToVault(id);

    return 1;
}

stock PlayerHasSkin(id, SkinID) {

    new NumSkins = ArraySize(ghPlayerSkins[id]);

    for ( new i ; i < NumSkins ; i++ ) {
        if ( ArrayGetCell(ghPlayerSkins[id], i) == SkinID )
            return 1;
    }

    return 0;
}

stock SavePlayerSkinsToVault(id) {

    new szSteamID[32];
    get_user_authid(id, szSteamID, charsmax(szSteamID));

    new szTemp[512], len;
    new NumSkins = ArraySize(ghPlayerSkins[id]);

    for ( new i ; i < NumSkins ; i++ )
        len += formatex(szTemp[len], charsmax(szTemp) - len, "%d ", ArrayGetCell(ghPlayerSkins[id], i));

    nvault_set(ghPlayerVault, szSteamID, szTemp);
}

stock IsSkinIDValid(SkinID) {

    new szKey[32];
    num_to_str(SkinID, szKey, charsmax(szKey));

    return TrieKeyExists(ghSkinInformation, szKey);
}

stock GetSkinInfo(SkinID, SkinInformation[enumSkinInformation]) {

    new szKey[32];
    num_to_str(SkinID, szKey, charsmax(szKey));

    if ( ! TrieKeyExists(ghSkinInformation, szKey) )
        return 0;

    TrieGetArray(ghSkinInformation, szKey, SkinInformation, enumSkinInformation);

    return 1;
}

public client_authorized(id) {

    new szData[512], szTemp[32], szSteamID[32];

    ghPlayerSkins[id] = ArrayCreate();

    get_user_authid(id, szSteamID, charsmax(szSteamID));
    nvault_get(ghPlayerVault, szSteamID, szData, charsmax(szData));

    if ( ! szData[0] )
        return;

    do {
        strbreak(szData, szTemp, charsmax(szTemp), szData, charsmax(szData));
        ArrayPushCell(ghPlayerSkins[id], str_to_num(szTemp));
    } while ( szData[0] );
}

public client_disconnect(id)
    ArrayDestroy(ghPlayerSkins[id]);

public plugin_precache() {

    new szFilename[128];
    get_configsdir(szFilename, charsmax(szFilename));
    add(szFilename, charsmax(szFilename), "/");
    add(szFilename, charsmax(szFilename), INI_FILENAME);

    new hFile = fopen(szFilename, "rt");

    if ( ! hFile )
        CreateNewIni(szFilename);

    ghSkinInformation = TrieCreate()
    ghAllSkins = ArrayCreate();

    new szData[512], szKey[32], tempID;
    new tempSkinInformation[enumSkinInformation];

    while ( !feof(hFile) ) {
        fgets(hFile, szData, charsmax(szData));
        trim(szData);

        if ( szData[0] == ';' || ( szData[0] == '/' && szData[1] == '/' ) )
            continue;

        parse(szData, tempSkinInformation[_FILENAME], charsmax(tempSkinInformation[_FILENAME]), tempSkinInformation[_NAME], charsmax(tempSkinInformation[_NAME]));

        if ( ! file_exists(tempSkinInformation[_FILENAME]) ) {
            server_print("I can't find the file ^"%s^".", tempSkinInformation[_FILENAME]);
            continue;
        }

        tempID = GetSkinUniqueID(tempSkinInformation[_FILENAME]);
        ArrayPushCell(ghAllSkins, tempID)

        num_to_str(tempID, szKey, charsmax(szKey));
        TrieSetArray(ghSkinInformation, szKey, tempSkinInformation, enumSkinInformation);

        precache_model(tempSkinInformation[_FILENAME]);
    }

    fclose(hFile);

    if ( ! ArraySize(ghAllSkins) )
        ExitPluginWithError("I can't find any valid skins in the ini file.");
}

public plugin_end() {

    ArrayDestroy(ghAllSkins);
    TrieDestroy(ghSkinInformation);

    nvault_close(ghSkinsVault);
    nvault_close(ghPlayerVault);
}

CreateNewIni(szFilename[]) {

    new hFile = fopen(szFilename, "wt");

    if ( ! hFile )
        ExitPluginWithError("I have failed to create the ini file.");

    fprintf(hFile, "; Default format of file...");
    fclose(hFile);

    ExitPluginWithError("My ini file is empty.");
}

GetSkinUniqueID(szSkinFilename[]) {

    if ( ! ghSkinsVault )
        ghSkinsVault = nvault_open(VAULT_FILENAME);

    static NextUniqueID;
    new szTemp[32];

    if ( ! NextUniqueID ) {
        
        NextUniqueID = nvault_get(ghSkinsVault, "COUNTER");

        if ( ! NextUniqueID ) {
            nvault_set(ghSkinsVault, "COUNTER", "1");
            NextUniqueID = 1;
        }
    }

    new Result = nvault_get(ghSkinsVault, szSkinFilename);

    if ( ! Result ) {
        num_to_str(NextUniqueID, szTemp, charsmax(szTemp));
        nvault_set(ghSkinsVault, szSkinFilename, szTemp);

        NextUniqueID++;
        num_to_str(NextUniqueID, szTemp, charsmax(szTemp));
        nvault_set(ghSkinsVault, "COUNTER", szTemp);

        return NextUniqueID - 1;
    }
    
    return Result;
}

ExitPluginWithError(fmt[], ...) {

    new buffer[128];
    vformat(buffer, charsmax(buffer), fmt, 1);

    set_fail_state(buffer);
}

[leonardo121]

god!!, dude you are a genius !! thankss!, i will learn with this plugin!, damm!

I will gladly integrate it more into your plugin if you give me more information or the code.

If I have any questions, I'll tell you!

I sent request on steam, because this is already off-topic, thanks, and keep coding, you are a master piece!