[Austin]

L4D2
I would like to change the functionality of this command so that
it only warps bots not humans.

warp_far_survivor_here

Right now the command warps whoever is the farthest away human or bot.

I would like it to only warp the bot that is the farthest away
ignoring all humans players.

I am good at sourcemod plugins but don't know how to start on this plugin.

[Austin]

Austin,
this is simple.
Just make a new command.

[code]
public Action:Command_WarpBots(client, args)
{
if(!client)
{
PrintToServer("[SM] Unable to execute this command from the server console!");
return Plugin_Handled;
}

GetClientAbsOrigin(client, VecOrigin);
for (new i = 1; i <= MAXPLAYERS + 1; i++)
{
if (IsClientInGame(i) && IsFakeClient(i) && GetClientTeam(i) == TEAM_SURVIVOR)
{
TeleportEntity(i, VecOrigin, NULL_VECTOR, NULL_VECTOR);
}
}
return Plugin_Handled;
}
[\code]

[Darkness_]

...Did you just answer your own question?

Try this. I don't know what TEAM_SURVIVOR is though so be sure to define it.

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>

#define TEAM_SURVIVOR 2 //DeathChaos25


public OnPluginStart() {
    RegAdminCmd("sm_warpbots", Command_warpBots, ADMFLAG_SLAY);
}

public Action Command_warpBots(int client, int args) {
    if (!client) {
        PrintToServer("[SM] Unable to execute this command from the server console!");
        return Plugin_Handled;
    }
    float clientPos[3];
    GetEntPropVector(client, Prop_Data, "m_vecOrigin", clientPos);
    int farthestBotIndex = getFarthestBot(client);
    if (farthestBotIndex < 1) {
        ReplyToCommand(client, "[SM] Could not find a bot to teleport.");
        return Plugin_Handled;
    }
    TeleportEntity(farthestBotIndex, clientPos, NULL_VECTOR, NULL_VECTOR);
    ReplyToCommand(client, "[SM] Teleported %N to you.", farthestBotIndex);
    return Plugin_Handled;
}

int getFarthestBot(client) {
    int farthestBotIndex = -1;
    float maxDist;
    float otherPos[3], clientPos[3];
    GetEntPropVector(client, Prop_Data, "m_vecOrigin", clientPos);
    for (int i = 1; i <= MaxClients; i++) {
        if (!IsClientInGame(i)) continue;
        if (!IsPlayerAlive(i)) continue;
        if (!IsFakeClient(i)) continue;
        if (GetClientTeam(i) != TEAM_SURVIVOR) continue;
        GetEntPropVector(i, Prop_Data, "m_vecOrigin", otherPos);
        if (GetVectorDistance(clientPos, otherPos, false) > maxDist) {
            maxDist = GetVectorDistance(clientPos, otherPos, false);
            farthestBotIndex = i;
        }
    }
    return farthestBotIndex;
} 


[DeathChaos25]

Team Survivors is team #2, so it'd be,

PHP Code:

#define TEAM_SURVIVOR 2 


[Austinbots]

Originally Posted by Darkness_ ...Did you just answer your own question?

It was taking a while to get an answer!, but i kept trying to figure this out and came up
with a plugin on my own that just warps all bots right to where I am,
which actually worked out better.

Thanks for the example code.
I will file it away for possible later use.