[HowToRuski]

hi, is there a 'if check' to check if a grenade is missed? thanks

im just trying to play a sound when its missed but i cant figure it out

PHP Code:

if (something here?)
        {
            ArrayGetString(grenade_miss_player, random_num(0, ArraySize(grenade_miss_player) - 1), sound, charsmax(sound))
            emit_sound(victim, CHAN_VOICE, sound, 1.0, ATTN_NORM, 0, PITCH_NORM)
            continue;
        } 


[HamletEagle]

How do you define a miss? For example, if we are talking about he grenade, is it a miss if the grenade does not damage anyone or is it a miss if the grenade does not directly hit (touch) a player?

[HowToRuski]

Originally Posted by HamletEagle How do you define a miss? For example, if we are talking about he grenade, is it a miss if the grenade does not damage anyone or is it a miss if the grenade does not directly hit (touch) a player?

probably not damage anyone

i've got something like this, but it doesnt seem to work....

PHP Code:

// Missed grenade
        if (victim == -1)
        {
            ArrayGetString(grenade_miss_player, random_num(0, ArraySize(grenade_miss_player) - 1), sound, charsmax(sound))
            emit_sound(victim, CHAN_VOICE, sound, 1.0, ATTN_NORM, 0, PITCH_NORM)
            continue;
        } 


[Bugsy]

Not ideal but it works without using Orpheu

PHP Code:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

new const Version[] = "0.1";

new const GrenadeExplodedSounds[][] =
{
    "weapons/debris1.wav",
    "weapons/debris2.wav",
    "weapons/debris3.wav"
};

public plugin_init() 
{
    register_plugin( "Detect Grenade Damage" , Version , "bugsy" );
    
    RegisterHam( Ham_TakeDamage , "player" , "PlayerTakeDamage" );
    register_forward( FM_EmitSound , "EmitSound" );
}

public PlayerTakeDamage( iVictim , iInflictor , iAttacker , Float:fDamage , damageBits )
{
    if ( iInflictor != iAttacker )
    {
        set_pev( iInflictor , pev_iuser4 , 1 );
        client_print( 0 , print_chat , "Player id [%d] took damage by grenade entity [%d]" , iVictim , iInflictor );
    }
}

public grenade_throw( id , gid , wid )
{
    if ( wid == CSW_HEGRENADE )
    {
        client_print( 0 , print_chat , "Grenade entity [%d] thrown" , gid );
        set_pev( gid , pev_iuser4 , 0 );
    }
}

public EmitSound( iEntity , iChannel , const szSound[] )
{
    if ( pev_valid( iEntity ) )
    {        
        for( new i = 0 ; i < sizeof( GrenadeExplodedSounds ) ; i++ )
        {
            if ( equal( GrenadeExplodedSounds[ i ], szSound ) )
            {
                client_print( 0 , print_chat , "Grenade entity [%d] exploded" , iEntity );
                set_task( 0.2 , "CheckForDamage" , iEntity );
                break;
            }
        }
    }
    
    return FMRES_IGNORED;
}

public CheckForDamage( iEntity )
{    
    if ( pev( iEntity , pev_iuser4 ) )
        client_print( 0 , print_chat , "Player(s) were damaged by grenade entity [%d]" , iEntity );
    else
        client_print( 0 , print_chat , "No player(s) were damaged by grenade entity [%d]" , iEntity );
} 


[deprale]

Depends, if you want it the easy way purpose damage detector you'd hook ham takedamage and check damagebits type DMG_GRENADE. Simple.

You could also hook when the grenade explodes, and use find_ent_in_sphere or whatever the function was called, creating a sphere of dimensions - DMG_GRENADE radius const value, but this way its worse because if you have a plugin modifying it's range then it won't detect it.

Also please check if the damage inflicted was less than 1, so you don't accidentally register 0.5 dmg (which causes players to emit hurt sounds but they stay undamaged)

[Bugsy]

This wasn't meant to be the end all be all, it worked in a few quick tests I did. It may need some TLC to get perfect. Feel free if you have the time.

[deprale]

Originally Posted by Bugsy This wasn't meant to be the end all be all, it worked in a few quick tests I did. It may need some TLC to get perfect. Feel free if you have the time.

Oh it wasn't a critique to your reply Bugsy, I was throwing suggestions at the OP, he doesn't look clueless so I didn't bother writing any code.