[Vechta]

Whats the best way to show Players play time in hours and minutes (saveable by nvault) ?

[wrecked_]

Catch the time on connect with a variable, then use the time they left to determine how long they were in the server.

new Float:connect[33]
new total_time[33]

public client_connect( id )
    connect[id] = get_gametime()

public client_disconnect( id )
    total_time[id] = floatround( get_gametime() - connect[id] )

// total_time[id] holds the seconds the player was in the server
// ( total_time[id] / 60 ) would hold the minutes
// ( ( total_time[id] / 60 ) / 60 ) would hold the hours. 

[Vechta]

sorry for stupid question but can you give me example how i can save it and show it in chat? xD

[SpeeDeeR]

https://forums.alliedmods.net/showthread.php?t=91503 asnwers all your questions
And putting it in chat differs for when do you want to put it.When client is connecting,when he is put in server or with command to see his own playtime.

[wrecked_]

Untested.

#include <amxmodx>
#include <nvault>

new Float:connect[33]
new total_time[33]

new vHandle
new vAuthKey[33][35]

public plugin_init()
{
    register_clcmd( "test", "CmdTest" )
    
    vHandle = nvault_open( "timevault" )
}

public plugin_end()
    nvault_close( vHandle )

public client_connect( id )
{
    connect[id] = get_gametime()
    
    get_user_authid( id, vAuthKey[id], 34 )
}

public client_disconnect( id )
    SaveData( id )
    
public CmdTest( id )
{
    CalcTotal( id )
    
    new total = total_time[id] // since we'll be using total_time a lot and this is faster
    
    client_print( id, print_chat, "Time In Seconds: %i", total )
    
    // sorry for the ugliness here, ask me if you have any questions
    new Hours = floatround( ( ( total / 60.0 ) / 60 ), floatround_floor )
    new Minutes = floatround( ( total / 60.0 ), floatround_floor ) - ( Hours * 60 )
    new Seconds = total - ( Hours * 60 ) - ( Minutes * 60 )
    
    client_print( id, print_chat, "Standard Time Format: %i hrs, %i mins, and %i secs.", Hours, Minutes, Seconds )
}
    
CalcTotal( id )
{
    total_time[id] = floatround( get_gametime() - connect[id] )
    total_time[id] += nvault_get( vHandle, vAuthKey[id] )
}

SaveData( id )
{
    CalcTotal( id )
    
    nvault_pset( vHandle, vAuthKey[id], total_time[id] )
}

[Vechta]

Thank you, i will test it later

[platzpatrone]

also change the topic title pls to a title that made searching
easier like: show Players play time in hours and minutes
or something else.

[Vechta]

Done.

[ConnorMcLeod]

Why don't use get_user_time et get_time_lengh ?

PHP Code:

#include <amxmodx>
#include <nvault>
#include <time>

#define VERSION "0.0.1"
#define PLUGIN "Played Time"

#define MAX_PLAYERS        32

new g_iVault

new g_szSteamId[MAX_PLAYERS+1][32]
new g_iLastPlayedTime[MAX_PLAYERS+1]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_dictionary("time.txt")

    g_iVault = nvault_open("played_time")

    register_clcmd("say /playtime", "ClientCommand_PlayedTime")
}

public plugin_end()
{
    nvault_close( g_iVault )
}

public client_authorized( id )
{
    get_user_authid(id, g_szSteamId[id], charsmax(g_szSteamId[]))

    new szTime[32]
    nvault_get(g_iVault, g_szSteamId[id], szTime, charsmax(szTime))
    g_iLastPlayedTime[id] = str_to_num(szTime)
}

get_user_total_playtime( id )
{
    return g_iLastPlayedTime[id] + get_user_time(id)
}

public ClientCommand_PlayedTime( id )
{
    new szTime[128]
    get_time_length(id, get_user_total_playtime( id ), timeunit_seconds, szTime, charsmax(szTime))
    client_print( id, print_chat, "Played time : %s", szTime )
}

public client_disconnect( id )
{
    new szTime[32]
    formatex(szTime, charsmax(szTime), "%d", get_user_total_playtime( id ))
    nvault_set(g_iVault, g_szSteamId[id], szTime)
} 


[Vechta]

Originally Posted by ConnorMcLeod Why don't use get_user_time et get_time_lengh ? PHP Code: #include <amxmodx> #include <nvault> #include <time> #define VERSION "0.0.1" #define PLUGIN "Played Time" #define MAX_PLAYERS        32 new g_iVault new g_szSteamId[MAX_PLAYERS+1][32] new g_iLastPlayedTime[MAX_PLAYERS+1] public plugin_init() {     register_plugin(PLUGIN, VERSION, "ConnorMcLeod")     register_dictionary("time.txt")     g_iVault = nvault_open("played_time")     register_clcmd("say /playtime", "ClientCommand_PlayedTime") } public plugin_end() {     nvault_close( g_iVault ) } public client_authorized( id ) {     get_user_authid(id, g_szSteamId[id], charsmax(g_szSteamId[]))     new szTime[32]     nvault_get(g_iVault, g_szSteamId[id], szTime, charsmax(szTime))     g_iLastPlayedTime[id] = str_to_num(szTime) } get_user_total_playtime( id ) {     return g_iLastPlayedTime[id] + get_user_time(id) } public ClientCommand_PlayedTime( id ) {     new szTime[128]     get_time_length(id, get_user_total_playtime( id ), timeunit_seconds, szTime, charsmax(szTime))     client_print( id, print_chat, "Played time : %s", szTime ) } public client_disconnect( id ) {     new szTime[32]     formatex(szTime, charsmax(szTime), "%d", get_user_total_playtime( id ))     nvault_set(g_iVault, g_szSteamId[id], szTime) }

Does this code print time in hours and minutes?