[martoxs]

Granate destroy baricades and push props very much. How to make props dont move when granade explodes ?

[Jargon]

As far as I know, they are either movable or they aren't, there's no selectivity with what weapon/grenade can/can't move them.

[Bimbo1]

you could try setting near props of a grenade to not movable 0.1 second before its explosion and, then, setting it to movable 0.1 second after its explosion.

@edit
actually, you could even try setting the props to not movable when the entity env_explosion is created.

[martoxs]

I don't understand, does anyone know how ?

[Bimbo1]

here you go, i did it for you:
you may want to change the number at the line 31. it's the squared range of the explosion. i set the range as 250000, which is 500 squared. it worked fine for me, but if you want to change its radius, do it.

#include <sourcemod>
#include <cstrike>
#include <sdktools>
#include <sdkhooks>

public OnEntityCreated(entity, const String:classname[]){
    
    if(StrEqual(classname, "hegrenade_projectile", false)){
        
        CreateTimer(1.5, OnGrenadeExplosion, entity);
        
    }
    
}

public Action:OnGrenadeExplosion(Handle:timer, any:entity){
    
    decl Float:pos[3];
    decl Float:pos2[3];
    decl String:classname[32];
    new Handle:pack = CreateDataPack();
    GetEntPropVector(entity, Prop_Data, "m_vecOrigin", pos);
    for(new i = MaxClients+1; i < 2048; i++){
        
        if(IsValidEntity(i)){
            
            GetEntPropString(i, Prop_Data, "m_iClassname", classname, 32);
            if(StrContains(classname, "prop_physics", false) != -1){
                
                GetEntPropVector(i, Prop_Data, "m_vecOrigin", pos2);
                if(GetVectorDistance(pos, pos2, true) <= 250000.0){
                    
                    AcceptEntityInput(i, "DisableMotion");
                    WritePackCell(pack, i);
                    
                }
                
            }
            
        }
        
    }
    WritePackCell(pack, -1);
    CreateTimer(0.1, AfterGrenadeExplosion, pack);
    return Plugin_Continue;
    
}

public Action:AfterGrenadeExplosion(Handle:timer, Handle:pack){
    
    ResetPack(pack);
    new entity = ReadPackCell(pack);
    decl String:classname[32];
    while(entity != -1){
        
        if(IsValidEntity(entity)){
            
            GetEntPropString(entity, Prop_Data, "m_iClassname", classname, 32);
            if(StrContains(classname, "prop_physics", false) != -1){
                
                AcceptEntityInput(entity, "EnableMotion");
                
            }
            
        }
        entity = ReadPackCell(pack);
        
    }
    
}

code in pastie: http://pastie.org/private/dynw0dfiukcimnjglsvvjq

[Bimbo1]

oh, and please change the line:
for(new i = MaxClients+1; i < 2048; i++){
to this
for(new i = MAXPLAYERS+1; i < 2048; i++){

[eziukasish]

Man, u are the beast!!!!!! Thank you!!!!!!!!!!!

[Bimbo1]

Originally Posted by eziukasish Man, u are the beast!!!!!! Thank you!!!!!!!!!!!

lol, i don't think being a beast is a good thing, but whatever. anyway, the method i used before is just dumb, so i thought a little more about it and did something much simplier and smarter which should work flawlessly:

#include <sourcemod>
#include <cstrike>
#include <sdktools>
#include <sdkhooks>

new bool:grenadeIndex[2048] = {false, false, ...};

public OnEntityCreated(entity, const String:classname[]){
    
    if(StrEqual(classname, "hegrenade_projectile", false)){
        
        grenadeIndex[entity] = true;
        
    }else if(StrContains(classname, "prop_physics", false) != -1){
        
        SDKHook(entity, SDKHook_OnTakeDamage, OnTakeDamage);
        
    }
    
}

public Action:OnTakeDamage(victim, &attacker, &inflictor, &Float:damage, &damagetype){
    
    if(!grenadeIndex[inflictor]){
        
        return Plugin_Continue;
        
    }
    return Plugin_Handled;
    
}

[rhelgeby]

The basic logic would work, but you don't have a line that's resetting an entry in grenadeIndex to false again. Over time every entry will eventually be true. Not all entity indexes are unique, like the grenade projectiles.

Perhaps it works by using OnEntityDestroyed to reset entries in grenadeIndex to false, if the entity exist in that list.

You also might want to add additional damage hooks for prop_physics_multiplier and prop_physics_override, since those are also common in maps.

[ocwoody]

Originally Posted by rhelgeby The basic logic would work, but you don't have a line that's resetting an entry in grenadeIndex to false again. Over time every entry will eventually be true. Not all entity indexes are unique, like the grenade projectiles. Perhaps it works by using OnEntityDestroyed to reset entries in grenadeIndex to false, if the entity exist in that list. You also might want to add additional damage hooks for prop_physics_multiplier and prop_physics_override, since those are also common in maps.

Would love to see these changes made, so I can use it on my server!