[edon1337]

Hello, I recently noticed that I'm unable to use 2D arrays in Enums.
I get this error:

PHP Code:

error 001: expected token: "}", but found "[" 


Is it just a random error or it's impossible to use 2D arrays in Enums?

PHP Code:

#define MAX_WEAPONS 19
#define MAX_MODELS 3 // V_, P_, W_

enum _:ModelData
{
    Weapon_Models[ MAX_WEAPONS ][ MAX_MODELS ]
} 


Basically, I'm using Weapon_Models to store the new weapon models and replace them with the old ones.
Where the first dimension is the list of armoury_entity entities
And the second dimension is reserved for the V_, P_ and W_ model types of the weapon.



The second problem is, I found a thread where it said you couldn't retrieve the weapon ID with cs_get_weapon_id in FM_SetModel, a working method is checking the weapon model, but that's not what I need. I found this stock (GetWeaponBoxProps) but I'm not really sure how to use it.

PHP Code:

GetWeaponBoxProps( ent, &weapon, &weaponType, &ammoCount, ammoName[], len ) 
{ 
    for(new i = 1; i<= 5; i++) 
    { 
        weapon = get_pdata_cbase(ent, m_rgpPlayerItems_CWeaponBox[i], XO_CWEAPONBOX); 
        if( weapon > 0 ) 
        { 
            break; 
        } 
    } 

    if( weapon > 0 ) 
    { 
        weaponType = get_pdata_int(weapon, m_iId, XO_CBASEPLAYERWEAPON); 
    } 
    else 
    { 
        weaponType = 0; 
    } 

    ammoCount = get_pdata_int(ent, m_rgAmmo_CWeaponBox[1], XO_CWEAPONBOX); 
    if( ammoCount ) 
    { 
        global_get(glb_pStringBase, get_pdata_int(ent, m_rgiszAmmo[1], XO_CWEAPONBOX), ammoName, len); 
    } 
} 


Thanks in advance!

[HamletEagle]

The second problem is, I found a thread where it said you couldn't retrieve the weapon ID with cs_get_weapon_id in FM_SetModel

No offense, but if you do not start connecting what you learn you won't get anywhere.

Remember your previous thread when you asked about weaponbox?
This was my reply: https://forums.alliedmods.net/showpo...5&postcount=27 You could have figured this out based on that information.

Explanation:
What it said is that FM_SetModel is called 2 times on weaponbox entities. Firstly, when the box is created(no weapon yet) and it has weaponbox.mdl as model. Then the weapon is added and the model is changed.
It's obvious you won't be able to use cs_get_weapon_id in the first SetModel call, since there's no weapon to retrieve the id from.
All you have to do is check in SetModel if you have a weaponbox entity and the model is not weaponbox.mdl. Then you can use cs_get_weapon_id.


About your first issue: a better solution is to use a trie(again)

PHP Code:

enum _:ModelType
{
    vModel[128],
    pModel[128],
    wModel[128]
}
    
new Models[ModelType]

TrieSetArray(Trie, key, Models) 


[Black Rose]

Don't use Trie when the index is an integer. That's what Dynamic Arrays are for.

[HamletEagle]

Originally Posted by Black Rose Don't use Trie when the index is an integer. That's what Dynamic Arrays are for.

I have to disagree. Firstly, how do you know his index will be an integer? He could store data like

armoury_m4a1 models
//or simply
ak47 models

And it would be much better to store data in a readable format for the end user. He does not know and does not have to know that armoury smokegrenade index is 18 to be able to make changes.

(assuming he is using a configuration file for models)

Even if it was an index, with a dynamic array you would have to iterate over the array and find the entry that match your desired index.

[edon1337]

Originally Posted by HamletEagle Remember your previous thread when you asked about weaponbox? This was my reply: https://forums.alliedmods.net/showpo...5&postcount=27 You could have figured this out based on that information.

How exactly could that solve my problem? I clearly said I was aware of the impossibility of retrieving Weapon ID in FM_SetModel and was asking for a solution to it.

Originally Posted by HamletEagle I have to disagree. Firstly, how do you know his index will be an integer? He could store data like armoury_m4a1 models //or simply ak47 models And it would be much better to store data in a readable format for the end user. He does not know and does not have to know that armoury smokegrenade index is 18 to be able to make changes. (assuming he is using a configuration file for models) Even if it was an index, with a dynamic array you would have to iterate over the array and find the entry that match your desired index.

This is what my configuration file looks like, can Tries be useful in my case?

PHP Code:

V_KNIFE = models/NewKnife_V.mdl
P_KNIFE =
W_KNIFE =

V_AK47 = models/NewAk47_V.mdl
P_AK47 =
W_AK47 =

V_AUG = models/NewAug_V.mdl
P_AUG =
W_AUG =

V_AWP = models/NewAwp_V.mdl
P_AWP =
W_AWP =

. . . 


EDIT: This is what I'm gonna do, store all the keys (V_AWP, P_AWP, W_AWP..) in a global string and then loop through all of them when using TrieGetString.

[HamletEagle]

Originally Posted by edon1337 How exactly could that solve my problem? I clearly said I was aware of the impossibility of retrieving Weapon ID in FM_SetModel and was asking for a solution to it.

I feel like people don't even listen anymore this days. There is no impossibility. I'll say it again:
->weaponbox is created, model is models/w_weaponbox.mdl
->at this point the box does not contain any weapon. It's just an "empty box".
->PackWeapon is called, weapon is added to the box, model is changed.

This means that the private data are set in the second FM_SetModel call, thus you can access them. All you need to do is to filter out the first call.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <cstrike>

public plugin_init()
{
    register_forward(FM_SetModel, "pfnSetModel", false)
}

public pfnSetModel(const Entity)
{
    if(pev_valid(Entity))
    {
        new EntityClassName[32]
        pev(Entity, pev_classname, EntityClassName, charsmax(EntityClassName))
        
        if(equal(EntityClassName, "weaponbox"))
        {
            new EntityModel[32]
            pev(Entity, pev_model, EntityModel, charsmax(EntityModel))
            
            if(!equal(EntityModel, "models/w_weaponbox.mdl"))
            {
                //do your stuff
            }
        }
    }
} 


Now, what probably confuses you is that when you do cs_get_weapon_id directly on the weaponbox it will most likely return 0. That's because the weaponbox is not the weapon.
You have to firstly get the weapon entity index from the weaponbox, then retrieve the weapon CSW_* index from the weapon entity index.
This is just how weaponbox entities work, not related with FM_SetModel or any other thing you said.

The stock you found is doing a lot of stuff that you probably don't need.

PHP Code:

GetWeaponBoxWeaponType( ent ) 
{ 
    new weapon; 
    for(new i = 1; i<= 5; i++) 
    { 
        weapon = get_pdata_cbase(ent, m_rgpPlayerItems_CWeaponBox[i], XO_CWEAPONBOX); 
        if( weapon > 0 ) 
        { 
            return cs_get_weapon_id(weapon); 
        } 
    } 

    return 0; 
} 


This one is more straightforward. Given a weaponbox entity index, it will return the CSW_* index of the first(usually the only) weapon entity that's packed into the box.

[edon1337]

Seems like it is impossible, the only possible way is by changing the config file names, ex:
V_AK47 --> AK47_V

then, I can create 2 global strings, 1 containing all the config file names, and the other one containing the weapon classes, in Ham_Item_Deploy I would loop through both strings and check

if( containi( szString1[ sizeof( szString1 ) - 2 ], szString2 ) )

sizeof() - 2 because we have to remove the _V/_P postfix.

Correct me if I'm wrong or there's a better solution.

[HamletEagle]

It's very possible and it's quite simple, you are overthinking and over complicating stuff.

[edon1337]

Any idea?

PHP Code:

#include < amxmodx >
#include < amxmisc >
#include < hamsandwich >
#include < fakemeta >
#include < fun >

enum _:ModelData
{
    Weapon_V[ 128 ],
    Weapon_P[ 128 ],
    Weapon_W[ 128 ]
}

new Trie:g_tWeaponModels;

new const g_szTrieKeys[ ][ ] =
{
    "KNIFE_V", "KNIFE_P", "KNIFE_W", "AK47_V", "AK47_P", "AK47_W", "AUG_V", "AUG_P", "AUG_W", "AWP_V", "AWP_P", "AWP_W", "FLASHBANG_V", "FLASHBANG_P", "FLASHBANG_W", "G3SG1_V", "G3SG1_P", "G3SG1_W", "HEGRENADE_V", "HEGRENADE_P", "HEGRENADE_W", "M3_V", "M3_P", "M3_W", "M4A1_V", "M4A1_P", "M4A1_W", "M249_V", "M249_P",
    "M249_W", "MAC10_V", "MAC10_P", "MAC10_W", "MP5NAVY_V", "MP5NAVY_P", "MP5NAVY_W", "P90_V", "P90_P", "P90_W", "SCOUT_V", "SCOUT_P", "SCOUT_W", "SG552_V", "SG552_P", "SG552_W", "SMOKEGRENADE_V", "SMOKEGRENADE_P", "SMOKEGRENADE_W", "TMP_V", "TMP_P", "TMP_W", "UMP45_V", "UMP45_P", "UMP45_W", "XM1014_V", "XM1014_P", "XM1014_W"
}

new const g_szWeaponClasses[ ][ ] =
{
    "weapon_knife", "weapon_ak47", "weapon_aug", "weapon_awp", "weapon_flashbang", "weapon_g3sg1", "weapon_hegrenade", "weapon_m3", "weapon_m4a1", "weapon_m249",
    "weapon_mac10", "weapon_mp5navy", "weapon_p90", "weapon_scout", "weapon_sg552", "weapon_smokegrenade", "weapon_tmp", "weapon_ump45", "weapon_xm1014"
}

new const g_szFileIni[ ] = "GameModels.ini";

public plugin_init( )
{
    register_plugin( "CS Battle Royale Models", "1.0", "DoNii" );

    g_tWeaponModels = TrieCreate( );
    
    for( new i; i < sizeof g_szWeaponClasses; i++ )
    RegisterHam( Ham_Item_Deploy, g_szWeaponClasses[ i ], "fw_HamItemDeployPost", 1 );

    ReadFile( );
}

public plugin_precache( )
{
    new iData[ ModelData ];
    
    for( new i; i < sizeof g_szTrieKeys; i++ )
    {
        if( TrieGetArray( g_tWeaponModels, g_szTrieKeys[ i ], iData, sizeof( iData ) ) )
        {
            precache_model( iData[ Weapon_V ] );
            precache_model( iData[ Weapon_P ] );
            precache_model( iData[ Weapon_W ] );
        }
    }
}

public fw_HamItemDeployPost( iEnt )
{
    if( pev_valid( iEnt ) != 2 )
    return HAM_IGNORED;
    
    new szClassName[ 32 ], szTrieKey[ 32 ];
    pev( iEnt, pev_classname, szClassName, charsmax( szClassName ) );

    for( new i; i < sizeof g_szTrieKeys; i++ )
    {
        copy( szTrieKey, charsmax( szTrieKey ), g_szTrieKeys[ i ] );
        szTrieKey[ sizeof( szTrieKey ) - 2 ] = EOS;
        
        if( equali( szTrieKey, szClassName ) )
        // i dont know...
    }
}

ReadFile( )
{
    new szConfigsName[ 256 ], szFilename[ 512 ];
    get_configsdir( szConfigsName, charsmax( szConfigsName ) );
    
    formatex( szFilename, charsmax( szFilename ), "%s/%s", szConfigsName, g_szFileIni );
    
    new iFile = fopen( szFilename, "r" );

    if( iFile )
    {
        new szData[ 128 ], szValue[ 64 ], szKey[ 32 ];
        
        while( ! feof( iFile ) )
        {
            fgets( iFile, szData, charsmax( szData ) );
            trim( szData );
            
            switch( szData[ 0 ] )
            {
            case EOS, '#', ';': 
                continue;
                
            default:
                {
                    strtok( szData, szKey, charsmax( szKey ), szValue, charsmax( szValue ), '=' );
                    trim( szKey ); 
                    trim( szValue );
                    
                    if( szValue[ 0 ] == EOS )
                    continue;
                    
                    TrieSetArray( g_tWeaponModels, szKey, szValue, sizeof szValue );
                }
            }
        }
    }
    fclose( iFile );
} 


Regarding post #6, I'm sorry for ignoring it, I basically wasn't concentrated and didn't even notice you replied. Thanks for your time.

[E1_531G]

Here you write string not array. Don't you see?

default: { strtok( szData, szKey, charsmax( szKey ), szValue, charsmax( szValue ), '=' ); trim( szKey ); trim( szValue ); if( szValue[ 0 ] == EOS ) continue; TrieSetArray( g_tWeaponModels, szKey, szValue, sizeof szValue ); // < HERE }

Go and read about how to use Trie***Array().

And, you have luck, Hamlet helps you, but you are incredible slow and blind...